pyrox.dev
1{
2 system ? builtins.currentSystem,
3 config ? {},
4 pkgs ? import ../../.. { inherit system config; },
5 lib ? pkgs.lib
6}:
7
8let
9 inherit (import ./common.nix { inherit pkgs lib; }) mkTestName mariadbPackages;
10
11 makeTest = import ./../make-test-python.nix;
12
13 makeBackupTest = {
14 package,
15 name ? mkTestName package
16 }: makeTest {
17 name = "${name}-backup";
18 meta = with pkgs.lib.maintainers; {
19 maintainers = [ rvl ];
20 };
21
22 nodes = {
23 master = { pkgs, ... }: {
24 services.mysql = {
25 inherit package;
26 enable = true;
27 initialDatabases = [ { name = "testdb"; schema = ./testdb.sql; } ];
28 };
29
30 services.mysqlBackup = {
31 enable = true;
32 databases = [ "doesnotexist" "testdb" ];
33 };
34 };
35 };
36
37 testScript = ''
38 start_all()
39
40 # Delete backup file that may be left over from a previous test run.
41 # This is not needed on Hydra but useful for repeated local test runs.
42 master.execute("rm -f /var/backup/mysql/testdb.gz")
43
44 # Need to have mysql started so that it can be populated with data.
45 master.wait_for_unit("mysql.service")
46
47 # Wait for testdb to be fully populated (5 rows).
48 master.wait_until_succeeds(
49 "mysql -u root -D testdb -N -B -e 'select count(id) from tests' | grep -q 5"
50 )
51
52 # Do a backup and wait for it to start
53 master.start_job("mysql-backup.service")
54
55 # wait for backup to fail, because of database 'doesnotexist'
56 master.wait_until_fails("systemctl is-active -q mysql-backup.service")
57
58 # wait for backup file and check that data appears in backup
59 master.wait_for_file("/var/backup/mysql/testdb.gz")
60 master.succeed(
61 "${pkgs.gzip}/bin/zcat /var/backup/mysql/testdb.gz | grep hello"
62 )
63
64 # Check that a failed backup is logged
65 master.succeed(
66 "journalctl -u mysql-backup.service | grep 'fail.*doesnotexist' > /dev/null"
67 )
68 '';
69 };
70in
71 lib.mapAttrs (_: package: makeBackupTest { inherit package; }) mariadbPackages