this repo has no description
dekker.one
1% This file contains redefinitions of standard builtins that can be overridden
2% by solvers.
3
4/***
5 @groupdef flatzinc.two FlatZinc builtins added in MiniZinc 2.0.0.
6
7 These functions and predicates define built-in operations of the MiniZinc language
8 that have been added in MiniZinc 2.0.0. Solvers that support these natively need
9 to include a file called redefinitions-2.0.mzn in their solver library that
10 redefines these predicates as builtins.
11
12*/
13
14/** @group flatzinc.two Reified clause constraint.
15 Constrains \( \a b \leftrightarrow \bigvee_i \a as[i] \lor \bigvee_j \lnot \a bs[j] \)
16 */
17predicate bool_clause_reif(array[int] of var bool: as,
18 array[int] of var bool: bs,
19 var bool: b) =
20 clause(as,bs++[b]) /\
21 forall (i in index_set(as)) (as[i] -> b) /\
22 forall (i in index_set(bs)) (bs[i] \/ b);
23
24/** @group flatzinc.two Constrains \a m to be the maximum value in array \a x. */
25predicate array_int_maximum(var int: m, array[int] of var int: x) =
26 let { int: l = min(index_set(x)),
27 int: u = max(index_set(x)),
28 int: ly = lb_array(x),
29 int: uy = ub_array(x),
30 array[l..u] of var ly..uy: y } in
31 y[l] = x[l] /\
32 m = y[u] /\
33 forall (i in l+1 .. u) ( y[i] == max(x[i],y[i-1]) );
34
35/** @group flatzinc.two Constrains \a m to be the maximum value in array \a x. */
36predicate array_float_maximum(var float: m, array[int] of var float: x) =
37 let { int: l = min(index_set(x)),
38 int: u = max(index_set(x)),
39 float: ly = lb_array(x),
40 float: uy = ub_array(x),
41 array[l..u] of var ly..uy: y } in
42 y[l] = x[l] /\
43 m = y[u] /\
44 forall (i in l+1 .. u) ( y[i] == max(x[i],y[i-1]) );
45
46/** @group flatzinc.two Constrains \a m to be the minimum value in array \a x. */
47predicate array_int_minimum(var int: m, array[int] of var int: x) =
48 let { int: l = min(index_set(x)),
49 int: u = max(index_set(x)),
50 int: ly = lb_array(x),
51 int: uy = ub_array(x),
52 array[l..u] of var ly..uy: y } in
53 y[l] = x[l] /\
54 m = y[u] /\
55 forall (i in l+1 .. u) ( y[i] == min(x[i],y[i-1]) );
56
57/** @group flatzinc.two Constrains \a m to be the minimum value in array \a x. */
58predicate array_float_minimum(var float: m, array[int] of var float: x) =
59 let { int: l = min(index_set(x)),
60 int: u = max(index_set(x)),
61 float: ly = lb_array(x),
62 float: uy = ub_array(x),
63 array[l..u] of var ly..uy: y } in
64 y[l] = x[l] /\
65 m = y[u] /\
66 forall (i in l+1 .. u) ( y[i] == min(x[i],y[i-1]) );