pyrox.dev
1{
2 system ? builtins.currentSystem,
3 config ? {},
4 pkgs ? import ../../.. { inherit system config; },
5 lib ? pkgs.lib
6}:
7
8let
9 inherit (import ./common.nix { inherit pkgs lib; }) mkTestName mariadbPackages;
10
11 makeTest = import ./../make-test-python.nix;
12
13 makeAutobackupTest = {
14 package,
15 name ? mkTestName package,
16 }: makeTest {
17 name = "${name}-automysqlbackup";
18 meta.maintainers = [ lib.maintainers.aanderse ];
19
20 nodes.machine = {
21 services.mysql = {
22 inherit package;
23 enable = true;
24 initialDatabases = [ { name = "testdb"; schema = ./testdb.sql; } ];
25 };
26
27 services.automysqlbackup.enable = true;
28 };
29
30 testScript = ''
31 start_all()
32
33 # Need to have mysql started so that it can be populated with data.
34 machine.wait_for_unit("mysql.service")
35
36 with subtest("Wait for testdb to be fully populated (5 rows)."):
37 machine.wait_until_succeeds(
38 "mysql -u root -D testdb -N -B -e 'select count(id) from tests' | grep -q 5"
39 )
40
41 with subtest("Do a backup and wait for it to start"):
42 machine.start_job("automysqlbackup.service")
43 machine.wait_for_job("automysqlbackup.service")
44
45 with subtest("wait for backup file and check that data appears in backup"):
46 machine.wait_for_file("/var/backup/mysql/daily/testdb")
47 machine.succeed(
48 "${pkgs.gzip}/bin/zcat /var/backup/mysql/daily/testdb/daily_testdb_*.sql.gz | grep hello"
49 )
50 '';
51 };
52in
53 lib.mapAttrs (_: package: makeAutobackupTest { inherit package; }) mariadbPackages