pyrox.dev
1# This module provides the proprietary NVIDIA X11 / OpenGL drivers.
2
3{ config, lib, pkgs, pkgs_i686, ... }:
4
5with lib;
6
7let
8
9 drivers = config.services.xserver.videoDrivers;
10
11 # FIXME: should introduce an option like
12 # ‘hardware.video.nvidia.package’ for overriding the default NVIDIA
13 # driver.
14 nvidiaForKernel = kernelPackages:
15 if elem "nvidia" drivers then
16 kernelPackages.nvidia_x11
17 else if elem "nvidiaBeta" drivers then
18 kernelPackages.nvidia_x11_beta
19 else if elem "nvidiaLegacy173" drivers then
20 kernelPackages.nvidia_x11_legacy173
21 else if elem "nvidiaLegacy304" drivers then
22 kernelPackages.nvidia_x11_legacy304
23 else if elem "nvidiaLegacy340" drivers then
24 kernelPackages.nvidia_x11_legacy340
25 else null;
26
27 nvidia_x11 = nvidiaForKernel config.boot.kernelPackages;
28 nvidia_libs32 = (nvidiaForKernel pkgs_i686.linuxPackages).override { libsOnly = true; kernel = null; };
29
30 enabled = nvidia_x11 != null;
31in
32
33{
34
35 config = mkIf enabled {
36
37 services.xserver.drivers = singleton
38 { name = "nvidia"; modules = [ nvidia_x11 ]; libPath = [ nvidia_x11 ]; };
39
40 services.xserver.screenSection =
41 ''
42 Option "RandRRotation" "on"
43 '';
44
45 hardware.opengl.package = nvidia_x11;
46 hardware.opengl.package32 = nvidia_libs32;
47
48 environment.systemPackages = [ nvidia_x11 ];
49
50 boot.extraModulePackages = [ nvidia_x11 ];
51
52 # nvidia-uvm is required by CUDA applications.
53 boot.kernelModules = [ "nvidia-uvm" ];
54
55 # Create /dev/nvidia-uvm when the nvidia-uvm module is loaded.
56 services.udev.extraRules =
57 ''
58 KERNEL=="nvidia_uvm", RUN+="${pkgs.stdenv.shell} -c 'mknod -m 666 /dev/nvidia-uvm c $(grep nvidia-uvm /proc/devices | cut -d \ -f 1) 0'"
59 '';
60
61 boot.blacklistedKernelModules = [ "nouveau" "nvidiafb" ];
62
63 services.acpid.enable = true;
64
65 environment.etc."OpenCL/vendors/nvidia.icd".source = "${nvidia_x11}/lib/vendors/nvidia.icd";
66
67 };
68
69}