pyrox.dev
1# Overriding {#chap-overrides}
2
3Sometimes one wants to override parts of `nixpkgs`, e.g. derivation attributes, the results of derivations.
4
5These functions are used to make changes to packages, returning only single packages. [Overlays](#chap-overlays), on the other hand, can be used to combine the overridden packages across the entire package set of Nixpkgs.
6
7## <pkg>.override {#sec-pkg-override}
8
9The function `override` is usually available for all the derivations in the nixpkgs expression (`pkgs`).
10
11It is used to override the arguments passed to a function.
12
13Example usages:
14
15```nix
16pkgs.foo.override { arg1 = val1; arg2 = val2; ... }
17```
18
19<!-- TODO: move below programlisting to a new section about extending and overlays and reference it -->
20
21```nix
22import pkgs.path { overlays = [ (self: super: {
23 foo = super.foo.override { barSupport = true ; };
24 })]};
25```
26
27```nix
28mypkg = pkgs.callPackage ./mypkg.nix {
29 mydep = pkgs.mydep.override { ... };
30 }
31```
32
33In the first example, `pkgs.foo` is the result of a function call with some default arguments, usually a derivation. Using `pkgs.foo.override` will call the same function with the given new arguments.
34
35## <pkg>.overrideAttrs {#sec-pkg-overrideAttrs}
36
37The function `overrideAttrs` allows overriding the attribute set passed to a `stdenv.mkDerivation` call, producing a new derivation based on the original one. This function is available on all derivations produced by the `stdenv.mkDerivation` function, which is most packages in the nixpkgs expression `pkgs`.
38
39Example usage:
40
41```nix
42helloWithDebug = pkgs.hello.overrideAttrs (oldAttrs: rec {
43 separateDebugInfo = true;
44});
45```
46
47In the above example, the `separateDebugInfo` attribute is overridden to be true, thus building debug info for `helloWithDebug`, while all other attributes will be retained from the original `hello` package.
48
49The argument `oldAttrs` is conventionally used to refer to the attr set originally passed to `stdenv.mkDerivation`.
50
51::: {.note}
52Note that `separateDebugInfo` is processed only by the `stdenv.mkDerivation` function, not the generated, raw Nix derivation. Thus, using `overrideDerivation` will not work in this case, as it overrides only the attributes of the final derivation. It is for this reason that `overrideAttrs` should be preferred in (almost) all cases to `overrideDerivation`, i.e. to allow using `stdenv.mkDerivation` to process input arguments, as well as the fact that it is easier to use (you can use the same attribute names you see in your Nix code, instead of the ones generated (e.g. `buildInputs` vs `nativeBuildInputs`), and it involves less typing).
53:::
54
55## <pkg>.overrideDerivation {#sec-pkg-overrideDerivation}
56
57::: {.warning}
58You should prefer `overrideAttrs` in almost all cases, see its documentation for the reasons why. `overrideDerivation` is not deprecated and will continue to work, but is less nice to use and does not have as many abilities as `overrideAttrs`.
59:::
60
61::: {.warning}
62Do not use this function in Nixpkgs as it evaluates a Derivation before modifying it, which breaks package abstraction and removes error-checking of function arguments. In addition, this evaluation-per-function application incurs a performance penalty, which can become a problem if many overrides are used. It is only intended for ad-hoc customisation, such as in `~/.config/nixpkgs/config.nix`.
63:::
64
65The function `overrideDerivation` creates a new derivation based on an existing one by overriding the original's attributes with the attribute set produced by the specified function. This function is available on all derivations defined using the `makeOverridable` function. Most standard derivation-producing functions, such as `stdenv.mkDerivation`, are defined using this function, which means most packages in the nixpkgs expression, `pkgs`, have this function.
66
67Example usage:
68
69```nix
70mySed = pkgs.gnused.overrideDerivation (oldAttrs: {
71 name = "sed-4.2.2-pre";
72 src = fetchurl {
73 url = ftp://alpha.gnu.org/gnu/sed/sed-4.2.2-pre.tar.bz2;
74 sha256 = "11nq06d131y4wmf3drm0yk502d2xc6n5qy82cg88rb9nqd2lj41k";
75 };
76 patches = [];
77});
78```
79
80In the above example, the `name`, `src`, and `patches` of the derivation will be overridden, while all other attributes will be retained from the original derivation.
81
82The argument `oldAttrs` is used to refer to the attribute set of the original derivation.
83
84::: {.note}
85A package's attributes are evaluated *before* being modified by the `overrideDerivation` function. For example, the `name` attribute reference in `url = "mirror://gnu/hello/${name}.tar.gz";` is filled-in *before* the `overrideDerivation` function modifies the attribute set. This means that overriding the `name` attribute, in this example, *will not* change the value of the `url` attribute. Instead, we need to override both the `name` *and* `url` attributes.
86:::
87
88## lib.makeOverridable {#sec-lib-makeOverridable}
89
90The function `lib.makeOverridable` is used to make the result of a function easily customizable. This utility only makes sense for functions that accept an argument set and return an attribute set.
91
92Example usage:
93
94```nix
95f = { a, b }: { result = a+b; };
96c = lib.makeOverridable f { a = 1; b = 2; };
97```
98
99The variable `c` is the value of the `f` function applied with some default arguments. Hence the value of `c.result` is `3`, in this example.
100
101The variable `c` however also has some additional functions, like
102[c.override](#sec-pkg-override) which can be used to override the
103default arguments. In this example the value of
104`(c.override { a = 4; }).result` is 6.