Microkernel thing OS experiment (Zig ⚡)
pci.express
1const common = @import("root.zig");
2const paging = common.mm.paging;
3const std = @import("std");
4const elf = std.elf;
5const log = std.log.scoped(.elf_loader);
6
7// Load root task, return the entry point
8pub fn loadRootTask() !usize {
9 const root_task = common.init_data.root_task;
10 const hdr = blk: {
11 const hdr: *elf.Elf64_Ehdr = @ptrCast(root_task);
12 break :blk elf.Header.init(hdr.*, .little);
13 };
14 var iter = hdr.iterateProgramHeadersBuffer(root_task);
15 while (try iter.next()) |entry| {
16 if ((entry.p_type != elf.PT_LOAD) or (entry.p_memsz == 0)) continue;
17
18 // 1. Allocate pages to back this allocation
19 const real_vaddr = std.mem.alignBackward(usize, entry.p_vaddr, std.heap.pageSize());
20 const vaddr_shift = entry.p_vaddr - real_vaddr;
21 const memsz_pages = std.mem.alignForward(usize, vaddr_shift + entry.p_memsz, std.heap.pageSize());
22
23 const page_backing = try common.init_data.bootmem.allocPhys(memsz_pages);
24 try paging.mapPhys(.{
25 .vaddr = real_vaddr,
26 .paddr = page_backing,
27 .size = memsz_pages,
28 .memory_type = .MemoryWriteBack,
29 .perms = .{
30 .executable = entry.p_flags & elf.PF_X > 0,
31 .writable = entry.p_flags & elf.PF_W > 0,
32 .userspace_accessible = true,
33 },
34 });
35
36 // 2. Copy filesz bytes from offset to this new page
37 const dst = common.mm.physToHHDM([*]u8, page_backing + vaddr_shift);
38 const dst_slice = dst[0..entry.p_filesz];
39
40 const src_slice = root_task[entry.p_offset..][0..entry.p_filesz];
41 @memcpy(dst_slice, src_slice);
42
43 // 3. Add memsz - filesz zeroes
44 const zero_slice = dst[entry.p_filesz..entry.p_memsz];
45 @memset(zero_slice, 0);
46 }
47
48 // Return the entry point
49 return hdr.entry;
50}