julien.rbrt.fr
forked from
tangled.org/core
Monorepo for Tangled — https://tangled.org
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 gomod2nix = {
7 url = "github:nix-community/gomod2nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 indigo = {
11 url = "github:oppiliappan/indigo";
12 flake = false;
13 };
14 htmx-src = {
15 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
16 flake = false;
17 };
18 htmx-ws-src = {
19 # strange errors in consle that i can't really make out
20 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
21 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
22 flake = false;
23 };
24 lucide-src = {
25 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
26 flake = false;
27 };
28 inter-fonts-src = {
29 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
30 flake = false;
31 };
32 ibm-plex-mono-src = {
33 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
34 flake = false;
35 };
36 sqlite-lib-src = {
37 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
38 flake = false;
39 };
40 };
41
42 outputs = {
43 self,
44 nixpkgs,
45 gomod2nix,
46 indigo,
47 htmx-src,
48 htmx-ws-src,
49 lucide-src,
50 inter-fonts-src,
51 sqlite-lib-src,
52 ibm-plex-mono-src,
53 }: let
54 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
55 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
56 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
57
58 mkPackageSet = pkgs:
59 pkgs.lib.makeScope pkgs.newScope (self: {
60 src = let
61 fs = pkgs.lib.fileset;
62 in
63 fs.toSource {
64 root = ./.;
65 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
66 };
67 buildGoApplication =
68 (self.callPackage "${gomod2nix}/builder" {
69 gomod2nix = gomod2nix.legacyPackages.${pkgs.system}.gomod2nix;
70 }).buildGoApplication;
71 modules = ./nix/gomod2nix.toml;
72 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
73 inherit (pkgs) gcc;
74 inherit sqlite-lib-src;
75 };
76 genjwks = self.callPackage ./nix/pkgs/genjwks.nix {};
77 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
78 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
79 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src;
80 };
81 appview = self.callPackage ./nix/pkgs/appview.nix {};
82 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
83 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
84 knot = self.callPackage ./nix/pkgs/knot.nix {};
85 });
86 in {
87 overlays.default = final: prev: {
88 inherit (mkPackageSet final) lexgen sqlite-lib genjwks spindle knot-unwrapped knot appview;
89 };
90
91 packages = forAllSystems (system: let
92 pkgs = nixpkgsFor.${system};
93 packages = mkPackageSet pkgs;
94 staticPackages = mkPackageSet pkgs.pkgsStatic;
95 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
96 in {
97 inherit (packages) appview appview-static-files lexgen genjwks spindle knot knot-unwrapped sqlite-lib;
98
99 pkgsStatic-appview = staticPackages.appview;
100 pkgsStatic-knot = staticPackages.knot;
101 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
102 pkgsStatic-spindle = staticPackages.spindle;
103 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
104
105 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
106 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
107 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
108 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
109 });
110 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
111 formatter = forAllSystems (system: nixpkgsFor.${system}.alejandra);
112 devShells = forAllSystems (system: let
113 pkgs = nixpkgsFor.${system};
114 packages' = self.packages.${system};
115 staticShell = pkgs.mkShell.override {
116 stdenv = pkgs.pkgsStatic.stdenv;
117 };
118 in {
119 default = staticShell {
120 nativeBuildInputs = [
121 pkgs.go
122 pkgs.air
123 pkgs.gopls
124 pkgs.httpie
125 pkgs.litecli
126 pkgs.websocat
127 pkgs.tailwindcss
128 pkgs.nixos-shell
129 pkgs.redis
130 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
131 packages'.lexgen
132 ];
133 shellHook = ''
134 mkdir -p appview/pages/static
135 # no preserve is needed because watch-tailwind will want to be able to overwrite
136 cp -frv --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
137 export TANGLED_OAUTH_JWKS="$(${packages'.genjwks}/bin/genjwks)"
138 '';
139 env.CGO_ENABLED = 1;
140 };
141 });
142 apps = forAllSystems (system: let
143 pkgs = nixpkgsFor."${system}";
144 packages' = self.packages.${system};
145 air-watcher = name: arg:
146 pkgs.writeShellScriptBin "run"
147 ''
148 ${pkgs.air}/bin/air -c /dev/null \
149 -build.cmd "${pkgs.go}/bin/go build -o ./out/${name}.out ./cmd/${name}/main.go" \
150 -build.bin "./out/${name}.out" \
151 -build.args_bin "${arg}" \
152 -build.stop_on_error "true" \
153 -build.include_ext "go"
154 '';
155 tailwind-watcher =
156 pkgs.writeShellScriptBin "run"
157 ''
158 ${pkgs.tailwindcss}/bin/tailwindcss -w -i input.css -o ./appview/pages/static/tw.css
159 '';
160 in {
161 watch-appview = {
162 type = "app";
163 program = toString (pkgs.writeShellScript "watch-appview" ''
164 echo "copying static files to appview/pages/static..."
165 ${pkgs.coreutils}/bin/cp -frv --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
166 ${air-watcher "appview" ""}/bin/run
167 '');
168 };
169 watch-knot = {
170 type = "app";
171 program = ''${air-watcher "knot" "server"}/bin/run'';
172 };
173 watch-tailwind = {
174 type = "app";
175 program = ''${tailwind-watcher}/bin/run'';
176 };
177 vm = let
178 system =
179 if pkgs.stdenv.hostPlatform.isAarch64
180 then "aarch64"
181 else "x86_64";
182
183 nixos-shell = pkgs.nixos-shell.overrideAttrs (old: {
184 patches =
185 (old.patches or [])
186 ++ [
187 # https://github.com/Mic92/nixos-shell/pull/94
188 (pkgs.fetchpatch {
189 name = "fix-foreign-vm.patch";
190 url = "https://github.com/Mic92/nixos-shell/commit/113e4cc55ae236b5b0b1fbd8b321e9b67c77580e.patch";
191 hash = "sha256-eauetBK0wXAOcd9PYbExokNCiwz2QyFnZ4FnwGi9VCo=";
192 })
193 ];
194 });
195 in {
196 type = "app";
197 program = toString (pkgs.writeShellScript "vm" ''
198 ${nixos-shell}/bin/nixos-shell --flake .#vm-${system} --guest-system ${system}-linux
199 '');
200 };
201 gomod2nix = {
202 type = "app";
203 program = toString (pkgs.writeShellScript "gomod2nix" ''
204 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
205 '');
206 };
207 lexgen = {
208 type = "app";
209 program =
210 (pkgs.writeShellApplication {
211 name = "lexgen";
212 text = ''
213 if ! command -v lexgen > /dev/null; then
214 echo "error: must be executed from devshell"
215 exit 1
216 fi
217
218 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
219 cd "$rootDir"
220
221 rm api/tangled/*
222 lexgen --build-file lexicon-build-config.json lexicons
223 sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
224 ${pkgs.gotools}/bin/goimports -w api/tangled/*
225 go run cmd/gen.go
226 lexgen --build-file lexicon-build-config.json lexicons
227 rm api/tangled/*.bak
228 '';
229 })
230 + /bin/lexgen;
231 };
232 });
233
234 nixosModules.appview = {
235 lib,
236 pkgs,
237 ...
238 }: {
239 imports = [./nix/modules/appview.nix];
240
241 services.tangled-appview.package = lib.mkDefault self.packages.${pkgs.system}.appview;
242 };
243 nixosModules.knot = {
244 lib,
245 pkgs,
246 ...
247 }: {
248 imports = [./nix/modules/knot.nix];
249
250 services.tangled-knot.package = lib.mkDefault self.packages.${pkgs.system}.knot;
251 };
252 nixosModules.spindle = {
253 lib,
254 pkgs,
255 ...
256 }: {
257 imports = [./nix/modules/spindle.nix];
258
259 services.tangled-spindle.package = lib.mkDefault self.packages.${pkgs.system}.spindle;
260 };
261 nixosConfigurations.vm-x86_64 = import ./nix/vm.nix {
262 inherit self nixpkgs;
263 system = "x86_64-linux";
264 };
265 nixosConfigurations.vm-aarch64 = import ./nix/vm.nix {
266 inherit self nixpkgs;
267 system = "aarch64-linux";
268 };
269 };
270}