pyrox.dev
1# OCaml {#sec-language-ocaml}
2
3OCaml libraries should be installed in `$(out)/lib/ocaml/${ocaml.version}/site-lib/`. Such directories are automatically added to the `$OCAMLPATH` environment variable when building another package that depends on them or when opening a `nix-shell`.
4
5Given that most of the OCaml ecosystem is now built with dune, nixpkgs includes a convenience build support function called `buildDunePackage` that will build an OCaml package using dune, OCaml and findlib and any additional dependencies provided as `buildInputs` or `propagatedBuildInputs`.
6
7Here is a simple package example. It defines an (optional) attribute `minimumOCamlVersion` that will be used to throw a descriptive evaluation error if building with an older OCaml is attempted. It uses the `fetchFromGitHub` fetcher to get its source. It sets the `doCheck` (optional) attribute to `true` which means that tests will be run with `dune runtest -p angstrom` after the build (`dune build -p angstrom`) is complete. It uses `alcotest` as a build input (because it is needed to run the tests) and `bigstringaf` and `result` as propagated build inputs (thus they will also be available to libraries depending on this library). The library will be installed using the `angstrom.install` file that dune generates.
8
9```nix
10{ lib
11, fetchFromGitHub
12, buildDunePackage
13, alcotest
14, result
15, bigstringaf
16}:
17
18buildDunePackage rec {
19 pname = "angstrom";
20 version = "0.10.0";
21
22 minimumOCamlVersion = "4.03";
23
24 src = fetchFromGitHub {
25 owner = "inhabitedtype";
26 repo = pname;
27 rev = version;
28 sha256 = "0lh6024yf9ds0nh9i93r9m6p5psi8nvrqxl5x7jwl13zb0r9xfpw";
29 };
30
31 buildInputs = [ alcotest ];
32 propagatedBuildInputs = [ bigstringaf result ];
33 doCheck = true;
34
35 meta = with lib; {
36 homepage = "https://github.com/inhabitedtype/angstrom";
37 description = "OCaml parser combinators built for speed and memory efficiency";
38 license = licenses.bsd3;
39 maintainers = with maintainers; [ sternenseemann ];
40 };
41}
42```
43
44Here is a second example, this time using a source archive generated with `dune-release`. It is a good idea to use this archive when it is available as it will usually contain substituted variables such as a `%%VERSION%%` field. This library does not depend on any other OCaml library and no tests are run after building it.
45
46```nix
47{ lib
48, fetchurl
49, buildDunePackage
50}:
51
52buildDunePackage rec {
53 pname = "wtf8";
54 version = "1.0.1";
55
56 minimumOCamlVersion = "4.01";
57
58 src = fetchurl {
59 url = "https://github.com/flowtype/ocaml-${pname}/releases/download/v${version}/${pname}-${version}.tbz";
60 sha256 = "1msg3vycd3k8qqj61sc23qks541cxpb97vrnrvrhjnqxsqnh6ygq";
61 };
62
63 meta = with lib; {
64 homepage = "https://github.com/flowtype/ocaml-wtf8";
65 description = "WTF-8 is a superset of UTF-8 that allows unpaired surrogates.";
66 license = licenses.mit;
67 maintainers = [ maintainers.eqyiel ];
68 };
69}
70```