pyrox.dev
1# QEMU-related utilities shared between various Nix expressions.
2{ lib, pkgs }:
3
4let
5 zeroPad = n:
6 lib.optionalString (n < 16) "0" +
7 (if n > 255
8 then throw "Can't have more than 255 nets or nodes!"
9 else lib.toHexString n);
10in
11
12rec {
13 qemuNicMac = net: machine: "52:54:00:12:${zeroPad net}:${zeroPad machine}";
14
15 qemuNICFlags = nic: net: machine:
16 [
17 "-device virtio-net-pci,netdev=vlan${toString nic},mac=${qemuNicMac net machine}"
18 ''-netdev vde,id=vlan${toString nic},sock="$QEMU_VDE_SOCKET_${toString net}"''
19 ];
20
21 qemuSerialDevice =
22 if with pkgs.stdenv.hostPlatform; isx86 || isMips64 || isRiscV then "ttyS0"
23 else if (with pkgs.stdenv.hostPlatform; isAarch || isPower) then "ttyAMA0"
24 else throw "Unknown QEMU serial device for system '${pkgs.stdenv.hostPlatform.system}'";
25
26 qemuBinary = qemuPkg:
27 let
28 hostStdenv = qemuPkg.stdenv;
29 hostSystem = hostStdenv.system;
30 guestSystem = pkgs.stdenv.hostPlatform.system;
31
32 linuxHostGuestMatrix = {
33 x86_64-linux = "${qemuPkg}/bin/qemu-kvm -cpu max";
34 armv7l-linux = "${qemuPkg}/bin/qemu-system-arm -machine virt,accel=kvm:tcg -cpu max";
35 aarch64-linux = "${qemuPkg}/bin/qemu-system-aarch64 -machine virt,gic-version=max,accel=kvm:tcg -cpu max";
36 powerpc64le-linux = "${qemuPkg}/bin/qemu-system-ppc64 -machine powernv";
37 powerpc64-linux = "${qemuPkg}/bin/qemu-system-ppc64 -machine powernv";
38 x86_64-darwin = "${qemuPkg}/bin/qemu-kvm -cpu max";
39 };
40 otherHostGuestMatrix = {
41 aarch64-darwin = {
42 aarch64-linux = "${qemuPkg}/bin/qemu-system-aarch64 -machine virt,gic-version=2,accel=hvf:tcg -cpu max";
43 };
44 x86_64-darwin = {
45 x86_64-linux = "${qemuPkg}/bin/qemu-system-x86_64 -machine type=q35,accel=hvf:tcg -cpu max";
46 };
47 };
48
49 throwUnsupportedHostSystem =
50 let
51 supportedSystems = [ "linux" ] ++ (lib.attrNames otherHostGuestMatrix);
52 in
53 throw "Unsupported host system ${hostSystem}, supported: ${lib.concatStringsSep ", " supportedSystems}";
54 throwUnsupportedGuestSystem = guestMap:
55 throw "Unsupported guest system ${guestSystem} for host ${hostSystem}, supported: ${lib.concatStringsSep ", " (lib.attrNames guestMap)}";
56 in
57 if hostStdenv.isLinux then
58 linuxHostGuestMatrix.${guestSystem} or "${qemuPkg}/bin/qemu-kvm"
59 else
60 let
61 guestMap = (otherHostGuestMatrix.${hostSystem} or throwUnsupportedHostSystem);
62 in
63 (guestMap.${guestSystem} or (throwUnsupportedGuestSystem guestMap));
64}