julien.rbrt.fr
forked from
tangled.org/core
Monorepo for Tangled — https://tangled.org
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 gomod2nix = {
7 url = "github:nix-community/gomod2nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 flake-compat = {
11 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
12 flake = false;
13 };
14 indigo = {
15 url = "github:oppiliappan/indigo";
16 flake = false;
17 };
18 htmx-src = {
19 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
20 flake = false;
21 };
22 htmx-ws-src = {
23 # strange errors in consle that i can't really make out
24 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
25 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
26 flake = false;
27 };
28 lucide-src = {
29 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
30 flake = false;
31 };
32 inter-fonts-src = {
33 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
34 flake = false;
35 };
36 actor-typeahead-src = {
37 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
38 flake = false;
39 };
40 ibm-plex-mono-src = {
41 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
42 flake = false;
43 };
44 sqlite-lib-src = {
45 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
46 flake = false;
47 };
48 };
49
50 outputs = {
51 self,
52 nixpkgs,
53 gomod2nix,
54 indigo,
55 htmx-src,
56 htmx-ws-src,
57 lucide-src,
58 inter-fonts-src,
59 sqlite-lib-src,
60 ibm-plex-mono-src,
61 actor-typeahead-src,
62 ...
63 }: let
64 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
65 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
66 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
67
68 mkPackageSet = pkgs:
69 pkgs.lib.makeScope pkgs.newScope (self: {
70 src = let
71 fs = pkgs.lib.fileset;
72 in
73 fs.toSource {
74 root = ./.;
75 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
76 };
77 buildGoApplication =
78 (self.callPackage "${gomod2nix}/builder" {
79 gomod2nix = gomod2nix.legacyPackages.${pkgs.system}.gomod2nix;
80 }).buildGoApplication;
81 modules = ./nix/gomod2nix.toml;
82 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
83 inherit sqlite-lib-src;
84 };
85 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
86 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
87 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
88 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src;
89 };
90 appview = self.callPackage ./nix/pkgs/appview.nix {};
91 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
92 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
93 knot = self.callPackage ./nix/pkgs/knot.nix {};
94 });
95 in {
96 overlays.default = final: prev: {
97 inherit (mkPackageSet final) lexgen goat sqlite-lib spindle knot-unwrapped knot appview;
98 };
99
100 packages = forAllSystems (system: let
101 pkgs = nixpkgsFor.${system};
102 packages = mkPackageSet pkgs;
103 staticPackages = mkPackageSet pkgs.pkgsStatic;
104 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
105 in {
106 inherit (packages) appview appview-static-files lexgen goat spindle knot knot-unwrapped sqlite-lib;
107
108 pkgsStatic-appview = staticPackages.appview;
109 pkgsStatic-knot = staticPackages.knot;
110 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
111 pkgsStatic-spindle = staticPackages.spindle;
112 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
113
114 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
115 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
116 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
117 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
118
119 treefmt-wrapper = pkgs.treefmt.withConfig {
120 settings.formatter = {
121 alejandra = {
122 command = pkgs.lib.getExe pkgs.alejandra;
123 includes = ["*.nix"];
124 };
125
126 gofmt = {
127 command = pkgs.lib.getExe' pkgs.go "gofmt";
128 options = ["-w"];
129 includes = ["*.go"];
130 };
131
132 # prettier = let
133 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
134 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
135 # '';
136 # in {
137 # command = wrapper;
138 # options = ["-w"];
139 # includes = ["*.html"];
140 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
141 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
142 # };
143 };
144 };
145 });
146 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
147 devShells = forAllSystems (system: let
148 pkgs = nixpkgsFor.${system};
149 packages' = self.packages.${system};
150 staticShell = pkgs.mkShell.override {
151 stdenv = pkgs.pkgsStatic.stdenv;
152 };
153 in {
154 default = staticShell {
155 nativeBuildInputs = [
156 pkgs.go
157 pkgs.air
158 pkgs.gopls
159 pkgs.httpie
160 pkgs.litecli
161 pkgs.websocat
162 pkgs.tailwindcss
163 pkgs.nixos-shell
164 pkgs.redis
165 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
166 packages'.lexgen
167 packages'.treefmt-wrapper
168 ];
169 shellHook = ''
170 mkdir -p appview/pages/static
171 # no preserve is needed because watch-tailwind will want to be able to overwrite
172 cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
173 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
174 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
175 '';
176 env.CGO_ENABLED = 1;
177 };
178 });
179 apps = forAllSystems (system: let
180 pkgs = nixpkgsFor."${system}";
181 packages' = self.packages.${system};
182 air-watcher = name: arg:
183 pkgs.writeShellScriptBin "run"
184 ''
185 export PATH=${pkgs.go}/bin:$PATH
186 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
187 -build.args_bin "${arg}"
188 '';
189 tailwind-watcher =
190 pkgs.writeShellScriptBin "run"
191 ''
192 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
193 '';
194 in {
195 fmt = {
196 type = "app";
197 program = pkgs.lib.getExe packages'.treefmt-wrapper;
198 };
199 watch-appview = {
200 type = "app";
201 program = toString (pkgs.writeShellScript "watch-appview" ''
202 echo "copying static files to appview/pages/static..."
203 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
204 ${air-watcher "appview" ""}/bin/run
205 '');
206 };
207 watch-knot = {
208 type = "app";
209 program = ''${air-watcher "knot" "server"}/bin/run'';
210 };
211 watch-spindle = {
212 type = "app";
213 program = ''${air-watcher "spindle" ""}/bin/run'';
214 };
215 watch-tailwind = {
216 type = "app";
217 program = ''${tailwind-watcher}/bin/run'';
218 };
219 vm = let
220 guestSystem =
221 if pkgs.stdenv.hostPlatform.isAarch64
222 then "aarch64-linux"
223 else "x86_64-linux";
224 in {
225 type = "app";
226 program =
227 (pkgs.writeShellApplication {
228 name = "launch-vm";
229 text = ''
230 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
231 cd "$rootDir"
232
233 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
234
235 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
236 exec ${pkgs.lib.getExe
237 (import ./nix/vm.nix {
238 inherit nixpkgs self;
239 system = guestSystem;
240 hostSystem = system;
241 }).config.system.build.vm}
242 '';
243 })
244 + /bin/launch-vm;
245 };
246 gomod2nix = {
247 type = "app";
248 program = toString (pkgs.writeShellScript "gomod2nix" ''
249 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
250 '');
251 };
252 lexgen = {
253 type = "app";
254 program =
255 (pkgs.writeShellApplication {
256 name = "lexgen";
257 text = ''
258 if ! command -v lexgen > /dev/null; then
259 echo "error: must be executed from devshell"
260 exit 1
261 fi
262
263 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
264 cd "$rootDir"
265
266 rm -f api/tangled/*
267 lexgen --build-file lexicon-build-config.json lexicons
268 sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
269 ${pkgs.gotools}/bin/goimports -w api/tangled/*
270 go run ./cmd/cborgen/
271 lexgen --build-file lexicon-build-config.json lexicons
272 rm api/tangled/*.bak
273 '';
274 })
275 + /bin/lexgen;
276 };
277 });
278
279 nixosModules.appview = {
280 lib,
281 pkgs,
282 ...
283 }: {
284 imports = [./nix/modules/appview.nix];
285
286 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
287 };
288 nixosModules.knot = {
289 lib,
290 pkgs,
291 ...
292 }: {
293 imports = [./nix/modules/knot.nix];
294
295 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
296 };
297 nixosModules.spindle = {
298 lib,
299 pkgs,
300 ...
301 }: {
302 imports = [./nix/modules/spindle.nix];
303
304 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
305 };
306 };
307}