pyrox.dev
1# Ruby {#sec-language-ruby}
2
3## Using Ruby {#using-ruby}
4
5Several versions of Ruby interpreters are available on Nix, as well as over 250 gems and many applications written in Ruby. The attribute `ruby` refers to the default Ruby interpreter, which is currently MRI 2.6. It's also possible to refer to specific versions, e.g. `ruby_2_y`, `jruby`, or `mruby`.
6
7In the Nixpkgs tree, Ruby packages can be found throughout, depending on what they do, and are called from the main package set. Ruby gems, however are separate sets, and there's one default set for each interpreter (currently MRI only).
8
9There are two main approaches for using Ruby with gems. One is to use a specifically locked `Gemfile` for an application that has very strict dependencies. The other is to depend on the common gems, which we'll explain further down, and rely on them being updated regularly.
10
11The interpreters have common attributes, namely `gems`, and `withPackages`. So you can refer to `ruby.gems.nokogiri`, or `ruby_2_7.gems.nokogiri` to get the Nokogiri gem already compiled and ready to use.
12
13Since not all gems have executables like `nokogiri`, it's usually more convenient to use the `withPackages` function like this: `ruby.withPackages (p: with p; [ nokogiri ])`. This will also make sure that the Ruby in your environment will be able to find the gem and it can be used in your Ruby code (for example via `ruby` or `irb` executables) via `require "nokogiri"` as usual.
14
15### Temporary Ruby environment with `nix-shell` {#temporary-ruby-environment-with-nix-shell}
16
17Rather than having a single Ruby environment shared by all Ruby development projects on a system, Nix allows you to create separate environments per project. `nix-shell` gives you the possibility to temporarily load another environment akin to a combined `chruby` or `rvm` and `bundle exec`.
18
19There are two methods for loading a shell with Ruby packages. The first and recommended method is to create an environment with `ruby.withPackages` and load that.
20
21```ShellSession
22$ nix-shell -p "ruby.withPackages (ps: with ps; [ nokogiri pry ])"
23```
24
25The other method, which is not recommended, is to create an environment and list all the packages directly.
26
27```ShellSession
28$ nix-shell -p ruby.gems.nokogiri ruby.gems.pry
29```
30
31Again, it's possible to launch the interpreter from the shell. The Ruby interpreter has the attribute `gems` which contains all Ruby gems for that specific interpreter.
32
33#### Load Ruby environment from `.nix` expression {#load-ruby-environment-from-.nix-expression}
34
35As explained in the Nix manual, `nix-shell` can also load an expression from a `.nix` file. Say we want to have Ruby 2.6, `nokogori`, and `pry`. Consider a `shell.nix` file with:
36
37```nix
38with import <nixpkgs> {};
39ruby.withPackages (ps: with ps; [ nokogiri pry ])
40```
41
42What's happening here?
43
441. We begin with importing the Nix Packages collections. `import <nixpkgs>` imports the `<nixpkgs>` function, `{}` calls it and the `with` statement brings all attributes of `nixpkgs` in the local scope. These attributes form the main package set.
452. Then we create a Ruby environment with the `withPackages` function.
463. The `withPackages` function expects us to provide a function as an argument that takes the set of all ruby gems and returns a list of packages to include in the environment. Here, we select the packages `nokogiri` and `pry` from the package set.
47
48#### Execute command with `--run` {#execute-command-with---run}
49
50A convenient flag for `nix-shell` is `--run`. It executes a command in the `nix-shell`. We can e.g. directly open a `pry` REPL:
51
52```ShellSession
53$ nix-shell -p "ruby.withPackages (ps: with ps; [ nokogiri pry ])" --run "pry"
54```
55
56Or immediately require `nokogiri` in pry:
57
58```ShellSession
59$ nix-shell -p "ruby.withPackages (ps: with ps; [ nokogiri pry ])" --run "pry -rnokogiri"
60```
61
62Or run a script using this environment:
63
64```ShellSession
65$ nix-shell -p "ruby.withPackages (ps: with ps; [ nokogiri pry ])" --run "ruby example.rb"
66```
67
68#### Using `nix-shell` as shebang {#using-nix-shell-as-shebang}
69
70In fact, for the last case, there is a more convenient method. You can add a [shebang](<https://en.wikipedia.org/wiki/Shebang_(Unix)>) to your script specifying which dependencies `nix-shell` needs. With the following shebang, you can just execute `./example.rb`, and it will run with all dependencies.
71
72```ruby
73#! /usr/bin/env nix-shell
74#! nix-shell -i ruby -p "ruby.withPackages (ps: with ps; [ nokogiri rest-client ])"
75
76require 'nokogiri'
77require 'rest-client'
78
79body = RestClient.get('http://example.com').body
80puts Nokogiri::HTML(body).at('h1').text
81```
82
83## Developing with Ruby {#developing-with-ruby}
84
85### Using an existing Gemfile {#using-an-existing-gemfile}
86
87In most cases, you'll already have a `Gemfile.lock` listing all your dependencies. This can be used to generate a `gemset.nix` which is used to fetch the gems and combine them into a single environment. The reason why you need to have a separate file for this, is that Nix requires you to have a checksum for each input to your build. Since the `Gemfile.lock` that `bundler` generates doesn't provide us with checksums, we have to first download each gem, calculate its SHA256, and store it in this separate file.
88
89So the steps from having just a `Gemfile` to a `gemset.nix` are:
90
91```ShellSession
92$ bundle lock
93$ bundix
94```
95
96If you already have a `Gemfile.lock`, you can simply run `bundix` and it will work the same.
97
98To update the gems in your `Gemfile.lock`, you may use the `bundix -l` flag, which will create a new `Gemfile.lock` in case the `Gemfile` has a more recent time of modification.
99
100Once the `gemset.nix` is generated, it can be used in a `bundlerEnv` derivation. Here is an example you could use for your `shell.nix`:
101
102```nix
103# ...
104let
105 gems = bundlerEnv {
106 name = "gems-for-some-project";
107 gemdir = ./.;
108 };
109in mkShell { packages = [ gems gems.wrappedRuby ]; }
110```
111
112With this file in your directory, you can run `nix-shell` to build and use the gems. The important parts here are `bundlerEnv` and `wrappedRuby`.
113
114The `bundlerEnv` is a wrapper over all the gems in your gemset. This means that all the `/lib` and `/bin` directories will be available, and the executables of all gems (even of indirect dependencies) will end up in your `$PATH`. The `wrappedRuby` provides you with all executables that come with Ruby itself, but wrapped so they can easily find the gems in your gemset.
115
116One common issue that you might have is that you have Ruby 2.6, but also `bundler` in your gemset. That leads to a conflict for `/bin/bundle` and `/bin/bundler`. You can resolve this by wrapping either your Ruby or your gems in a `lowPrio` call. So in order to give the `bundler` from your gemset priority, it would be used like this:
117
118```nix
119# ...
120mkShell { buildInputs = [ gems (lowPrio gems.wrappedRuby) ]; }
121```
122
123### Gem-specific configurations and workarounds {#gem-specific-configurations-and-workarounds}
124
125In some cases, especially if the gem has native extensions, you might need to modify the way the gem is built.
126
127This is done via a common configuration file that includes all of the workarounds for each gem.
128
129This file lives at `/pkgs/development/ruby-modules/gem-config/default.nix`, since it already contains a lot of entries, it should be pretty easy to add the modifications you need for your needs.
130
131In the meanwhile, or if the modification is for a private gem, you can also add the configuration to only your own environment.
132
133Two places that allow this modification are the `ruby` derivation, or `bundlerEnv`.
134
135Here's the `ruby` one:
136
137```nix
138{ pg_version ? "10", pkgs ? import <nixpkgs> { } }:
139let
140 myRuby = pkgs.ruby.override {
141 defaultGemConfig = pkgs.defaultGemConfig // {
142 pg = attrs: {
143 buildFlags =
144 [ "--with-pg-config=${pkgs."postgresql_${pg_version}"}/bin/pg_config" ];
145 };
146 };
147 };
148in myRuby.withPackages (ps: with ps; [ pg ])
149```
150
151And an example with `bundlerEnv`:
152
153```nix
154{ pg_version ? "10", pkgs ? import <nixpkgs> { } }:
155let
156 gems = pkgs.bundlerEnv {
157 name = "gems-for-some-project";
158 gemdir = ./.;
159 gemConfig = pkgs.defaultGemConfig // {
160 pg = attrs: {
161 buildFlags =
162 [ "--with-pg-config=${pkgs."postgresql_${pg_version}"}/bin/pg_config" ];
163 };
164 };
165 };
166in mkShell { buildInputs = [ gems gems.wrappedRuby ]; }
167```
168
169And finally via overlays:
170
171```nix
172{ pg_version ? "10" }:
173let
174 pkgs = import <nixpkgs> {
175 overlays = [
176 (self: super: {
177 defaultGemConfig = super.defaultGemConfig // {
178 pg = attrs: {
179 buildFlags = [
180 "--with-pg-config=${
181 pkgs."postgresql_${pg_version}"
182 }/bin/pg_config"
183 ];
184 };
185 };
186 })
187 ];
188 };
189in pkgs.ruby.withPackages (ps: with ps; [ pg ])
190```
191
192Then we can get whichever postgresql version we desire and the `pg` gem will always reference it correctly:
193
194```ShellSession
195$ nix-shell --argstr pg_version 9_4 --run 'ruby -rpg -e "puts PG.library_version"'
19690421
197
198$ nix-shell --run 'ruby -rpg -e "puts PG.library_version"'
199100007
200```
201
202Of course for this use-case one could also use overlays since the configuration for `pg` depends on the `postgresql` alias, but for demonstration purposes this has to suffice.
203
204### Platform-specific gems {#ruby-platform-specif-gems}
205
206Right now, bundix has some issues with pre-built, platform-specific gems: [bundix PR #68](https://github.com/nix-community/bundix/pull/68).
207Until this is solved, you can tell bundler to not use platform-specific gems and instead build them from source each time:
208- globally (will be set in `~/.config/.bundle/config`):
209```shell
210$ bundle config set force_ruby_platform true
211```
212- locally (will be set in `<project-root>/.bundle/config`):
213```shell
214$ bundle config set --local force_ruby_platform true
215```
216
217### Adding a gem to the default gemset {#adding-a-gem-to-the-default-gemset}
218
219Now that you know how to get a working Ruby environment with Nix, it's time to go forward and start actually developing with Ruby. We will first have a look at how Ruby gems are packaged on Nix. Then, we will look at how you can use development mode with your code.
220
221All gems in the standard set are automatically generated from a single `Gemfile`. The dependency resolution is done with `bundler` and makes it more likely that all gems are compatible to each other.
222
223In order to add a new gem to nixpkgs, you can put it into the `/pkgs/development/ruby-modules/with-packages/Gemfile` and run `./maintainers/scripts/update-ruby-packages`.
224
225To test that it works, you can then try using the gem with:
226
227```shell
228NIX_PATH=nixpkgs=$PWD nix-shell -p "ruby.withPackages (ps: with ps; [ name-of-your-gem ])"
229```
230
231### Packaging applications {#packaging-applications}
232
233A common task is to add a ruby executable to nixpkgs, popular examples would be `chef`, `jekyll`, or `sass`. A good way to do that is to use the `bundlerApp` function, that allows you to make a package that only exposes the listed executables, otherwise the package may cause conflicts through common paths like `bin/rake` or `bin/bundler` that aren't meant to be used.
234
235The absolute easiest way to do that is to write a `Gemfile` along these lines:
236
237```ruby
238source 'https://rubygems.org' do
239 gem 'mdl'
240end
241```
242
243If you want to package a specific version, you can use the standard Gemfile syntax for that, e.g. `gem 'mdl', '0.5.0'`, but if you want the latest stable version anyway, it's easier to update by simply running the `bundle lock` and `bundix` steps again.
244
245Now you can also make a `default.nix` that looks like this:
246
247```nix
248{ bundlerApp }:
249
250bundlerApp {
251 pname = "mdl";
252 gemdir = ./.;
253 exes = [ "mdl" ];
254}
255```
256
257All that's left to do is to generate the corresponding `Gemfile.lock` and `gemset.nix` as described above in the `Using an existing Gemfile` section.
258
259#### Packaging executables that require wrapping {#packaging-executables-that-require-wrapping}
260
261Sometimes your app will depend on other executables at runtime, and tries to find it through the `PATH` environment variable.
262
263In this case, you can provide a `postBuild` hook to `bundlerApp` that wraps the gem in another script that prefixes the `PATH`.
264
265Of course you could also make a custom `gemConfig` if you know exactly how to patch it, but it's usually much easier to maintain with a simple wrapper so the patch doesn't have to be adjusted for each version.
266
267Here's another example:
268
269```nix
270{ lib, bundlerApp, makeWrapper, git, gnutar, gzip }:
271
272bundlerApp {
273 pname = "r10k";
274 gemdir = ./.;
275 exes = [ "r10k" ];
276
277 nativeBuildInputs = [ makeWrapper ];
278
279 postBuild = ''
280 wrapProgram $out/bin/r10k --prefix PATH : ${lib.makeBinPath [ git gnutar gzip ]}
281 '';
282}
283```