this repo has no description
dekker.one
1# - Try to find Geas
2# Once done this will define
3# GEAS_FOUND - System has Geas
4# GEAS_INCLUDE_DIRS - The Geas include directories
5# GEAS_LIBRARIES - The libraries needed to use Geas
6# User can set GEAS_ROOT to the preferred installation prefix
7# Imported target Geas will be created for linking purposes
8
9list(INSERT CMAKE_PREFIX_PATH 0 "${GEAS_ROOT}" "$ENV{GEAS_ROOT}")
10
11find_path(
12 GEAS_INCLUDE geas/c/geas.h
13 PATH_SUFFIXES include
14)
15
16find_library(
17 GEAS_LIBRARY NAMES geas libgeas
18 PATH_SUFFIXES lib
19)
20
21include(FindPackageHandleStandardArgs)
22# handle the QUIETLY and REQUIRED arguments and set GEAS_FOUND to TRUE
23# if all listed variables are TRUE
24find_package_handle_standard_args(Geas
25 FOUND_VAR GEAS_FOUND
26 REQUIRED_VARS GEAS_INCLUDE GEAS_LIBRARY
27 FAIL_MESSAGE "Could NOT find Geas, use GEAS_ROOT to hint its location"
28)
29
30mark_as_advanced(GEAS_INCLUDE GEAS_LIBRARY)
31list(REMOVE_AT CMAKE_PREFIX_PATH 1 0)
32
33if(GEAS_FOUND)
34 add_library(Geas UNKNOWN IMPORTED)
35 set_target_properties(Geas PROPERTIES
36 IMPORTED_LOCATION ${GEAS_LIBRARY}
37 INTERFACE_INCLUDE_DIRECTORIES ${GEAS_INCLUDE}
38 )
39endif()
40
41set(GEAS_LIBRARIES ${GEAS_LIBRARY})
42set(GEAS_INCLUDE_DIRS ${GEAS_INCLUDE})