Kieran's opinionated (and probably slightly dumb) nix config
dunkirk.sh
1{
2 description = "Kieran's opinionated (and probably slightly dumb) nix config";
3
4 inputs = {
5 # Nixpkgs
6 nixpkgs.url = "github:nixos/nixpkgs/nixos-25.11";
7 nixpkgs-unstable.url = "github:nixos/nixpkgs/nixos-unstable";
8
9 # NixOS hardware configuration
10 hardware.url = "github:NixOS/nixos-hardware/master";
11
12 # Home manager
13 home-manager.url = "github:nix-community/home-manager/release-25.11";
14 home-manager.inputs.nixpkgs.follows = "nixpkgs";
15
16 # Nix-Darwin
17 nix-darwin.url = "github:nix-darwin/nix-darwin/nix-darwin-25.11";
18 nix-darwin.inputs.nixpkgs.follows = "nixpkgs";
19
20 disko.url = "github:nix-community/disko";
21 disko.inputs.nixpkgs.follows = "nixpkgs";
22
23 nixos-facter-modules.url = "github:numtide/nixos-facter-modules";
24
25 # agenix
26 agenix.url = "github:ryantm/agenix";
27
28 spicetify-nix = {
29 url = "github:Gerg-L/spicetify-nix";
30 inputs.nixpkgs.follows = "nixpkgs";
31 };
32
33 catppuccin = {
34 url = "github:catppuccin/nix?rev=f518f96a60aceda4cd487437b25eaa48d0f1b97d";
35 inputs.nixpkgs.follows = "nixpkgs";
36 };
37
38 catppuccin-vsc = {
39 url = "github:catppuccin/vscode";
40 };
41
42 nix-vscode-extensions.url = "github:nix-community/nix-vscode-extensions";
43
44 frc-nix = {
45 url = "github:frc4451/frc-nix";
46 inputs.nixpkgs.follows = "nixpkgs";
47 };
48
49 claude-desktop = {
50 url = "github:k3d3/claude-desktop-linux-flake";
51 inputs.nixpkgs.follows = "nixpkgs";
52 };
53
54 hyprland-contrib = {
55 url = "github:hyprwm/contrib";
56 inputs.nixpkgs.follows = "nixpkgs";
57 };
58
59 nixvim.url = "github:taciturnaxolotl/nixvim";
60
61 terminal-wakatime = {
62 url = "github:taciturnaxolotl/terminal-wakatime";
63 inputs.nixpkgs.follows = "nixpkgs";
64 };
65
66 ctfd-alerts = {
67 url = "github:taciturnaxolotl/ctfd-alerts";
68 inputs.nixpkgs.follows = "nixpkgs";
69 };
70
71 flare = {
72 url = "github:ByteAtATime/flare/feat/nix";
73 inputs.nixpkgs.follows = "nixpkgs";
74 };
75
76 import-tree.url = "github:vic/import-tree";
77
78 nur = {
79 url = "github:nix-community/NUR";
80 inputs.nixpkgs.follows = "nixpkgs";
81 };
82
83 cedarlogic = {
84 url = "github:taciturnaxolotl/CedarLogic";
85 inputs.nixpkgs.follows = "nixpkgs";
86 };
87
88 soapdump = {
89 url = "github:taciturnaxolotl/soapdump";
90 inputs.nixpkgs.follows = "nixpkgs";
91 };
92
93 wakatime-ls = {
94 url = "github:mrnossiom/wakatime-ls";
95 inputs.nixpkgs.follows = "nixpkgs";
96 };
97
98 deploy-rs = {
99 url = "github:serokell/deploy-rs";
100 inputs.nixpkgs.follows = "nixpkgs";
101 };
102
103 tangled = {
104 url = "git+https://tangled.org/tangled.org/core";
105 inputs.nixpkgs.follows = "nixpkgs";
106 };
107
108 battleship-arena = {
109 url = "github:taciturnaxolotl/battleship-arena";
110 inputs.nixpkgs.follows = "nixpkgs";
111 };
112 };
113
114 outputs =
115 {
116 self,
117 nixpkgs,
118 nixpkgs-unstable,
119 agenix,
120 home-manager,
121 nur,
122 nix-darwin,
123 deploy-rs,
124 tangled,
125 ...
126 }@inputs:
127 let
128 outputs = inputs.self.outputs;
129 unstable-overlays = {
130 nixpkgs.overlays = [
131 (final: prev: {
132 unstable = import nixpkgs-unstable {
133 system = final.stdenv.hostPlatform.system;
134 config.allowUnfree = true;
135 };
136
137 bambu-studio = prev.bambu-studio.overrideAttrs (oldAttrs: {
138 version = "01.00.01.50";
139 src = prev.fetchFromGitHub {
140 owner = "bambulab";
141 repo = "BambuStudio";
142 rev = "v01.00.01.50";
143 hash = "sha256-7mkrPl2CQSfc1lRjl1ilwxdYcK5iRU//QGKmdCicK30=";
144 };
145 });
146 })
147 ];
148 };
149 in
150 {
151 # NixOS configuration entrypoint
152 # Available through 'nixos-rebuild --flake .#hostname'
153 nixosConfigurations = {
154 moonlark = nixpkgs.lib.nixosSystem {
155 specialArgs = { inherit inputs outputs; };
156 modules = [
157 inputs.disko.nixosModules.disko
158 { disko.devices.disk.disk1.device = "/dev/vda"; }
159 agenix.nixosModules.default
160 unstable-overlays
161 ./machines/moonlark
162 nur.modules.nixos.default
163 ];
164 };
165
166 prattle = nixpkgs.lib.nixosSystem {
167 specialArgs = { inherit inputs outputs; };
168 modules = [
169 inputs.disko.nixosModules.disko
170 agenix.nixosModules.default
171 inputs.nixos-facter-modules.nixosModules.facter
172 { config.facter.reportPath = ./machines/prattle/facter.json; }
173 unstable-overlays
174 ./machines/prattle
175 nur.modules.nixos.default
176 ];
177 };
178
179 terebithia = nixpkgs.lib.nixosSystem {
180 specialArgs = { inherit inputs outputs; };
181 modules = [
182 inputs.disko.nixosModules.disko
183 agenix.nixosModules.default
184 inputs.nixos-facter-modules.nixosModules.facter
185 { config.facter.reportPath = ./machines/terebithia/facter.json; }
186 unstable-overlays
187 ./machines/terebithia
188 nur.modules.nixos.default
189 ];
190 };
191 };
192
193 # Standalone home-manager configurations
194 # Available through 'home-manager --flake .#hostname'
195 homeConfigurations = {
196 "tacyon" = home-manager.lib.homeManagerConfiguration {
197 pkgs = nixpkgs.legacyPackages.aarch64-linux;
198 extraSpecialArgs = {
199 inherit inputs outputs;
200 nixpkgs-unstable = nixpkgs-unstable;
201 };
202 modules = [
203 ./machines/tacyon
204 unstable-overlays
205 ];
206 };
207
208 "nest" = home-manager.lib.homeManagerConfiguration {
209 pkgs = nixpkgs.legacyPackages.x86_64-linux;
210 extraSpecialArgs = {
211 inherit inputs outputs;
212 nixpkgs-unstable = nixpkgs-unstable;
213 system = "x86_64-linux";
214 };
215 modules = [
216 ./machines/nest
217 unstable-overlays
218 ];
219 };
220
221 "ember" = home-manager.lib.homeManagerConfiguration {
222 pkgs = nixpkgs.legacyPackages.x86_64-linux;
223 extraSpecialArgs = {
224 inherit inputs outputs;
225 nixpkgs-unstable = nixpkgs-unstable;
226 };
227 modules = [
228 ./machines/ember
229 unstable-overlays
230 ];
231
232 };
233 "john" = home-manager.lib.homeManagerConfiguration {
234 pkgs = nixpkgs.legacyPackages.x86_64-linux;
235 extraSpecialArgs = {
236 inherit inputs outputs;
237 nixpkgs-unstable = nixpkgs-unstable;
238 system = "x86_64-linux";
239 };
240 modules = [
241 ./machines/john
242 unstable-overlays
243 ];
244 };
245 };
246
247 # Darwin configurations
248 # Available through 'darwin-rebuild switch --flake .#hostname'
249 darwinConfigurations = {
250 atalanta = nix-darwin.lib.darwinSystem {
251 system = "aarch64-darwin";
252 specialArgs = { inherit inputs outputs; };
253 modules = [
254 home-manager.darwinModules.home-manager
255 agenix.darwinModules.default
256 unstable-overlays
257 ./machines/atalanta
258 ];
259 };
260 };
261
262 formatter.x86_64-linux = nixpkgs.legacyPackages.x86_64-linux.nixfmt-tree;
263 formatter.aarch64-darwin = nixpkgs.legacyPackages.aarch64-darwin.nixfmt-tree;
264
265 # Deploy-rs configurations
266 deploy.nodes = {
267 # NixOS servers
268 terebithia = {
269 hostname = "terebithia";
270 profiles.system = {
271 sshUser = "kierank";
272 user = "root";
273 path = deploy-rs.lib.aarch64-linux.activate.nixos self.nixosConfigurations.terebithia;
274 };
275 };
276 };
277
278 # Validation checks
279 checks = builtins.mapAttrs (system: deployLib: deployLib.deployChecks self.deploy) deploy-rs.lib;
280 };
281}