pyrox.dev
1# This module provides the proprietary NVIDIA X11 / OpenGL drivers.
2
3{ config, lib, pkgs, pkgs_i686, ... }:
4
5with lib;
6
7let
8
9 drivers = config.services.xserver.videoDrivers;
10
11 # FIXME: should introduce an option like
12 # ‘hardware.video.nvidia.package’ for overriding the default NVIDIA
13 # driver.
14 nvidiaForKernel = kernelPackages:
15 if elem "nvidia" drivers then
16 kernelPackages.nvidia_x11
17 else if elem "nvidiaBeta" drivers then
18 kernelPackages.nvidia_x11_beta
19 else if elem "nvidiaLegacy173" drivers then
20 kernelPackages.nvidia_x11_legacy173
21 else if elem "nvidiaLegacy304" drivers then
22 kernelPackages.nvidia_x11_legacy304
23 else if elem "nvidiaLegacy340" drivers then
24 kernelPackages.nvidia_x11_legacy340
25 else null;
26
27 nvidia_x11 = nvidiaForKernel config.boot.kernelPackages;
28 nvidia_libs32 = (nvidiaForKernel pkgs_i686.linuxPackages).override { libsOnly = true; kernel = null; };
29
30 nvidiaPackage = nvidia: pkgs:
31 if !nvidia.useGLVND then nvidia.out
32 else pkgs.buildEnv {
33 name = "nvidia-libs";
34 paths = [ pkgs.libglvnd nvidia.out ];
35 };
36
37 enabled = nvidia_x11 != null;
38in
39
40{
41
42 config = mkIf enabled {
43 assertions = [
44 {
45 assertion = config.services.xserver.displayManager.gdm.wayland;
46 message = "NVidia drivers don't support wayland";
47 }
48 ];
49
50 services.xserver.drivers = singleton
51 { name = "nvidia"; modules = [ nvidia_x11.bin ]; libPath = [ nvidia_x11 ]; };
52
53 services.xserver.screenSection =
54 ''
55 Option "RandRRotation" "on"
56 '';
57
58 environment.etc."nvidia/nvidia-application-profiles-rc" = mkIf nvidia_x11.useProfiles {
59 source = "${nvidia_x11.bin}/share/nvidia/nvidia-application-profiles-rc";
60 };
61
62 hardware.opengl.package = nvidiaPackage nvidia_x11 pkgs;
63 hardware.opengl.package32 = nvidiaPackage nvidia_libs32 pkgs_i686;
64
65 environment.systemPackages = [ nvidia_x11.bin nvidia_x11.settings ]
66 ++ lib.filter (p: p != null) [ nvidia_x11.persistenced ];
67
68 boot.extraModulePackages = [ nvidia_x11.bin ];
69
70 # nvidia-uvm is required by CUDA applications.
71 boot.kernelModules = [ "nvidia-uvm" ] ++
72 lib.optionals config.services.xserver.enable [ "nvidia" "nvidia_modeset" "nvidia_drm" ];
73
74
75 # Create /dev/nvidia-uvm when the nvidia-uvm module is loaded.
76 services.udev.extraRules =
77 ''
78 KERNEL=="nvidia", RUN+="${pkgs.stdenv.shell} -c 'mknod -m 666 /dev/nvidiactl c $(grep nvidia-frontend /proc/devices | cut -d \ -f 1) 255'"
79 KERNEL=="nvidia_modeset", RUN+="${pkgs.stdenv.shell} -c 'mknod -m 666 /dev/nvidia-modeset c $(grep nvidia-frontend /proc/devices | cut -d \ -f 1) 254'"
80 KERNEL=="card*", SUBSYSTEM=="drm", DRIVERS=="nvidia", RUN+="${pkgs.stdenv.shell} -c 'mknod -m 666 /dev/nvidia%n c $(grep nvidia-frontend /proc/devices | cut -d \ -f 1) %n'"
81 KERNEL=="nvidia_uvm", RUN+="${pkgs.stdenv.shell} -c 'mknod -m 666 /dev/nvidia-uvm c $(grep nvidia-uvm /proc/devices | cut -d \ -f 1) 0'"
82 '';
83
84 boot.blacklistedKernelModules = [ "nouveau" "nvidiafb" ];
85
86 services.acpid.enable = true;
87
88 };
89
90}