foxwitch.net
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 gomod2nix = {
7 url = "github:nix-community/gomod2nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 flake-compat = {
11 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
12 flake = false;
13 };
14 indigo = {
15 url = "github:oppiliappan/indigo";
16 flake = false;
17 };
18 htmx-src = {
19 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
20 flake = false;
21 };
22 htmx-ws-src = {
23 # strange errors in consle that i can't really make out
24 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
25 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
26 flake = false;
27 };
28 lucide-src = {
29 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
30 flake = false;
31 };
32 inter-fonts-src = {
33 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
34 flake = false;
35 };
36 ibm-plex-mono-src = {
37 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
38 flake = false;
39 };
40 sqlite-lib-src = {
41 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
42 flake = false;
43 };
44 };
45
46 outputs = {
47 self,
48 nixpkgs,
49 gomod2nix,
50 indigo,
51 htmx-src,
52 htmx-ws-src,
53 lucide-src,
54 inter-fonts-src,
55 sqlite-lib-src,
56 ibm-plex-mono-src,
57 ...
58 }: let
59 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
60 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
61 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
62
63 mkPackageSet = pkgs:
64 pkgs.lib.makeScope pkgs.newScope (self: {
65 src = let
66 fs = pkgs.lib.fileset;
67 in
68 fs.toSource {
69 root = ./.;
70 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
71 };
72 buildGoApplication =
73 (self.callPackage "${gomod2nix}/builder" {
74 gomod2nix = gomod2nix.legacyPackages.${pkgs.system}.gomod2nix;
75 }).buildGoApplication;
76 modules = ./nix/gomod2nix.toml;
77 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
78 inherit (pkgs) gcc;
79 inherit sqlite-lib-src;
80 };
81 genjwks = self.callPackage ./nix/pkgs/genjwks.nix {};
82 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
83 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
84 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src;
85 };
86 appview = self.callPackage ./nix/pkgs/appview.nix {};
87 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
88 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
89 knot = self.callPackage ./nix/pkgs/knot.nix {};
90 });
91 in {
92 overlays.default = final: prev: {
93 inherit (mkPackageSet final) lexgen sqlite-lib genjwks spindle knot-unwrapped knot appview;
94 };
95
96 packages = forAllSystems (system: let
97 pkgs = nixpkgsFor.${system};
98 packages = mkPackageSet pkgs;
99 staticPackages = mkPackageSet pkgs.pkgsStatic;
100 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
101 in {
102 inherit (packages) appview appview-static-files lexgen genjwks spindle knot knot-unwrapped sqlite-lib;
103
104 pkgsStatic-appview = staticPackages.appview;
105 pkgsStatic-knot = staticPackages.knot;
106 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
107 pkgsStatic-spindle = staticPackages.spindle;
108 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
109
110 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
111 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
112 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
113 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
114
115 treefmt-wrapper = pkgs.treefmt.withConfig {
116 settings.formatter = {
117 alejandra = {
118 command = pkgs.lib.getExe pkgs.alejandra;
119 includes = ["*.nix"];
120 };
121
122 gofmt = {
123 command = pkgs.lib.getExe' pkgs.go "gofmt";
124 options = ["-w"];
125 includes = ["*.go"];
126 };
127
128 # prettier = let
129 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
130 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
131 # '';
132 # in {
133 # command = wrapper;
134 # options = ["-w"];
135 # includes = ["*.html"];
136 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
137 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
138 # };
139 };
140 };
141 });
142 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
143 devShells = forAllSystems (system: let
144 pkgs = nixpkgsFor.${system};
145 packages' = self.packages.${system};
146 staticShell = pkgs.mkShell.override {
147 stdenv = pkgs.pkgsStatic.stdenv;
148 };
149 in {
150 default = staticShell {
151 nativeBuildInputs = [
152 pkgs.go
153 pkgs.air
154 pkgs.gopls
155 pkgs.httpie
156 pkgs.litecli
157 pkgs.websocat
158 pkgs.tailwindcss
159 pkgs.nixos-shell
160 pkgs.redis
161 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
162 packages'.lexgen
163 packages'.treefmt-wrapper
164 ];
165 shellHook = ''
166 mkdir -p appview/pages/static
167 # no preserve is needed because watch-tailwind will want to be able to overwrite
168 cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
169 export TANGLED_OAUTH_JWKS="$(${packages'.genjwks}/bin/genjwks)"
170 '';
171 env.CGO_ENABLED = 1;
172 };
173 });
174 apps = forAllSystems (system: let
175 pkgs = nixpkgsFor."${system}";
176 packages' = self.packages.${system};
177 air-watcher = name: arg:
178 pkgs.writeShellScriptBin "run"
179 ''
180 ${pkgs.air}/bin/air -c /dev/null \
181 -build.cmd "${pkgs.go}/bin/go build -o ./out/${name}.out ./cmd/${name}/main.go" \
182 -build.bin "./out/${name}.out" \
183 -build.args_bin "${arg}" \
184 -build.stop_on_error "true" \
185 -build.include_ext "go"
186 '';
187 tailwind-watcher =
188 pkgs.writeShellScriptBin "run"
189 ''
190 ${pkgs.tailwindcss}/bin/tailwindcss -w -i input.css -o ./appview/pages/static/tw.css
191 '';
192 in {
193 fmt = {
194 type = "app";
195 program = pkgs.lib.getExe packages'.treefmt-wrapper;
196 };
197 watch-appview = {
198 type = "app";
199 program = toString (pkgs.writeShellScript "watch-appview" ''
200 echo "copying static files to appview/pages/static..."
201 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
202 ${air-watcher "appview" ""}/bin/run
203 '');
204 };
205 watch-knot = {
206 type = "app";
207 program = ''${air-watcher "knot" "server"}/bin/run'';
208 };
209 watch-tailwind = {
210 type = "app";
211 program = ''${tailwind-watcher}/bin/run'';
212 };
213 vm = let
214 guestSystem =
215 if pkgs.stdenv.hostPlatform.isAarch64
216 then "aarch64-linux"
217 else "x86_64-linux";
218 in {
219 type = "app";
220 program =
221 (pkgs.writeShellApplication {
222 name = "launch-vm";
223 text = ''
224 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
225 cd "$rootDir"
226
227 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
228
229 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
230 exec ${pkgs.lib.getExe
231 (import ./nix/vm.nix {
232 inherit nixpkgs self;
233 system = guestSystem;
234 hostSystem = system;
235 }).config.system.build.vm}
236 '';
237 })
238 + /bin/launch-vm;
239 };
240 gomod2nix = {
241 type = "app";
242 program = toString (pkgs.writeShellScript "gomod2nix" ''
243 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
244 '');
245 };
246 lexgen = {
247 type = "app";
248 program =
249 (pkgs.writeShellApplication {
250 name = "lexgen";
251 text = ''
252 if ! command -v lexgen > /dev/null; then
253 echo "error: must be executed from devshell"
254 exit 1
255 fi
256
257 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
258 cd "$rootDir"
259
260 rm -f api/tangled/*
261 lexgen --build-file lexicon-build-config.json lexicons
262 sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
263 ${pkgs.gotools}/bin/goimports -w api/tangled/*
264 go run cmd/gen.go
265 lexgen --build-file lexicon-build-config.json lexicons
266 rm api/tangled/*.bak
267 '';
268 })
269 + /bin/lexgen;
270 };
271 });
272
273 nixosModules.appview = {
274 lib,
275 pkgs,
276 ...
277 }: {
278 imports = [./nix/modules/appview.nix];
279
280 services.tangled-appview.package = lib.mkDefault self.packages.${pkgs.system}.appview;
281 };
282 nixosModules.knot = {
283 lib,
284 pkgs,
285 ...
286 }: {
287 imports = [./nix/modules/knot.nix];
288
289 services.tangled-knot.package = lib.mkDefault self.packages.${pkgs.system}.knot;
290 };
291 nixosModules.spindle = {
292 lib,
293 pkgs,
294 ...
295 }: {
296 imports = [./nix/modules/spindle.nix];
297
298 services.tangled-spindle.package = lib.mkDefault self.packages.${pkgs.system}.spindle;
299 };
300 };
301}