pyrox.dev
1{ system, minimal ? false, config ? {} }:
2
3with import ./build-vms.nix { inherit system minimal config; };
4with pkgs;
5
6rec {
7
8 inherit pkgs;
9
10
11 testDriver = stdenv.mkDerivation {
12 name = "nixos-test-driver";
13
14 buildInputs = [ makeWrapper perl ];
15
16 unpackPhase = "true";
17
18 preferLocalBuild = true;
19
20 installPhase =
21 ''
22 mkdir -p $out/bin
23 cp ${./test-driver/test-driver.pl} $out/bin/nixos-test-driver
24 chmod u+x $out/bin/nixos-test-driver
25
26 libDir=$out/lib/perl5/site_perl
27 mkdir -p $libDir
28 cp ${./test-driver/Machine.pm} $libDir/Machine.pm
29 cp ${./test-driver/Logger.pm} $libDir/Logger.pm
30
31 wrapProgram $out/bin/nixos-test-driver \
32 --prefix PATH : "${lib.makeBinPath [ qemu vde2 netpbm coreutils ]}" \
33 --prefix PERL5LIB : "${with perlPackages; lib.makePerlPath [ TermReadLineGnu XMLWriter IOTty FileSlurp ]}:$out/lib/perl5/site_perl"
34 '';
35 };
36
37
38 # Run an automated test suite in the given virtual network.
39 # `driver' is the script that runs the network.
40 runTests = driver:
41 stdenv.mkDerivation {
42 name = "vm-test-run-${driver.testName}";
43
44 requiredSystemFeatures = [ "kvm" "nixos-test" ];
45
46 buildInputs = [ libxslt ];
47
48 buildCommand =
49 ''
50 mkdir -p $out/nix-support
51
52 LOGFILE=$out/log.xml tests='eval $ENV{testScript}; die $@ if $@;' ${driver}/bin/nixos-test-driver
53
54 # Generate a pretty-printed log.
55 xsltproc --output $out/log.html ${./test-driver/log2html.xsl} $out/log.xml
56 ln -s ${./test-driver/logfile.css} $out/logfile.css
57 ln -s ${./test-driver/treebits.js} $out/treebits.js
58 ln -s ${jquery}/js/jquery.min.js $out/
59 ln -s ${jquery-ui}/js/jquery-ui.min.js $out/
60
61 touch $out/nix-support/hydra-build-products
62 echo "report testlog $out log.html" >> $out/nix-support/hydra-build-products
63
64 for i in */xchg/coverage-data; do
65 mkdir -p $out/coverage-data
66 mv $i $out/coverage-data/$(dirname $(dirname $i))
67 done
68 ''; # */
69 };
70
71
72 makeTest =
73 { testScript
74 , makeCoverageReport ? false
75 , enableOCR ? false
76 , name ? "unnamed"
77 , ...
78 } @ t:
79
80 let
81 testDriverName = "nixos-test-driver-${name}";
82
83 nodes = buildVirtualNetwork (
84 t.nodes or (if t ? machine then { machine = t.machine; } else { }));
85
86 testScript' =
87 # Call the test script with the computed nodes.
88 if builtins.isFunction testScript
89 then testScript { inherit nodes; }
90 else testScript;
91
92 vlans = map (m: m.config.virtualisation.vlans) (lib.attrValues nodes);
93
94 vms = map (m: m.config.system.build.vm) (lib.attrValues nodes);
95
96 ocrProg = tesseract_4.override { enableLanguages = [ "eng" ]; };
97
98 # Generate onvenience wrappers for running the test driver
99 # interactively with the specified network, and for starting the
100 # VMs from the command line.
101 driver = runCommand testDriverName
102 { buildInputs = [ makeWrapper];
103 testScript = testScript';
104 preferLocalBuild = true;
105 testName = name;
106 }
107 ''
108 mkdir -p $out/bin
109 echo "$testScript" > $out/test-script
110 ln -s ${testDriver}/bin/nixos-test-driver $out/bin/
111 vms=($(for i in ${toString vms}; do echo $i/bin/run-*-vm; done))
112 wrapProgram $out/bin/nixos-test-driver \
113 --add-flags "''${vms[*]}" \
114 ${lib.optionalString enableOCR
115 "--prefix PATH : '${ocrProg}/bin:${imagemagick}/bin'"} \
116 --run "testScript=\"\$(cat $out/test-script)\"" \
117 --set testScript '$testScript' \
118 --set VLANS '${toString vlans}'
119 ln -s ${testDriver}/bin/nixos-test-driver $out/bin/nixos-run-vms
120 wrapProgram $out/bin/nixos-run-vms \
121 --add-flags "''${vms[*]}" \
122 ${lib.optionalString enableOCR "--prefix PATH : '${ocrProg}/bin'"} \
123 --set tests 'startAll; joinAll;' \
124 --set VLANS '${toString vlans}' \
125 ${lib.optionalString (builtins.length vms == 1) "--set USE_SERIAL 1"}
126 ''; # "
127
128 passMeta = drv: drv // lib.optionalAttrs (t ? meta) {
129 meta = (drv.meta or {}) // t.meta;
130 };
131
132 test = passMeta (runTests driver);
133 report = passMeta (releaseTools.gcovReport { coverageRuns = [ test ]; });
134
135 in (if makeCoverageReport then report else test) // {
136 inherit nodes driver test;
137 };
138
139 runInMachine =
140 { drv
141 , machine
142 , preBuild ? ""
143 , postBuild ? ""
144 , ... # ???
145 }:
146 let
147 vm = buildVM { }
148 [ machine
149 { key = "run-in-machine";
150 networking.hostName = "client";
151 nix.readOnlyStore = false;
152 }
153 ];
154
155 buildrunner = writeText "vm-build" ''
156 source $1
157
158 ${coreutils}/bin/mkdir -p $TMPDIR
159 cd $TMPDIR
160
161 exec $origBuilder $origArgs
162 '';
163
164 testScript = ''
165 startAll;
166 $client->waitForUnit("multi-user.target");
167 ${preBuild}
168 $client->succeed("env -i ${bash}/bin/bash ${buildrunner} /tmp/xchg/saved-env >&2");
169 ${postBuild}
170 $client->succeed("sync"); # flush all data before pulling the plug
171 '';
172
173 vmRunCommand = writeText "vm-run" ''
174 xchg=vm-state-client/xchg
175 ${coreutils}/bin/mkdir $out
176 ${coreutils}/bin/mkdir -p $xchg
177
178 for i in $passAsFile; do
179 i2=''${i}Path
180 _basename=$(${coreutils}/bin/basename ''${!i2})
181 ${coreutils}/bin/cp ''${!i2} $xchg/$_basename
182 eval $i2=/tmp/xchg/$_basename
183 ${coreutils}/bin/ls -la $xchg
184 done
185
186 unset i i2 _basename
187 export | ${gnugrep}/bin/grep -v '^xchg=' > $xchg/saved-env
188 unset xchg
189
190 export tests='${testScript}'
191 ${testDriver}/bin/nixos-test-driver ${vm.config.system.build.vm}/bin/run-*-vm
192 ''; # */
193
194 in
195 lib.overrideDerivation drv (attrs: {
196 requiredSystemFeatures = [ "kvm" ];
197 builder = "${bash}/bin/sh";
198 args = ["-e" vmRunCommand];
199 origArgs = attrs.args;
200 origBuilder = attrs.builder;
201 });
202
203
204 runInMachineWithX = { require ? [], ... } @ args:
205 let
206 client =
207 { config, pkgs, ... }:
208 {
209 inherit require;
210 virtualisation.memorySize = 1024;
211 services.xserver.enable = true;
212 services.xserver.displayManager.slim.enable = false;
213 services.xserver.displayManager.auto.enable = true;
214 services.xserver.windowManager.default = "icewm";
215 services.xserver.windowManager.icewm.enable = true;
216 services.xserver.desktopManager.default = "none";
217 };
218 in
219 runInMachine ({
220 machine = client;
221 preBuild =
222 ''
223 $client->waitForX;
224 '';
225 } // args);
226
227
228 simpleTest = as: (makeTest as).test;
229
230}