pyrox.dev
1# This module provides the proprietary NVIDIA X11 / OpenGL drivers.
2
3{ config, lib, pkgs, pkgs_i686, ... }:
4
5with lib;
6
7let
8
9 drivers = config.services.xserver.videoDrivers;
10
11 # FIXME: should introduce an option like
12 # ‘hardware.video.nvidia.package’ for overriding the default NVIDIA
13 # driver.
14 nvidiaForKernel = kernelPackages:
15 if elem "nvidia" drivers then
16 kernelPackages.nvidia_x11
17 else if elem "nvidiaBeta" drivers then
18 kernelPackages.nvidia_x11_beta
19 else if elem "nvidiaLegacy173" drivers then
20 kernelPackages.nvidia_x11_legacy173
21 else if elem "nvidiaLegacy304" drivers then
22 kernelPackages.nvidia_x11_legacy304
23 else if elem "nvidiaLegacy340" drivers then
24 kernelPackages.nvidia_x11_legacy340
25 else null;
26
27 nvidia_x11 = nvidiaForKernel config.boot.kernelPackages;
28 nvidia_libs32 = (nvidiaForKernel pkgs_i686.linuxPackages).override { libsOnly = true; kernel = null; };
29
30 nvidiaPackage = nvidia: pkgs:
31 if !nvidia.useGLVND then nvidia.out
32 else pkgs.buildEnv {
33 name = "nvidia-libs";
34 paths = [ pkgs.libglvnd nvidia.out ];
35 };
36
37 enabled = nvidia_x11 != null;
38in
39
40{
41
42 config = mkIf enabled {
43
44 services.xserver.drivers = singleton
45 { name = "nvidia"; modules = [ nvidia_x11.bin ]; libPath = [ nvidia_x11 ]; };
46
47 services.xserver.screenSection =
48 ''
49 Option "RandRRotation" "on"
50 '';
51
52 environment.etc."nvidia/nvidia-application-profiles-rc" = mkIf nvidia_x11.useProfiles {
53 source = "${nvidia_x11.bin}/share/nvidia/nvidia-application-profiles-rc";
54 };
55
56 hardware.opengl.package = nvidiaPackage nvidia_x11 pkgs;
57 hardware.opengl.package32 = nvidiaPackage nvidia_libs32 pkgs_i686;
58
59 environment.systemPackages = [ nvidia_x11.bin nvidia_x11.settings ]
60 ++ lib.filter (p: p != null) [ nvidia_x11.persistenced ];
61
62 boot.extraModulePackages = [ nvidia_x11.bin ];
63
64 # nvidia-uvm is required by CUDA applications.
65 boot.kernelModules = [ "nvidia-uvm" ];
66
67 # Create /dev/nvidia-uvm when the nvidia-uvm module is loaded.
68 services.udev.extraRules =
69 ''
70 KERNEL=="nvidia_uvm", RUN+="${pkgs.stdenv.shell} -c 'mknod -m 666 /dev/nvidia-uvm c $(grep nvidia-uvm /proc/devices | cut -d \ -f 1) 0'"
71 '';
72
73 boot.blacklistedKernelModules = [ "nouveau" "nvidiafb" ];
74
75 services.acpid.enable = true;
76
77 };
78
79}