{
  description = "Cyclamen: Nel's NixOS and Home Manager nix flake";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    home-manager = {
      url = "github:nix-community/home-manager/master";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    wrappers = {
      url = "github:lassulus/wrappers";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    nixpkgs,
    home-manager,
    ...
  } @ inputs: let
    lib = nixpkgs.lib;
    forAllSystems = function:
      lib.genAttrs lib.systems.flakeExposed (
        system: (function system nixpkgs.legacyPackages.${system})
      );
  in {
    homeConfigurations."nel" = home-manager.lib.homeManagerConfiguration {
      pkgs = nixpkgs.legacyPackages."x86_64-linux";
      extraSpecialArgs = { inherit inputs; };
      modules = [ ./homes/nel/default.nix ];
    };

    nixosConfigurations."nel-desktop" = nixpkgs.lib.nixosSystem {
      specialArgs = { inherit inputs; };
      modules = [ ./systems/nel-desktop/configuration.nix ];
    };

    devShells = forAllSystems (system: pkgs: {
      rust = (pkgs.callPackage ./templates/rust/shell.nix { });
    });

    templates = {
      rust = {
        path = ./templates/rust;
        description = "Basic rust project with nix";
      };
    };
  };
}