pyrox.dev
1{ config, pkgs, lib, ... }:
2let
3 inherit (lib) mkOption mkEnableOption mkIf mkMerge types optional;
4
5 cfg = config.services.uptime;
6
7 configDir = pkgs.runCommand "config" { preferLocalBuild = true; }
8 (if cfg.configFile != null then ''
9 mkdir $out
10 ext=`echo ${cfg.configFile} | grep -o \\..*`
11 ln -sv ${cfg.configFile} $out/default$ext
12 ln -sv /var/lib/uptime/runtime.json $out/runtime.json
13 '' else ''
14 mkdir $out
15 cat ${pkgs.nodePackages.node-uptime}/lib/node_modules/node-uptime/config/default.yaml > $out/default.yaml
16 cat >> $out/default.yaml <<EOF
17
18 autoStartMonitor: false
19
20 mongodb:
21 connectionString: 'mongodb://localhost/uptime'
22 EOF
23 ln -sv /var/lib/uptime/runtime.json $out/runtime.json
24 '');
25in {
26 options.services.uptime = {
27 configFile = mkOption {
28 description = ''
29 The uptime configuration file
30
31 If mongodb: server != localhost, please set usesRemoteMongo = true
32
33 If you only want to run the monitor, please set enableWebService = false
34 and enableSeparateMonitoringService = true
35
36 If autoStartMonitor: false (recommended) and you want to run both
37 services, please set enableSeparateMonitoringService = true
38 '';
39
40 type = types.nullOr types.path;
41
42 default = null;
43 };
44
45 usesRemoteMongo = mkOption {
46 description = "Whether the configuration file specifies a remote mongo instance";
47
48 default = false;
49
50 type = types.bool;
51 };
52
53 enableWebService = mkEnableOption "the uptime monitoring program web service";
54
55 enableSeparateMonitoringService = mkEnableOption "the uptime monitoring service" // { default = cfg.enableWebService; };
56
57 nodeEnv = mkOption {
58 description = "The node environment to run in (development, production, etc.)";
59
60 type = types.str;
61
62 default = "production";
63 };
64 };
65
66 config = mkMerge [ (mkIf cfg.enableWebService {
67 systemd.services.uptime = {
68 description = "uptime web service";
69 wantedBy = [ "multi-user.target" ];
70 environment = {
71 NODE_CONFIG_DIR = configDir;
72 NODE_ENV = cfg.nodeEnv;
73 NODE_PATH = "${pkgs.nodePackages.node-uptime}/lib/node_modules/node-uptime/node_modules";
74 };
75 preStart = "mkdir -p /var/lib/uptime";
76 serviceConfig.ExecStart = "${pkgs.nodejs}/bin/node ${pkgs.nodePackages.node-uptime}/lib/node_modules/node-uptime/app.js";
77 };
78
79 services.mongodb.enable = mkIf (!cfg.usesRemoteMongo) true;
80 }) (mkIf cfg.enableSeparateMonitoringService {
81 systemd.services.uptime-monitor = {
82 description = "uptime monitoring service";
83 wantedBy = [ "multi-user.target" ];
84 requires = optional cfg.enableWebService "uptime.service";
85 after = optional cfg.enableWebService "uptime.service";
86 environment = {
87 NODE_CONFIG_DIR = configDir;
88 NODE_ENV = cfg.nodeEnv;
89 NODE_PATH = "${pkgs.nodePackages.node-uptime}/lib/node_modules/node-uptime/node_modules";
90 };
91 # Ugh, need to wait for web service to be up
92 preStart = if cfg.enableWebService then "sleep 1s" else "mkdir -p /var/lib/uptime";
93 serviceConfig.ExecStart = "${pkgs.nodejs}/bin/node ${pkgs.nodePackages.node-uptime}/lib/node_modules/node-uptime/monitor.js";
94 };
95 }) ];
96}