Microkernel thing OS experiment (Zig ⚡)
pci.express
1const common = @import("root.zig");
2const arch = @import("arch");
3const paging = common.mm.paging;
4const std = @import("std");
5const elf = std.elf;
6const log = std.log.scoped(.elf_loader);
7
8// Load root task, return the entry point
9pub fn loadElf(context: *arch.mm.paging.Context, task_slice: []align(4096) u8) !usize {
10 const hdr = blk: {
11 const hdr: *elf.Elf64_Ehdr = @ptrCast(task_slice);
12 break :blk elf.Header.init(hdr.*, .little);
13 };
14 var iter = hdr.iterateProgramHeadersBuffer(task_slice);
15 while (try iter.next()) |entry| {
16 if ((entry.p_type != elf.PT_LOAD) or (entry.p_memsz == 0)) continue;
17
18 // 1. Allocate pages to back this allocation
19 const real_vaddr = std.mem.alignBackward(usize, entry.p_vaddr, std.heap.pageSize());
20 const vaddr_shift = entry.p_vaddr - real_vaddr;
21 const memsz_pages = std.mem.alignForward(usize, vaddr_shift + entry.p_memsz, std.heap.pageSize());
22
23 const page_backing = try common.init_data.bootmem.allocPhys(memsz_pages);
24 try paging.mapPhys(.{
25 .vaddr = real_vaddr,
26 .paddr = page_backing,
27 .size = memsz_pages,
28 .memory_type = .MemoryWriteBack,
29 .perms = .{
30 .x = entry.p_flags & elf.PF_X > 0,
31 .w = entry.p_flags & elf.PF_W > 0,
32 .u = true,
33 },
34 .context = context,
35 });
36
37 // 2. Copy filesz bytes from offset to this new page
38 const dst = common.mm.physToHHDM([*]u8, page_backing + vaddr_shift);
39 const dst_slice = dst[0..entry.p_filesz];
40
41 const src_slice = task_slice[entry.p_offset..][0..entry.p_filesz];
42 @memcpy(dst_slice, src_slice);
43
44 // 3. Add memsz - filesz zeroes
45 const zero_slice = dst[entry.p_filesz..entry.p_memsz];
46 @memset(zero_slice, 0);
47 }
48
49 // Return the entry point
50 return hdr.entry;
51}