pyrox.dev
1# Test ensures buildbot master comes up correctly and workers can connect
2
3import ./make-test-python.nix ({ pkgs, ... }: {
4 name = "buildbot";
5
6 nodes = {
7 bbmaster = { pkgs, ... }: {
8 services.buildbot-master = {
9 enable = true;
10
11 # NOTE: use fake repo due to no internet in hydra ci
12 factorySteps = [
13 "steps.Git(repourl='git://gitrepo/fakerepo.git', mode='incremental')"
14 "steps.ShellCommand(command=['bash', 'fakerepo.sh'])"
15 ];
16 changeSource = [
17 "changes.GitPoller('git://gitrepo/fakerepo.git', workdir='gitpoller-workdir', branch='master', pollinterval=300)"
18 ];
19 };
20 networking.firewall.allowedTCPPorts = [ 8010 8011 9989 ];
21 environment.systemPackages = with pkgs; [ git buildbot-full ];
22 };
23
24 bbworker = { pkgs, ... }: {
25 services.buildbot-worker = {
26 enable = true;
27 masterUrl = "bbmaster:9989";
28 };
29 environment.systemPackages = with pkgs; [ git buildbot-worker ];
30 };
31
32 gitrepo = { pkgs, ... }: {
33 services.openssh.enable = true;
34 networking.firewall.allowedTCPPorts = [ 22 9418 ];
35 environment.systemPackages = with pkgs; [ git ];
36 systemd.services.git-daemon = {
37 description = "Git daemon for the test";
38 wantedBy = [ "multi-user.target" ];
39 after = [ "network.target" "sshd.service" ];
40
41 serviceConfig.Restart = "always";
42 path = with pkgs; [ coreutils git openssh ];
43 environment = { HOME = "/root"; };
44 preStart = ''
45 git config --global user.name 'Nobody Fakeuser'
46 git config --global user.email 'nobody\@fakerepo.com'
47 rm -rvf /srv/repos/fakerepo.git /tmp/fakerepo
48 mkdir -pv /srv/repos/fakerepo ~/.ssh
49 ssh-keyscan -H gitrepo > ~/.ssh/known_hosts
50 cat ~/.ssh/known_hosts
51
52 mkdir -p /src/repos/fakerepo
53 cd /srv/repos/fakerepo
54 rm -rf *
55 git init
56 echo -e '#!/bin/sh\necho fakerepo' > fakerepo.sh
57 cat fakerepo.sh
58 touch .git/git-daemon-export-ok
59 git add fakerepo.sh .git/git-daemon-export-ok
60 git commit -m fakerepo
61 '';
62 script = ''
63 git daemon --verbose --export-all --base-path=/srv/repos --reuseaddr
64 '';
65 };
66 };
67 };
68
69 testScript = ''
70 gitrepo.wait_for_unit("git-daemon.service")
71 gitrepo.wait_for_unit("multi-user.target")
72
73 with subtest("Repo is accessible via git daemon"):
74 bbmaster.wait_for_unit("network-online.target")
75 bbmaster.succeed("rm -rfv /tmp/fakerepo")
76 bbmaster.succeed("git clone git://gitrepo/fakerepo /tmp/fakerepo")
77
78 with subtest("Master service and worker successfully connect"):
79 bbmaster.wait_for_unit("buildbot-master.service")
80 bbmaster.wait_until_succeeds("curl --fail -s --head http://bbmaster:8010")
81 bbworker.wait_for_unit("network-online.target")
82 bbworker.succeed("nc -z bbmaster 8010")
83 bbworker.succeed("nc -z bbmaster 9989")
84 bbworker.wait_for_unit("buildbot-worker.service")
85
86 with subtest("Stop buildbot worker"):
87 bbmaster.succeed("systemctl -l --no-pager status buildbot-master")
88 bbmaster.succeed("systemctl stop buildbot-master")
89 bbworker.fail("nc -z bbmaster 8010")
90 bbworker.fail("nc -z bbmaster 9989")
91 bbworker.succeed("systemctl -l --no-pager status buildbot-worker")
92 bbworker.succeed("systemctl stop buildbot-worker")
93
94 with subtest("Buildbot daemon mode works"):
95 bbmaster.succeed(
96 "buildbot create-master /tmp",
97 "mv -fv /tmp/master.cfg.sample /tmp/master.cfg",
98 "sed -i 's/8010/8011/' /tmp/master.cfg",
99 "buildbot start /tmp",
100 "nc -z bbmaster 8011",
101 )
102 bbworker.wait_until_succeeds("curl --fail -s --head http://bbmaster:8011")
103 bbmaster.wait_until_succeeds("buildbot stop /tmp")
104 bbworker.fail("nc -z bbmaster 8011")
105 '';
106
107 meta.maintainers = with pkgs.lib.maintainers; [ ];
108})