julien.rbrt.fr
forked from
tangled.org/core
Monorepo for Tangled — https://tangled.org
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 gomod2nix = {
7 url = "github:nix-community/gomod2nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 indigo = {
11 url = "github:oppiliappan/indigo";
12 flake = false;
13 };
14 htmx-src = {
15 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
16 flake = false;
17 };
18 htmx-ws-src = {
19 # strange errors in consle that i can't really make out
20 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
21 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
22 flake = false;
23 };
24 lucide-src = {
25 url = "https://github.com/lucide-icons/lucide/releases/download/0.483.0/lucide-icons-0.483.0.zip";
26 flake = false;
27 };
28 inter-fonts-src = {
29 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
30 flake = false;
31 };
32 ibm-plex-mono-src = {
33 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
34 flake = false;
35 };
36 sqlite-lib-src = {
37 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
38 flake = false;
39 };
40 gitignore = {
41 url = "github:hercules-ci/gitignore.nix";
42 inputs.nixpkgs.follows = "nixpkgs";
43 };
44 };
45
46 outputs = {
47 self,
48 nixpkgs,
49 gomod2nix,
50 indigo,
51 htmx-src,
52 htmx-ws-src,
53 lucide-src,
54 gitignore,
55 inter-fonts-src,
56 sqlite-lib-src,
57 ibm-plex-mono-src,
58 }: let
59 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
60 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
61 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
62
63 mkPackageSet = pkgs:
64 pkgs.lib.makeScope pkgs.newScope (self: {
65 inherit (gitignore.lib) gitignoreSource;
66 inherit (gomod2nix.legacyPackages.${pkgs.system}) buildGoApplication;
67 modules = ./nix/gomod2nix.toml;
68 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
69 inherit (pkgs) gcc;
70 inherit sqlite-lib-src;
71 };
72 genjwks = self.callPackage ./nix/pkgs/genjwks.nix {};
73 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
74 appview = self.callPackage ./nix/pkgs/appview.nix {
75 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src;
76 };
77 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
78 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
79 knot = self.callPackage ./nix/pkgs/knot.nix {};
80 });
81 in {
82 overlays.default = final: prev: {
83 inherit (mkPackageSet final) lexgen sqlite-lib genjwks spindle knot-unwrapped knot appview;
84 };
85
86 packages = forAllSystems (system: let
87 pkgs = nixpkgsFor.${system};
88 packages = mkPackageSet pkgs;
89 staticPackages = mkPackageSet pkgs.pkgsStatic;
90 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
91 in {
92 appview = packages.appview;
93 lexgen = packages.lexgen;
94 knot = packages.knot;
95 knot-unwrapped = packages.knot-unwrapped;
96 spindle = packages.spindle;
97 genjwks = packages.genjwks;
98 sqlite-lib = packages.sqlite-lib;
99
100 pkgsStatic-appview = staticPackages.appview;
101 pkgsStatic-knot = staticPackages.knot;
102 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
103 pkgsStatic-spindle = staticPackages.spindle;
104 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
105
106 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
107 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
108 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
109 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
110 });
111 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
112 formatter = forAllSystems (system: nixpkgsFor.${system}.alejandra);
113 devShells = forAllSystems (system: let
114 pkgs = nixpkgsFor.${system};
115 packages' = self.packages.${system};
116 staticShell = pkgs.mkShell.override {
117 stdenv = pkgs.pkgsStatic.stdenv;
118 };
119 in {
120 default = staticShell {
121 nativeBuildInputs = [
122 pkgs.go
123 pkgs.air
124 pkgs.gopls
125 pkgs.httpie
126 pkgs.litecli
127 pkgs.websocat
128 pkgs.tailwindcss
129 pkgs.nixos-shell
130 pkgs.redis
131 packages'.lexgen
132 ];
133 shellHook = ''
134 mkdir -p appview/pages/static/{fonts,icons}
135 cp -f ${htmx-src} appview/pages/static/htmx.min.js
136 cp -f ${htmx-ws-src} appview/pages/static/htmx-ext-ws.min.js
137 cp -rf ${lucide-src}/*.svg appview/pages/static/icons/
138 cp -f ${inter-fonts-src}/web/InterVariable*.woff2 appview/pages/static/fonts/
139 cp -f ${inter-fonts-src}/web/InterDisplay*.woff2 appview/pages/static/fonts/
140 cp -f ${ibm-plex-mono-src}/fonts/complete/woff2/IBMPlexMono-Regular.woff2 appview/pages/static/fonts/
141 export TANGLED_OAUTH_JWKS="$(${packages'.genjwks}/bin/genjwks)"
142 '';
143 env.CGO_ENABLED = 1;
144 };
145 });
146 apps = forAllSystems (system: let
147 pkgs = nixpkgsFor."${system}";
148 air-watcher = name: arg:
149 pkgs.writeShellScriptBin "run"
150 ''
151 ${pkgs.air}/bin/air -c /dev/null \
152 -build.cmd "${pkgs.go}/bin/go build -o ./out/${name}.out ./cmd/${name}/main.go" \
153 -build.bin "./out/${name}.out ${arg}" \
154 -build.stop_on_error "true" \
155 -build.include_ext "go"
156 '';
157 tailwind-watcher =
158 pkgs.writeShellScriptBin "run"
159 ''
160 ${pkgs.tailwindcss}/bin/tailwindcss -w -i input.css -o ./appview/pages/static/tw.css
161 '';
162 in {
163 watch-appview = {
164 type = "app";
165 program = ''${air-watcher "appview" ""}/bin/run'';
166 };
167 watch-knot = {
168 type = "app";
169 program = ''${air-watcher "knot" "server"}/bin/run'';
170 };
171 watch-tailwind = {
172 type = "app";
173 program = ''${tailwind-watcher}/bin/run'';
174 };
175 vm = {
176 type = "app";
177 program = toString (pkgs.writeShellScript "vm" ''
178 ${pkgs.nixos-shell}/bin/nixos-shell --flake .#vm
179 '');
180 };
181 gomod2nix = {
182 type = "app";
183 program = toString (pkgs.writeShellScript "gomod2nix" ''
184 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
185 '');
186 };
187 });
188
189 nixosModules.appview = import ./nix/modules/appview.nix {inherit self;};
190 nixosModules.knot = import ./nix/modules/knot.nix {inherit self;};
191 nixosModules.spindle = import ./nix/modules/spindle.nix {inherit self;};
192 nixosConfigurations.vm = import ./nix/vm.nix {inherit self nixpkgs;};
193 };
194}