pyrox.dev
1# This module provides the proprietary NVIDIA X11 / OpenGL drivers.
2
3{ config, lib, pkgs, pkgs_i686, ... }:
4
5with lib;
6
7let
8
9 drivers = config.services.xserver.videoDrivers;
10
11 # FIXME: should introduce an option like
12 # ‘hardware.video.nvidia.package’ for overriding the default NVIDIA
13 # driver.
14 nvidiaForKernel = kernelPackages:
15 if elem "nvidia" drivers then
16 kernelPackages.nvidia_x11
17 else if elem "nvidiaLegacy173" drivers then
18 kernelPackages.nvidia_x11_legacy173
19 else if elem "nvidiaLegacy304" drivers then
20 kernelPackages.nvidia_x11_legacy304
21 else if elem "nvidiaLegacy340" drivers then
22 kernelPackages.nvidia_x11_legacy340
23 else null;
24
25 nvidia_x11 = nvidiaForKernel config.boot.kernelPackages;
26 nvidia_libs32 = (nvidiaForKernel pkgs_i686.linuxPackages).override { libsOnly = true; kernel = null; };
27
28 enabled = nvidia_x11 != null;
29in
30
31{
32
33 config = mkIf enabled {
34
35 services.xserver.drivers = singleton
36 { name = "nvidia"; modules = [ nvidia_x11 ]; libPath = [ nvidia_x11 ]; };
37
38 services.xserver.screenSection =
39 ''
40 Option "RandRRotation" "on"
41 '';
42
43 hardware.opengl.package = nvidia_x11;
44 hardware.opengl.package32 = nvidia_libs32;
45
46 environment.systemPackages = [ nvidia_x11 ];
47
48 boot.extraModulePackages = [ nvidia_x11 ];
49
50 # nvidia-uvm is required by CUDA applications.
51 boot.kernelModules = [ "nvidia-uvm" ];
52
53 # Create /dev/nvidia-uvm when the nvidia-uvm module is loaded.
54 services.udev.extraRules =
55 ''
56 KERNEL=="nvidia_uvm", RUN+="${pkgs.stdenv.shell} -c 'mknod -m 666 /dev/nvidia-uvm c $(grep nvidia-uvm /proc/devices | cut -d \ -f 1) 0'"
57 '';
58
59 boot.blacklistedKernelModules = [ "nouveau" "nvidiafb" ];
60
61 services.acpid.enable = true;
62
63 environment.etc."OpenCL/vendors/nvidia.icd".source = "${nvidia_x11}/lib/vendors/nvidia.icd";
64
65 };
66
67}