pyrox.dev
1{ kernelPackages ? null, flavour }: let
2 preparationCode = {
3 raid = ''
4 machine.succeed("vgcreate test_vg /dev/vdb /dev/vdc")
5 machine.succeed("lvcreate -L 512M --type raid0 test_vg -n test_lv")
6 '';
7
8 thinpool = ''
9 machine.succeed("vgcreate test_vg /dev/vdb")
10 machine.succeed("lvcreate -L 512M -T test_vg/test_thin_pool")
11 machine.succeed("lvcreate -n test_lv -V 16G --thinpool test_thin_pool test_vg")
12 '';
13
14 vdo = ''
15 machine.succeed("vgcreate test_vg /dev/vdb")
16 machine.succeed("lvcreate --type vdo -n test_lv -L 6G -V 12G test_vg/vdo_pool_lv")
17 '';
18 }.${flavour};
19
20 extraConfig = {
21 raid = {
22 boot.initrd.kernelModules = [
23 "dm-raid"
24 "raid0"
25 ];
26 };
27
28 thinpool = {
29 services.lvm = {
30 boot.thin.enable = true;
31 dmeventd.enable = true;
32 };
33 };
34
35 vdo = {
36 services.lvm = {
37 boot.vdo.enable = true;
38 dmeventd.enable = true;
39 };
40 };
41 }.${flavour};
42
43 extraCheck = {
44 raid = ''
45 "test_lv" in machine.succeed("lvs --select segtype=raid0")
46 '';
47
48 thinpool = ''
49 "test_lv" in machine.succeed("lvs --select segtype=thin-pool")
50 '';
51
52 vdo = ''
53 "test_lv" in machine.succeed("lvs --select segtype=vdo")
54 '';
55 }.${flavour};
56
57in import ../make-test-python.nix ({ pkgs, ... }: {
58 name = "lvm2-${flavour}-systemd-stage-1";
59 meta.maintainers = with pkgs.lib.maintainers; [ das_j ];
60
61 nodes.machine = { pkgs, lib, ... }: {
62 imports = [ extraConfig ];
63 # Use systemd-boot
64 virtualisation = {
65 emptyDiskImages = [ 8192 8192 ];
66 useBootLoader = true;
67 useEFIBoot = true;
68 # To boot off the LVM disk, we need to have a init script which comes from the Nix store.
69 mountHostNixStore = true;
70 };
71 boot.loader.systemd-boot.enable = true;
72 boot.loader.efi.canTouchEfiVariables = true;
73
74 environment.systemPackages = with pkgs; [ e2fsprogs ]; # for mkfs.ext4
75 boot = {
76 initrd.systemd = {
77 enable = true;
78 emergencyAccess = true;
79 };
80 initrd.services.lvm.enable = true;
81 kernelPackages = lib.mkIf (kernelPackages != null) kernelPackages;
82 };
83
84 specialisation.boot-lvm.configuration.virtualisation.rootDevice = "/dev/test_vg/test_lv";
85 };
86
87 testScript = ''
88 machine.wait_for_unit("multi-user.target")
89 # Create a VG for the root
90 ${preparationCode}
91 machine.succeed("mkfs.ext4 /dev/test_vg/test_lv")
92 machine.succeed("mkdir -p /mnt && mount /dev/test_vg/test_lv /mnt && echo hello > /mnt/test && umount /mnt")
93
94 # Boot from LVM
95 machine.succeed("bootctl set-default nixos-generation-1-specialisation-boot-lvm.conf")
96 machine.succeed("sync")
97 machine.crash()
98 machine.wait_for_unit("multi-user.target")
99
100 # Ensure we have successfully booted from LVM
101 assert "(initrd)" in machine.succeed("systemd-analyze") # booted with systemd in stage 1
102 assert "/dev/mapper/test_vg-test_lv on / type ext4" in machine.succeed("mount")
103 assert "hello" in machine.succeed("cat /test")
104 ${extraCheck}
105 '';
106})