pyrox.dev
1{ config, pkgs, lib, ... }:
2
3with lib;
4
5let
6
7 e = pkgs.enlightenment;
8 xcfg = config.services.xserver;
9 cfg = xcfg.desktopManager.enlightenment;
10 GST_PLUGIN_PATH = lib.makeSearchPathOutput "lib" "lib/gstreamer-1.0" [
11 pkgs.gst_all_1.gst-plugins-base
12 pkgs.gst_all_1.gst-plugins-good
13 pkgs.gst_all_1.gst-plugins-bad
14 pkgs.gst_all_1.gst-libav ];
15
16in
17
18{
19 options = {
20
21 services.xserver.desktopManager.enlightenment.enable = mkOption {
22 default = false;
23 description = "Enable the Enlightenment desktop environment.";
24 };
25
26 };
27
28 config = mkIf (xcfg.enable && cfg.enable) {
29
30 environment.systemPackages = [
31 e.efl e.enlightenment
32 e.terminology e.econnman
33 pkgs.xorg.xauth # used by kdesu
34 pkgs.gtk2 # To get GTK+'s themes.
35 pkgs.tango-icon-theme
36
37 pkgs.gnome2.gnomeicontheme
38 pkgs.xorg.xcursorthemes
39 ];
40
41 environment.pathsToLink = [
42 "/etc/enlightenment"
43 "/share/enlightenment"
44 "/share/elementary"
45 "/share/locale"
46 ];
47
48 services.xserver.desktopManager.session = [
49 { name = "Enlightenment";
50 start = ''
51 # Set GTK_DATA_PREFIX so that GTK+ can find the themes
52 export GTK_DATA_PREFIX=${config.system.path}
53 # find theme engines
54 export GTK_PATH=${config.system.path}/lib/gtk-3.0:${config.system.path}/lib/gtk-2.0
55 export XDG_MENU_PREFIX=e-
56
57 export GST_PLUGIN_PATH="${GST_PLUGIN_PATH}"
58
59 # make available for D-BUS user services
60 #export XDG_DATA_DIRS=$XDG_DATA_DIRS''${XDG_DATA_DIRS:+:}:${config.system.path}/share:${e.efl}/share
61
62 # Update user dirs as described in http://freedesktop.org/wiki/Software/xdg-user-dirs/
63 ${pkgs.xdg-user-dirs}/bin/xdg-user-dirs-update
64
65 exec ${e.enlightenment}/bin/enlightenment_start
66 '';
67 }];
68
69 security.wrappers = (import (builtins.toPath "${e.enlightenment}/e-wrappers.nix")).security.wrappers;
70
71 environment.etc = singleton
72 { source = xcfg.xkbDir;
73 target = "X11/xkb";
74 };
75
76 fonts.fonts = [ pkgs.dejavu_fonts pkgs.ubuntu_font_family ];
77
78 services.udisks2.enable = true;
79 services.upower.enable = config.powerManagement.enable;
80
81 services.dbus.packages = [ e.efl ];
82
83 systemd.user.services.efreet =
84 { enable = true;
85 description = "org.enlightenment.Efreet";
86 serviceConfig =
87 { ExecStart = "${e.efl}/bin/efreetd";
88 StandardOutput = "null";
89 };
90 };
91
92 systemd.user.services.ethumb =
93 { enable = true;
94 description = "org.enlightenment.Ethumb";
95 serviceConfig =
96 { ExecStart = "${e.efl}/bin/ethumbd";
97 StandardOutput = "null";
98 };
99 };
100
101
102 };
103
104}