julien.rbrt.fr
forked from
tangled.org/core
Monorepo for Tangled — https://tangled.org
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 indigo = {
7 url = "github:oppiliappan/indigo";
8 flake = false;
9 };
10 htmx-src = {
11 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
12 flake = false;
13 };
14 htmx-ws-src = {
15 # strange errors in consle that i can't really make out
16 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
17 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
18 flake = false;
19 };
20 lucide-src = {
21 url = "https://github.com/lucide-icons/lucide/releases/download/0.483.0/lucide-icons-0.483.0.zip";
22 flake = false;
23 };
24 inter-fonts-src = {
25 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
26 flake = false;
27 };
28 ibm-plex-mono-src = {
29 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
30 flake = false;
31 };
32 sqlite-lib-src = {
33 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
34 flake = false;
35 };
36 gitignore = {
37 url = "github:hercules-ci/gitignore.nix";
38 inputs.nixpkgs.follows = "nixpkgs";
39 };
40 };
41
42 outputs = {
43 self,
44 nixpkgs,
45 indigo,
46 htmx-src,
47 htmx-ws-src,
48 lucide-src,
49 gitignore,
50 inter-fonts-src,
51 sqlite-lib-src,
52 ibm-plex-mono-src,
53 }: let
54 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
55 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
56 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
57 inherit (gitignore.lib) gitignoreSource;
58 mkPackageSet = pkgs: let
59 goModHash = "sha256-SLi+nALwCd/Lzn3aljwPqCo2UaM9hl/4OAjcHQLt2Bk=";
60 sqlite-lib = pkgs.callPackage ./nix/pkgs/sqlite-lib.nix {
61 inherit (pkgs) gcc;
62 inherit sqlite-lib-src;
63 };
64 genjwks = pkgs.callPackage ./nix/pkgs/genjwks.nix {inherit goModHash gitignoreSource;};
65 lexgen = pkgs.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
66 appview = pkgs.callPackage ./nix/pkgs/appview.nix {
67 inherit sqlite-lib htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src goModHash gitignoreSource;
68 };
69 spindle = pkgs.callPackage ./nix/pkgs/spindle.nix {inherit sqlite-lib goModHash gitignoreSource;};
70 knot-unwrapped = pkgs.callPackage ./nix/pkgs/knot-unwrapped.nix {inherit sqlite-lib goModHash gitignoreSource;};
71 knot = pkgs.callPackage ./nix/pkgs/knot.nix {inherit knot-unwrapped;};
72 in {
73 inherit lexgen appview spindle knot-unwrapped knot sqlite-lib genjwks;
74 };
75 in {
76 overlays.default = final: prev: mkPackageSet final;
77
78 packages = forAllSystems (system: let
79 pkgs = nixpkgsFor.${system};
80 packages = mkPackageSet pkgs;
81 staticPackages = mkPackageSet pkgs.pkgsStatic;
82 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
83 in {
84 appview = packages.appview;
85 lexgen = packages.lexgen;
86 knot = packages.knot;
87 knot-unwrapped = packages.knot-unwrapped;
88 spindle = packages.spindle;
89 genjwks = packages.genjwks;
90 sqlite-lib = packages.sqlite-lib;
91
92 pkgsStatic-appview = staticPackages.appview;
93 pkgsStatic-knot = staticPackages.knot;
94 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
95 pkgsStatic-spindle = staticPackages.spindle;
96 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
97
98 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
99 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
100 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
101 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
102 });
103 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
104 formatter = forAllSystems (system: nixpkgsFor.${system}.alejandra);
105 devShells = forAllSystems (system: let
106 pkgs = nixpkgsFor.${system};
107 packages' = self.packages.${system};
108 staticShell = pkgs.mkShell.override {
109 stdenv = pkgs.pkgsStatic.stdenv;
110 };
111 in {
112 default = staticShell {
113 nativeBuildInputs = [
114 pkgs.go
115 pkgs.air
116 pkgs.gopls
117 pkgs.httpie
118 pkgs.litecli
119 pkgs.websocat
120 pkgs.tailwindcss
121 pkgs.nixos-shell
122 pkgs.redis
123 packages'.lexgen
124 ];
125 shellHook = ''
126 mkdir -p appview/pages/static/{fonts,icons}
127 cp -f ${htmx-src} appview/pages/static/htmx.min.js
128 cp -f ${htmx-ws-src} appview/pages/static/htmx-ext-ws.min.js
129 cp -rf ${lucide-src}/*.svg appview/pages/static/icons/
130 cp -f ${inter-fonts-src}/web/InterVariable*.woff2 appview/pages/static/fonts/
131 cp -f ${inter-fonts-src}/web/InterDisplay*.woff2 appview/pages/static/fonts/
132 cp -f ${ibm-plex-mono-src}/fonts/complete/woff2/IBMPlexMono-Regular.woff2 appview/pages/static/fonts/
133 export TANGLED_OAUTH_JWKS="$(${packages'.genjwks}/bin/genjwks)"
134 '';
135 env.CGO_ENABLED = 1;
136 };
137 });
138 apps = forAllSystems (system: let
139 pkgs = nixpkgsFor."${system}";
140 air-watcher = name: arg:
141 pkgs.writeShellScriptBin "run"
142 ''
143 ${pkgs.air}/bin/air -c /dev/null \
144 -build.cmd "${pkgs.go}/bin/go build -o ./out/${name}.out ./cmd/${name}/main.go" \
145 -build.bin "./out/${name}.out ${arg}" \
146 -build.stop_on_error "true" \
147 -build.include_ext "go"
148 '';
149 tailwind-watcher =
150 pkgs.writeShellScriptBin "run"
151 ''
152 ${pkgs.tailwindcss}/bin/tailwindcss -w -i input.css -o ./appview/pages/static/tw.css
153 '';
154 in {
155 watch-appview = {
156 type = "app";
157 program = ''${air-watcher "appview" ""}/bin/run'';
158 };
159 watch-knot = {
160 type = "app";
161 program = ''${air-watcher "knot" "server"}/bin/run'';
162 };
163 watch-tailwind = {
164 type = "app";
165 program = ''${tailwind-watcher}/bin/run'';
166 };
167 vm = {
168 type = "app";
169 program = toString (pkgs.writeShellScript "vm" ''
170 ${pkgs.nixos-shell}/bin/nixos-shell --flake .#vm
171 '');
172 };
173 });
174
175 nixosModules.appview = import ./nix/modules/appview.nix {inherit self;};
176 nixosModules.knot = import ./nix/modules/knot.nix {inherit self;};
177 nixosModules.spindle = import ./nix/modules/spindle.nix {inherit self;};
178 nixosConfigurations.vm = import ./nix/vm.nix {inherit self nixpkgs;};
179 };
180}