pyrox.dev
1{ system ? builtins.currentSystem }:
2
3with import ../lib/testing.nix { inherit system; };
4
5let
6 testReader = pkgs.writeScript "test-input-reader" ''
7 #!${pkgs.stdenv.shell}
8 readInput() {
9 touch /tmp/reader.ready
10 echo "Waiting for '$1' to be typed"
11 read -r -n1 c
12 if [ "$c" = "$2" ]; then
13 echo "SUCCESS: Got back '$c' as expected."
14 echo 0 >&2
15 else
16 echo "FAIL: Expected '$2' but got '$c' instead."
17 echo 1 >&2
18 fi
19 }
20
21 main() {
22 error=0
23 while [ $# -gt 0 ]; do
24 ret="$((readInput "$2" "$3" | systemd-cat -t "$1") 2>&1)"
25 if [ $ret -ne 0 ]; then error=1; fi
26 shift 3
27 done
28 return $error
29 }
30
31 main "$@"; echo -n $? > /tmp/reader.exit
32 '';
33
34 mkReaderInput = testname: { qwerty, expect }: with pkgs.lib; let
35 lq = length qwerty;
36 le = length expect;
37 msg = "`qwerty' (${lq}) and `expect' (${le}) lists"
38 + " need to be of the same length!";
39 result = flatten (zipListsWith (a: b: [testname a b]) qwerty expect);
40 in if lq != le then throw msg else result;
41
42 mkKeyboardTest = layout: { extraConfig ? {}, tests }: with pkgs.lib; let
43 readerInput = flatten (mapAttrsToList mkReaderInput tests);
44 perlStr = val: "'${escape ["'" "\\"] val}'";
45 perlReaderInput = concatMapStringsSep ", " perlStr readerInput;
46 in makeTest {
47 name = "keymap-${layout}";
48
49 machine.i18n.consoleKeyMap = mkOverride 900 layout;
50 machine.services.xserver.layout = mkOverride 900 layout;
51 machine.imports = [ ./common/x11.nix extraConfig ];
52 machine.services.xserver.displayManager.slim = {
53 enable = true;
54
55 # Use a custom theme in order to get best OCR results
56 theme = pkgs.runCommand "slim-theme-ocr" {
57 nativeBuildInputs = [ pkgs.imagemagick ];
58 } ''
59 mkdir "$out"
60 convert -size 1x1 xc:white "$out/background.jpg"
61 convert -size 200x100 xc:white "$out/panel.jpg"
62 cat > "$out/slim.theme" <<EOF
63 background_color #ffffff
64 background_style tile
65
66 input_fgcolor #000000
67 msg_color #000000
68
69 session_color #000000
70 session_font Verdana:size=16:bold
71
72 username_msg Username:
73 username_font Verdana:size=16:bold
74 username_color #000000
75 username_x 50%
76 username_y 40%
77
78 password_msg Password:
79 password_x 50%
80 password_y 40%
81 EOF
82 '';
83 };
84
85 testScript = ''
86 sub waitCatAndDelete ($) {
87 return $machine->succeed(
88 "for i in \$(seq 600); do if [ -e '$_[0]' ]; then ".
89 "cat '$_[0]' && rm -f '$_[0]' && exit 0; ".
90 "fi; sleep 0.1; done; echo timed out after 60 seconds >&2; exit 1"
91 );
92 };
93
94 sub mkTest ($$) {
95 my ($desc, $cmd) = @_;
96
97 my @testdata = (${perlReaderInput});
98 my $shellTestdata = join ' ', map { "'".s/'/'\\'''/gr."'" } @testdata;
99
100 subtest $desc, sub {
101 $machine->succeed("$cmd ${testReader} $shellTestdata &");
102 while (my ($testname, $qwerty, $expect) = splice(@testdata, 0, 3)) {
103 waitCatAndDelete "/tmp/reader.ready";
104 $machine->sendKeys($qwerty);
105 };
106 my $exitcode = waitCatAndDelete "/tmp/reader.exit";
107 die "tests for $desc failed" if $exitcode ne 0;
108 };
109 }
110
111 $machine->waitForX;
112
113 mkTest "VT keymap", "openvt -sw --";
114 mkTest "Xorg keymap", "DISPLAY=:0 xterm -fullscreen -e";
115 '';
116 };
117
118in pkgs.lib.mapAttrs mkKeyboardTest {
119 azerty = {
120 tests = {
121 azqw.qwerty = [ "q" "w" ];
122 azqw.expect = [ "a" "z" ];
123 altgr.qwerty = [ "alt_r-2" "alt_r-3" "alt_r-4" "alt_r-5" "alt_r-6" ];
124 altgr.expect = [ "~" "#" "{" "[" "|" ];
125 };
126
127 extraConfig.i18n.consoleKeyMap = "azerty/fr";
128 extraConfig.services.xserver.layout = "fr";
129 };
130
131 colemak = {
132 tests = {
133 homerow.qwerty = [ "a" "s" "d" "f" "j" "k" "l" "semicolon" ];
134 homerow.expect = [ "a" "r" "s" "t" "n" "e" "i" "o" ];
135 };
136
137 extraConfig.i18n.consoleKeyMap = "en-latin9";
138 extraConfig.services.xserver.layout = "us";
139 extraConfig.services.xserver.xkbVariant = "colemak";
140 };
141
142 dvorak = {
143 tests = {
144 homerow.qwerty = [ "a" "s" "d" "f" "j" "k" "l" "semicolon" ];
145 homerow.expect = [ "a" "o" "e" "u" "h" "t" "n" "s" ];
146 symbols.qwerty = [ "q" "w" "e" "minus" "equal" ];
147 symbols.expect = [ "'" "," "." "[" "]" ];
148 };
149 };
150
151 dvp = {
152 tests = {
153 homerow.qwerty = [ "a" "s" "d" "f" "j" "k" "l" "semicolon" ];
154 homerow.expect = [ "a" "o" "e" "u" "h" "t" "n" "s" ];
155 numbers.qwerty = map (x: "shift-${x}")
156 [ "1" "2" "3" "4" "5" "6" "7" "8" "9" "0" "minus" ];
157 numbers.expect = [ "%" "7" "5" "3" "1" "9" "0" "2" "4" "6" "8" ];
158 symbols.qwerty = [ "1" "2" "3" "4" "5" "6" "7" "8" "9" "0" "minus" ];
159 symbols.expect = [ "&" "[" "{" "}" "(" "=" "*" ")" "+" "]" "!" ];
160 };
161
162 extraConfig.services.xserver.layout = "us";
163 extraConfig.services.xserver.xkbVariant = "dvp";
164 };
165
166 neo = {
167 tests = {
168 layer1.qwerty = [ "f" "j" ];
169 layer1.expect = [ "e" "n" ];
170 layer2.qwerty = [ "shift-f" "shift-j" "shift-6" ];
171 layer2.expect = [ "E" "N" "$" ];
172 layer3.qwerty = [ "caps_lock-d" "caps_lock-f" ];
173 layer3.expect = [ "{" "}" ];
174 };
175
176 extraConfig.services.xserver.layout = "de";
177 extraConfig.services.xserver.xkbVariant = "neo";
178 };
179
180 qwertz = {
181 tests = {
182 zy.qwerty = [ "z" "y" ];
183 zy.expect = [ "y" "z" ];
184 altgr.qwerty = map (x: "alt_r-${x}")
185 [ "q" "less" "7" "8" "9" "0" ];
186 altgr.expect = [ "@" "|" "{" "[" "]" "}" ];
187 };
188
189 extraConfig.i18n.consoleKeyMap = "de";
190 extraConfig.services.xserver.layout = "de";
191 };
192}