kot.pink
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 gomod2nix = {
7 url = "github:nix-community/gomod2nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 flake-compat = {
11 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
12 flake = false;
13 };
14 indigo = {
15 url = "github:oppiliappan/indigo";
16 flake = false;
17 };
18 htmx-src = {
19 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
20 flake = false;
21 };
22 htmx-ws-src = {
23 # strange errors in consle that i can't really make out
24 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
25 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
26 flake = false;
27 };
28 lucide-src = {
29 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
30 flake = false;
31 };
32 inter-fonts-src = {
33 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
34 flake = false;
35 };
36 actor-typeahead-src = {
37 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
38 flake = false;
39 };
40 ibm-plex-mono-src = {
41 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
42 flake = false;
43 };
44 sqlite-lib-src = {
45 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
46 flake = false;
47 };
48 };
49
50 outputs = {
51 self,
52 nixpkgs,
53 gomod2nix,
54 indigo,
55 htmx-src,
56 htmx-ws-src,
57 lucide-src,
58 inter-fonts-src,
59 sqlite-lib-src,
60 ibm-plex-mono-src,
61 actor-typeahead-src,
62 ...
63 }: let
64 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
65 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
66 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
67
68 mkPackageSet = pkgs:
69 pkgs.lib.makeScope pkgs.newScope (self: {
70 src = let
71 fs = pkgs.lib.fileset;
72 in
73 fs.toSource {
74 root = ./.;
75 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
76 };
77 buildGoApplication =
78 (self.callPackage "${gomod2nix}/builder" {
79 gomod2nix = gomod2nix.legacyPackages.${pkgs.system}.gomod2nix;
80 }).buildGoApplication;
81 modules = ./nix/gomod2nix.toml;
82 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
83 inherit (pkgs) gcc;
84 inherit sqlite-lib-src;
85 };
86 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
87 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
88 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
89 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src;
90 };
91 appview = self.callPackage ./nix/pkgs/appview.nix {};
92 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
93 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
94 knot = self.callPackage ./nix/pkgs/knot.nix {};
95 });
96 in {
97 overlays.default = final: prev: {
98 inherit (mkPackageSet final) lexgen goat sqlite-lib spindle knot-unwrapped knot appview;
99 };
100
101 packages = forAllSystems (system: let
102 pkgs = nixpkgsFor.${system};
103 packages = mkPackageSet pkgs;
104 staticPackages = mkPackageSet pkgs.pkgsStatic;
105 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
106 in {
107 inherit (packages) appview appview-static-files lexgen goat spindle knot knot-unwrapped sqlite-lib;
108
109 pkgsStatic-appview = staticPackages.appview;
110 pkgsStatic-knot = staticPackages.knot;
111 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
112 pkgsStatic-spindle = staticPackages.spindle;
113 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
114
115 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
116 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
117 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
118 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
119
120 treefmt-wrapper = pkgs.treefmt.withConfig {
121 settings.formatter = {
122 alejandra = {
123 command = pkgs.lib.getExe pkgs.alejandra;
124 includes = ["*.nix"];
125 };
126
127 gofmt = {
128 command = pkgs.lib.getExe' pkgs.go "gofmt";
129 options = ["-w"];
130 includes = ["*.go"];
131 };
132
133 # prettier = let
134 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
135 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
136 # '';
137 # in {
138 # command = wrapper;
139 # options = ["-w"];
140 # includes = ["*.html"];
141 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
142 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
143 # };
144 };
145 };
146 });
147 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
148 devShells = forAllSystems (system: let
149 pkgs = nixpkgsFor.${system};
150 packages' = self.packages.${system};
151 staticShell = pkgs.mkShell.override {
152 stdenv = pkgs.pkgsStatic.stdenv;
153 };
154 in {
155 default = staticShell {
156 nativeBuildInputs = [
157 pkgs.go
158 pkgs.air
159 pkgs.tilt
160 pkgs.gopls
161 pkgs.httpie
162 pkgs.litecli
163 pkgs.websocat
164 pkgs.tailwindcss
165 pkgs.nixos-shell
166 pkgs.redis
167 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
168 packages'.lexgen
169 packages'.treefmt-wrapper
170 ];
171 shellHook = ''
172 mkdir -p appview/pages/static
173 # no preserve is needed because watch-tailwind will want to be able to overwrite
174 cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
175 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
176 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
177 '';
178 env.CGO_ENABLED = 1;
179 };
180 });
181 apps = forAllSystems (system: let
182 pkgs = nixpkgsFor."${system}";
183 packages' = self.packages.${system};
184 air-watcher = name: arg:
185 pkgs.writeShellScriptBin "run"
186 ''
187 ${pkgs.air}/bin/air -c /dev/null \
188 -build.cmd "${pkgs.go}/bin/go build -o ./out/${name}.out ./cmd/${name}/main.go" \
189 -build.bin "./out/${name}.out" \
190 -build.args_bin "${arg}" \
191 -build.stop_on_error "true" \
192 -build.include_ext "go"
193 '';
194 tailwind-watcher =
195 pkgs.writeShellScriptBin "run"
196 ''
197 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
198 '';
199 in {
200 fmt = {
201 type = "app";
202 program = pkgs.lib.getExe packages'.treefmt-wrapper;
203 };
204 watch-appview = {
205 type = "app";
206 program = toString (pkgs.writeShellScript "watch-appview" ''
207 echo "copying static files to appview/pages/static..."
208 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
209 ${air-watcher "appview" ""}/bin/run
210 '');
211 };
212 watch-knot = {
213 type = "app";
214 program = ''${air-watcher "knot" "server"}/bin/run'';
215 };
216 watch-spindle = {
217 type = "app";
218 program = ''${air-watcher "spindle" ""}/bin/run'';
219 };
220 watch-tailwind = {
221 type = "app";
222 program = ''${tailwind-watcher}/bin/run'';
223 };
224 vm = let
225 guestSystem =
226 if pkgs.stdenv.hostPlatform.isAarch64
227 then "aarch64-linux"
228 else "x86_64-linux";
229 in {
230 type = "app";
231 program =
232 (pkgs.writeShellApplication {
233 name = "launch-vm";
234 text = ''
235 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
236 cd "$rootDir"
237
238 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
239
240 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
241 exec ${pkgs.lib.getExe
242 (import ./nix/vm.nix {
243 inherit nixpkgs self;
244 system = guestSystem;
245 hostSystem = system;
246 }).config.system.build.vm}
247 '';
248 })
249 + /bin/launch-vm;
250 };
251 gomod2nix = {
252 type = "app";
253 program = toString (pkgs.writeShellScript "gomod2nix" ''
254 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
255 '');
256 };
257 lexgen = {
258 type = "app";
259 program =
260 (pkgs.writeShellApplication {
261 name = "lexgen";
262 text = ''
263 if ! command -v lexgen > /dev/null; then
264 echo "error: must be executed from devshell"
265 exit 1
266 fi
267
268 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
269 cd "$rootDir"
270
271 rm -f api/tangled/*
272 lexgen --build-file lexicon-build-config.json lexicons
273 sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
274 ${pkgs.gotools}/bin/goimports -w api/tangled/*
275 go run ./cmd/cborgen/
276 lexgen --build-file lexicon-build-config.json lexicons
277 rm api/tangled/*.bak
278 '';
279 })
280 + /bin/lexgen;
281 };
282 });
283
284 nixosModules.appview = {
285 lib,
286 pkgs,
287 ...
288 }: {
289 imports = [./nix/modules/appview.nix];
290
291 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.system}.appview;
292 };
293 nixosModules.knot = {
294 lib,
295 pkgs,
296 ...
297 }: {
298 imports = [./nix/modules/knot.nix];
299
300 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.system}.knot;
301 };
302 nixosModules.spindle = {
303 lib,
304 pkgs,
305 ...
306 }: {
307 imports = [./nix/modules/spindle.nix];
308
309 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.system}.spindle;
310 };
311 };
312}