julien.rbrt.fr
forked from
tangled.org/core
Monorepo for Tangled — https://tangled.org
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 gomod2nix = {
7 url = "github:nix-community/gomod2nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 flake-compat = {
11 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
12 flake = false;
13 };
14 indigo = {
15 url = "github:oppiliappan/indigo";
16 flake = false;
17 };
18 htmx-src = {
19 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
20 flake = false;
21 };
22 htmx-ws-src = {
23 # strange errors in consle that i can't really make out
24 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
25 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
26 flake = false;
27 };
28 lucide-src = {
29 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
30 flake = false;
31 };
32 inter-fonts-src = {
33 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
34 flake = false;
35 };
36 actor-typeahead-src = {
37 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
38 flake = false;
39 };
40 ibm-plex-mono-src = {
41 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
42 flake = false;
43 };
44 sqlite-lib-src = {
45 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
46 flake = false;
47 };
48 };
49
50 outputs = {
51 self,
52 nixpkgs,
53 gomod2nix,
54 indigo,
55 htmx-src,
56 htmx-ws-src,
57 lucide-src,
58 inter-fonts-src,
59 sqlite-lib-src,
60 ibm-plex-mono-src,
61 actor-typeahead-src,
62 ...
63 }: let
64 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
65 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
66 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
67
68 mkPackageSet = pkgs:
69 pkgs.lib.makeScope pkgs.newScope (self: {
70 src = let
71 fs = pkgs.lib.fileset;
72 in
73 fs.toSource {
74 root = ./.;
75 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
76 };
77 buildGoApplication =
78 (self.callPackage "${gomod2nix}/builder" {
79 gomod2nix = gomod2nix.legacyPackages.${pkgs.system}.gomod2nix;
80 }).buildGoApplication;
81 modules = ./nix/gomod2nix.toml;
82 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
83 inherit (pkgs) gcc;
84 inherit sqlite-lib-src;
85 };
86 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
87 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
88 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
89 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src;
90 };
91 appview = self.callPackage ./nix/pkgs/appview.nix {};
92 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
93 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
94 knot = self.callPackage ./nix/pkgs/knot.nix {};
95 });
96 in {
97 overlays.default = final: prev: {
98 inherit (mkPackageSet final) lexgen goat sqlite-lib spindle knot-unwrapped knot appview;
99 };
100
101 packages = forAllSystems (system: let
102 pkgs = nixpkgsFor.${system};
103 packages = mkPackageSet pkgs;
104 staticPackages = mkPackageSet pkgs.pkgsStatic;
105 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
106 in {
107 inherit (packages) appview appview-static-files lexgen goat spindle knot knot-unwrapped sqlite-lib;
108
109 pkgsStatic-appview = staticPackages.appview;
110 pkgsStatic-knot = staticPackages.knot;
111 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
112 pkgsStatic-spindle = staticPackages.spindle;
113 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
114
115 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
116 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
117 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
118 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
119
120 treefmt-wrapper = pkgs.treefmt.withConfig {
121 settings.formatter = {
122 alejandra = {
123 command = pkgs.lib.getExe pkgs.alejandra;
124 includes = ["*.nix"];
125 };
126
127 gofmt = {
128 command = pkgs.lib.getExe' pkgs.go "gofmt";
129 options = ["-w"];
130 includes = ["*.go"];
131 };
132
133 # prettier = let
134 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
135 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
136 # '';
137 # in {
138 # command = wrapper;
139 # options = ["-w"];
140 # includes = ["*.html"];
141 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
142 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
143 # };
144 };
145 };
146 });
147 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
148 devShells = forAllSystems (system: let
149 pkgs = nixpkgsFor.${system};
150 packages' = self.packages.${system};
151 staticShell = pkgs.mkShell.override {
152 stdenv = pkgs.pkgsStatic.stdenv;
153 };
154 in {
155 default = staticShell {
156 nativeBuildInputs = [
157 pkgs.go
158 pkgs.air
159 pkgs.gopls
160 pkgs.httpie
161 pkgs.litecli
162 pkgs.websocat
163 pkgs.tailwindcss
164 pkgs.nixos-shell
165 pkgs.redis
166 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
167 packages'.lexgen
168 packages'.treefmt-wrapper
169 ];
170 shellHook = ''
171 mkdir -p appview/pages/static
172 # no preserve is needed because watch-tailwind will want to be able to overwrite
173 cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
174 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
175 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
176 '';
177 env.CGO_ENABLED = 1;
178 };
179 });
180 apps = forAllSystems (system: let
181 pkgs = nixpkgsFor."${system}";
182 packages' = self.packages.${system};
183 air-watcher = name: arg:
184 pkgs.writeShellScriptBin "run"
185 ''
186 export PATH=${pkgs.go}/bin:$PATH
187 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
188 -build.args_bin "${arg}"
189 '';
190 tailwind-watcher =
191 pkgs.writeShellScriptBin "run"
192 ''
193 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
194 '';
195 in {
196 fmt = {
197 type = "app";
198 program = pkgs.lib.getExe packages'.treefmt-wrapper;
199 };
200 watch-appview = {
201 type = "app";
202 program = toString (pkgs.writeShellScript "watch-appview" ''
203 echo "copying static files to appview/pages/static..."
204 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
205 ${air-watcher "appview" ""}/bin/run
206 '');
207 };
208 watch-knot = {
209 type = "app";
210 program = ''${air-watcher "knot" "server"}/bin/run'';
211 };
212 watch-spindle = {
213 type = "app";
214 program = ''${air-watcher "spindle" ""}/bin/run'';
215 };
216 watch-tailwind = {
217 type = "app";
218 program = ''${tailwind-watcher}/bin/run'';
219 };
220 vm = let
221 guestSystem =
222 if pkgs.stdenv.hostPlatform.isAarch64
223 then "aarch64-linux"
224 else "x86_64-linux";
225 in {
226 type = "app";
227 program =
228 (pkgs.writeShellApplication {
229 name = "launch-vm";
230 text = ''
231 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
232 cd "$rootDir"
233
234 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
235
236 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
237 exec ${pkgs.lib.getExe
238 (import ./nix/vm.nix {
239 inherit nixpkgs self;
240 system = guestSystem;
241 hostSystem = system;
242 }).config.system.build.vm}
243 '';
244 })
245 + /bin/launch-vm;
246 };
247 gomod2nix = {
248 type = "app";
249 program = toString (pkgs.writeShellScript "gomod2nix" ''
250 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
251 '');
252 };
253 lexgen = {
254 type = "app";
255 program =
256 (pkgs.writeShellApplication {
257 name = "lexgen";
258 text = ''
259 if ! command -v lexgen > /dev/null; then
260 echo "error: must be executed from devshell"
261 exit 1
262 fi
263
264 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
265 cd "$rootDir"
266
267 rm -f api/tangled/*
268 lexgen --build-file lexicon-build-config.json lexicons
269 sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
270 ${pkgs.gotools}/bin/goimports -w api/tangled/*
271 go run ./cmd/cborgen/
272 lexgen --build-file lexicon-build-config.json lexicons
273 rm api/tangled/*.bak
274 '';
275 })
276 + /bin/lexgen;
277 };
278 });
279
280 nixosModules.appview = {
281 lib,
282 pkgs,
283 ...
284 }: {
285 imports = [./nix/modules/appview.nix];
286
287 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
288 };
289 nixosModules.knot = {
290 lib,
291 pkgs,
292 ...
293 }: {
294 imports = [./nix/modules/knot.nix];
295
296 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
297 };
298 nixosModules.spindle = {
299 lib,
300 pkgs,
301 ...
302 }: {
303 imports = [./nix/modules/spindle.nix];
304
305 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
306 };
307 };
308}