pyrox.dev
1{ system ? builtins.currentSystem }:
2
3with import ../lib/testing.nix { inherit system; };
4
5let
6 testReader = pkgs.writeScript "test-input-reader" ''
7 #!${pkgs.stdenv.shell}
8 readInput() {
9 touch /tmp/reader.ready
10 echo "Waiting for '$1' to be typed"
11 read -r -n1 c
12 if [ "$c" = "$2" ]; then
13 echo "SUCCESS: Got back '$c' as expected."
14 echo 0 >&2
15 else
16 echo "FAIL: Expected '$2' but got '$c' instead."
17 echo 1 >&2
18 fi
19 }
20
21 main() {
22 error=0
23 while [ $# -gt 0 ]; do
24 ret="$((readInput "$2" "$3" | systemd-cat -t "$1") 2>&1)"
25 if [ $ret -ne 0 ]; then error=1; fi
26 shift 3
27 done
28 return $error
29 }
30
31 main "$@"; echo -n $? > /tmp/reader.exit
32 '';
33
34 mkReaderInput = testname: { qwerty, expect }: with pkgs.lib; let
35 lq = length qwerty;
36 le = length expect;
37 msg = "`qwerty' (${lq}) and `expect' (${le}) lists"
38 + " need to be of the same length!";
39 result = flatten (zipListsWith (a: b: [testname a b]) qwerty expect);
40 in if lq != le then throw msg else result;
41
42 mkKeyboardTest = layout: { extraConfig ? {}, tests }: with pkgs.lib; let
43 readerInput = flatten (mapAttrsToList mkReaderInput tests);
44 perlStr = val: "'${escape ["'" "\\"] val}'";
45 perlReaderInput = concatMapStringsSep ", " perlStr readerInput;
46 in makeTest {
47 name = "keymap-${layout}";
48
49 machine.i18n.consoleKeyMap = mkOverride 900 layout;
50 machine.services.xserver.layout = mkOverride 900 layout;
51 machine.imports = [ ./common/x11.nix extraConfig ];
52
53 testScript = ''
54 sub waitCatAndDelete ($) {
55 return $machine->succeed(
56 "for i in \$(seq 600); do if [ -e '$_[0]' ]; then ".
57 "cat '$_[0]' && rm -f '$_[0]' && exit 0; ".
58 "fi; sleep 0.1; done; echo timed out after 60 seconds >&2; exit 1"
59 );
60 };
61
62 sub mkTest ($$) {
63 my ($desc, $cmd) = @_;
64
65 my @testdata = (${perlReaderInput});
66 my $shellTestdata = join ' ', map { "'".s/'/'\\'''/gr."'" } @testdata;
67
68 subtest $desc, sub {
69 $machine->succeed("$cmd ${testReader} $shellTestdata &");
70 while (my ($testname, $qwerty, $expect) = splice(@testdata, 0, 3)) {
71 waitCatAndDelete "/tmp/reader.ready";
72 $machine->sendKeys($qwerty);
73 };
74 my $exitcode = waitCatAndDelete "/tmp/reader.exit";
75 die "tests for $desc failed" if $exitcode ne 0;
76 };
77 }
78
79 $machine->waitForX;
80
81 mkTest "VT keymap", "openvt -sw --";
82 mkTest "Xorg keymap", "DISPLAY=:0 xterm -fullscreen -e";
83 '';
84 };
85
86in pkgs.lib.mapAttrs mkKeyboardTest {
87 azerty = {
88 tests = {
89 azqw.qwerty = [ "q" "w" ];
90 azqw.expect = [ "a" "z" ];
91 altgr.qwerty = [ "alt_r-2" "alt_r-3" "alt_r-4" "alt_r-5" "alt_r-6" ];
92 altgr.expect = [ "~" "#" "{" "[" "|" ];
93 };
94
95 extraConfig.i18n.consoleKeyMap = "azerty/fr";
96 extraConfig.services.xserver.layout = "fr";
97 };
98
99 colemak = {
100 tests = {
101 homerow.qwerty = [ "a" "s" "d" "f" "j" "k" "l" "semicolon" ];
102 homerow.expect = [ "a" "r" "s" "t" "n" "e" "i" "o" ];
103 };
104
105 extraConfig.i18n.consoleKeyMap = "en-latin9";
106 extraConfig.services.xserver.layout = "us";
107 extraConfig.services.xserver.xkbVariant = "colemak";
108 };
109
110 dvorak = {
111 tests = {
112 homerow.qwerty = [ "a" "s" "d" "f" "j" "k" "l" "semicolon" ];
113 homerow.expect = [ "a" "o" "e" "u" "h" "t" "n" "s" ];
114 symbols.qwerty = [ "q" "w" "e" "minus" "equal" ];
115 symbols.expect = [ "'" "," "." "[" "]" ];
116 };
117 };
118
119 dvp = {
120 tests = {
121 homerow.qwerty = [ "a" "s" "d" "f" "j" "k" "l" "semicolon" ];
122 homerow.expect = [ "a" "o" "e" "u" "h" "t" "n" "s" ];
123 numbers.qwerty = map (x: "shift-${x}")
124 [ "1" "2" "3" "4" "5" "6" "7" "8" "9" "0" "minus" ];
125 numbers.expect = [ "%" "7" "5" "3" "1" "9" "0" "2" "4" "6" "8" ];
126 symbols.qwerty = [ "1" "2" "3" "4" "5" "6" "7" "8" "9" "0" "minus" ];
127 symbols.expect = [ "&" "[" "{" "}" "(" "=" "*" ")" "+" "]" "!" ];
128 };
129
130 extraConfig.services.xserver.layout = "us";
131 extraConfig.services.xserver.xkbVariant = "dvp";
132 };
133
134 neo = {
135 tests = {
136 layer1.qwerty = [ "f" "j" ];
137 layer1.expect = [ "e" "n" ];
138 layer2.qwerty = [ "shift-f" "shift-j" "shift-6" ];
139 layer2.expect = [ "E" "N" "$" ];
140 layer3.qwerty = [ "caps_lock-d" "caps_lock-f" ];
141 layer3.expect = [ "{" "}" ];
142 };
143
144 extraConfig.services.xserver.layout = "de";
145 extraConfig.services.xserver.xkbVariant = "neo";
146 };
147
148 qwertz = {
149 tests = {
150 zy.qwerty = [ "z" "y" ];
151 zy.expect = [ "y" "z" ];
152 altgr.qwerty = map (x: "alt_r-${x}")
153 [ "q" "less" "7" "8" "9" "0" ];
154 altgr.expect = [ "@" "|" "{" "[" "]" "}" ];
155 };
156
157 extraConfig.i18n.consoleKeyMap = "de";
158 extraConfig.services.xserver.layout = "de";
159 };
160}