pyrox.dev
1# This jobset defines the main NixOS channels (such as nixos-unstable
2# and nixos-14.04). The channel is updated every time the ‘tested’ job
3# succeeds, and all other jobs have finished (they may fail).
4
5{ nixpkgs ? { outPath = ./..; revCount = 56789; shortRev = "gfedcba"; }
6, stableBranch ? false
7, supportedSystems ? [ "x86_64-linux" "i686-linux" ]
8}:
9
10let
11
12 nixpkgsSrc = nixpkgs; # urgh
13
14 pkgs = import ./.. {};
15
16 removeMaintainers = set: if builtins.isAttrs set
17 then if (set.type or "") == "derivation"
18 then set // { meta = builtins.removeAttrs (set.meta or {}) [ "maintainers" ]; }
19 else pkgs.lib.mapAttrs (n: v: removeMaintainers v) set
20 else set;
21
22in rec {
23
24 nixos = removeMaintainers (import ./release.nix {
25 inherit stableBranch supportedSystems;
26 nixpkgs = nixpkgsSrc;
27 });
28
29 nixpkgs = builtins.removeAttrs (removeMaintainers (import ../pkgs/top-level/release.nix {
30 inherit supportedSystems;
31 nixpkgs = nixpkgsSrc;
32 })) [ "unstable" ];
33
34 tested = pkgs.lib.hydraJob (pkgs.releaseTools.aggregate {
35 name = "nixos-${nixos.channel.version}";
36 meta = {
37 description = "Release-critical builds for the NixOS channel";
38 maintainers = [ pkgs.lib.maintainers.eelco ];
39 };
40 constituents =
41 let all = x: map (system: x.${system}) supportedSystems; in
42 [ nixos.channel
43 (all nixos.dummy)
44 (all nixos.manual)
45
46 (all nixos.iso_minimal)
47 nixos.iso_graphical.x86_64-linux
48 nixos.ova.x86_64-linux
49
50 #(all nixos.tests.containers)
51 nixos.tests.chromium
52 (all nixos.tests.firefox)
53 (all nixos.tests.firewall)
54 nixos.tests.gnome3.x86_64-linux # FIXME: i686-linux
55 (all nixos.tests.installer.lvm)
56 (all nixos.tests.installer.luksroot)
57 (all nixos.tests.installer.separateBoot)
58 (all nixos.tests.installer.separateBootFat)
59 (all nixos.tests.installer.simple)
60 (all nixos.tests.installer.simpleLabels)
61 (all nixos.tests.installer.simpleProvided)
62 (all nixos.tests.installer.swraid)
63 (all nixos.tests.installer.btrfsSimple)
64 (all nixos.tests.installer.btrfsSubvols)
65 (all nixos.tests.installer.btrfsSubvolDefault)
66 (all nixos.tests.boot.biosCdrom)
67 #(all nixos.tests.boot.biosUsb) # disabled due to issue #15690
68 (all nixos.tests.boot.uefiCdrom)
69 (all nixos.tests.boot.uefiUsb)
70 (all nixos.tests.boot-stage1)
71 (all nixos.tests.hibernate)
72 (all nixos.tests.ecryptfs)
73 (all nixos.tests.ipv6)
74 (all nixos.tests.i3wm)
75 (all nixos.tests.kde4)
76 #(all nixos.tests.lightdm)
77 (all nixos.tests.login)
78 (all nixos.tests.misc)
79 (all nixos.tests.nat.firewall)
80 (all nixos.tests.nat.standalone)
81 (all nixos.tests.networking.scripted.loopback)
82 (all nixos.tests.networking.scripted.static)
83 (all nixos.tests.networking.scripted.dhcpSimple)
84 (all nixos.tests.networking.scripted.dhcpOneIf)
85 (all nixos.tests.networking.scripted.bond)
86 (all nixos.tests.networking.scripted.bridge)
87 (all nixos.tests.networking.scripted.macvlan)
88 (all nixos.tests.networking.scripted.sit)
89 (all nixos.tests.networking.scripted.vlan)
90 (all nixos.tests.nfs3)
91 (all nixos.tests.openssh)
92 (all nixos.tests.printing)
93 (all nixos.tests.proxy)
94 (all nixos.tests.sddm)
95 (all nixos.tests.simple)
96 (all nixos.tests.udisks2)
97 (all nixos.tests.xfce)
98
99 nixpkgs.tarball
100 (all nixpkgs.emacs)
101 (all nixpkgs.jdk)
102 ];
103 });
104
105}