this repo has no description
dekker.one
1int: n;
2% La reina de la i columna está en la fila q[i]
3array [1..n] of var 1..n: q;
4
5include "alldifferent.mzn";
6
7% Filas distintas.
8constraint alldifferent(q);
9
10% Diagonales distintas.
11constraint alldifferent([ q[i] + i | i in 1..n]);
12
13% Hacia arriba + hacia abajo.
14constraint alldifferent([ q[i] - i | i in 1..n]);
15
16include "lex_lesseq.mzn";
17
18% Modelo booleano alternativo:
19% Mapa de cada posición i, j a un número booleano
20% señalando si hay una reina en la posición i, j.
21array[1..n,1..n] of var bool: qb;
22
23% Coeficiente de canalización.
24constraint forall (i,j in 1..n) ( qb[i,j] <-> (q[i]=j) );
25
26% Restricciones de ruptura de simetría lexicográfica.
27constraint
28 lex_lesseq(array1d(qb), [ qb[j,i] | i,j in 1..n ])
29/\ lex_lesseq(array1d(qb), [ qb[i,j] | i in reverse(1..n), j in 1..n ])
30/\ lex_lesseq(array1d(qb), [ qb[j,i] | i in 1..n, j in reverse(1..n) ])
31/\ lex_lesseq(array1d(qb), [ qb[i,j] | i in 1..n, j in reverse(1..n) ])
32/\ lex_lesseq(array1d(qb), [ qb[j,i] | i in reverse(1..n), j in 1..n ])
33/\ lex_lesseq(array1d(qb), [ qb[i,j] | i,j in reverse(1..n) ])
34/\ lex_lesseq(array1d(qb), [ qb[j,i] | i,j in reverse(1..n) ])
35;
36
37% Búsqueda.
38solve :: int_search(q, first_fail, indomain_min, complete)
39 satisfy;
40output [ if fix(q[j]) == i then "Q" else "." endif ++
41 if j == n then "\n" else "" endif | i,j in 1..n]