pyrox.dev
1# Perl {#sec-language-perl}
2
3## Running Perl programs on the shell {#ssec-perl-running}
4
5When executing a Perl script, it is possible you get an error such as `./myscript.pl: bad interpreter: /usr/bin/perl: no such file or directory`. This happens when the script expects Perl to be installed at `/usr/bin/perl`, which is not the case when using Perl from nixpkgs. You can fix the script by changing the first line to:
6
7```perl
8#!/usr/bin/env perl
9```
10
11to take the Perl installation from the `PATH` environment variable, or invoke Perl directly with:
12
13```ShellSession
14$ perl ./myscript.pl
15```
16
17When the script is using a Perl library that is not installed globally, you might get an error such as `Can't locate DB_File.pm in @INC (you may need to install the DB_File module)`. In that case, you can use `nix-shell` to start an ad-hoc shell with that library installed, for instance:
18
19```ShellSession
20$ nix-shell -p perl perlPackages.DBFile --run ./myscript.pl
21```
22
23If you are always using the script in places where `nix-shell` is available, you can embed the `nix-shell` invocation in the shebang like this:
24
25```perl
26#!/usr/bin/env nix-shell
27#! nix-shell -i perl -p perl perlPackages.DBFile
28```
29
30## Packaging Perl programs {#ssec-perl-packaging}
31
32Nixpkgs provides a function `buildPerlPackage`, a generic package builder function for any Perl package that has a standard `Makefile.PL`. It’s implemented in [pkgs/development/perl-modules/generic](https://github.com/NixOS/nixpkgs/blob/master/pkgs/development/perl-modules/generic).
33
34Perl packages from CPAN are defined in [pkgs/top-level/perl-packages.nix](https://github.com/NixOS/nixpkgs/blob/master/pkgs/top-level/perl-packages.nix) rather than `pkgs/all-packages.nix`. Most Perl packages are so straight-forward to build that they are defined here directly, rather than having a separate function for each package called from `perl-packages.nix`. However, more complicated packages should be put in a separate file, typically in `pkgs/development/perl-modules`. Here is an example of the former:
35
36```nix
37{
38 ClassC3 = buildPerlPackage rec {
39 pname = "Class-C3";
40 version = "0.21";
41 src = fetchurl {
42 url = "mirror://cpan/authors/id/F/FL/FLORA/${pname}-${version}.tar.gz";
43 hash = "sha256-/5GE5xHT0uYGOQxroqj6LMU7CtKn2s6vMVoSXxL4iK4=";
44 };
45 };
46}
47```
48
49Note the use of `mirror://cpan/`, and the `pname` and `version` in the URL definition to ensure that the `pname` attribute is consistent with the source that we’re actually downloading. Perl packages are made available in `all-packages.nix` through the variable `perlPackages`. For instance, if you have a package that needs `ClassC3`, you would typically write
50
51```nix
52{
53 foo = import ../path/to/foo.nix {
54 inherit stdenv fetchurl /* ... */;
55 inherit (perlPackages) ClassC3;
56 };
57}
58```
59
60in `all-packages.nix`. You can test building a Perl package as follows:
61
62```ShellSession
63$ nix-build -A perlPackages.ClassC3
64```
65
66To install it with `nix-env` instead: `nix-env -f. -iA perlPackages.ClassC3`.
67
68So what does `buildPerlPackage` do? It does the following:
69
701. In the configure phase, it calls `perl Makefile.PL` to generate a Makefile. You can set the variable `makeMakerFlags` to pass flags to `Makefile.PL`
712. It adds the contents of the `PERL5LIB` environment variable to `#! .../bin/perl` line of Perl scripts as `-Idir` flags. This ensures that a script can find its dependencies. (This can cause this shebang line to become too long for Darwin to handle; see the note below.)
723. In the fixup phase, it writes the propagated build inputs (`propagatedBuildInputs`) to the file `$out/nix-support/propagated-user-env-packages`. `nix-env` recursively installs all packages listed in this file when you install a package that has it. This ensures that a Perl package can find its dependencies.
73
74`buildPerlPackage` is built on top of `stdenv`, so everything can be customised in the usual way. For instance, the `BerkeleyDB` module has a `preConfigure` hook to generate a configuration file used by `Makefile.PL`:
75
76```nix
77{ buildPerlPackage, fetchurl, db }:
78
79buildPerlPackage rec {
80 pname = "BerkeleyDB";
81 version = "0.36";
82
83 src = fetchurl {
84 url = "mirror://cpan/authors/id/P/PM/PMQS/${pname}-${version}.tar.gz";
85 hash = "sha256-4Y+HGgGQqcOfdiKcFIyMrWBEccVNVAMDBWZlFTMorh8=";
86 };
87
88 preConfigure = ''
89 echo "LIB = ${db.out}/lib" > config.in
90 echo "INCLUDE = ${db.dev}/include" >> config.in
91 '';
92}
93```
94
95Dependencies on other Perl packages can be specified in the `buildInputs` and `propagatedBuildInputs` attributes. If something is exclusively a build-time dependency, use `buildInputs`; if it’s (also) a runtime dependency, use `propagatedBuildInputs`. For instance, this builds a Perl module that has runtime dependencies on a bunch of other modules:
96
97```nix
98{
99 ClassC3Componentised = buildPerlPackage rec {
100 pname = "Class-C3-Componentised";
101 version = "1.0004";
102 src = fetchurl {
103 url = "mirror://cpan/authors/id/A/AS/ASH/${pname}-${version}.tar.gz";
104 hash = "sha256-ASO9rV/FzJYZ0BH572Fxm2ZrFLMZLFATJng1NuU4FHc=";
105 };
106 propagatedBuildInputs = [
107 ClassC3 ClassInspector TestException MROCompat
108 ];
109 };
110}
111```
112
113On Darwin, if a script has too many `-Idir` flags in its first line (its “shebang line”), it will not run. This can be worked around by calling the `shortenPerlShebang` function from the `postInstall` phase:
114
115```nix
116{ lib, stdenv, buildPerlPackage, fetchurl, shortenPerlShebang }:
117
118{
119 ImageExifTool = buildPerlPackage {
120 pname = "Image-ExifTool";
121 version = "12.50";
122
123 src = fetchurl {
124 url = "https://exiftool.org/${pname}-${version}.tar.gz";
125 hash = "sha256-vOhB/FwQMC8PPvdnjDvxRpU6jAZcC6GMQfc0AH4uwKg=";
126 };
127
128 nativeBuildInputs = lib.optional stdenv.isDarwin shortenPerlShebang;
129 postInstall = lib.optionalString stdenv.isDarwin ''
130 shortenPerlShebang $out/bin/exiftool
131 '';
132 };
133}
134```
135
136This will remove the `-I` flags from the shebang line, rewrite them in the `use lib` form, and put them on the next line instead. This function can be given any number of Perl scripts as arguments; it will modify them in-place.
137
138### Generation from CPAN {#ssec-generation-from-CPAN}
139
140Nix expressions for Perl packages can be generated (almost) automatically from CPAN. This is done by the program `nix-generate-from-cpan`, which can be installed as follows:
141
142```ShellSession
143$ nix-env -f "<nixpkgs>" -iA nix-generate-from-cpan
144```
145
146Substitute `<nixpkgs>` by the path of a nixpkgs clone to use the latest version.
147
148This program takes a Perl module name, looks it up on CPAN, fetches and unpacks the corresponding package, and prints a Nix expression on standard output. For example:
149
150```ShellSession
151$ nix-generate-from-cpan XML::Simple
152 XMLSimple = buildPerlPackage rec {
153 pname = "XML-Simple";
154 version = "2.22";
155 src = fetchurl {
156 url = "mirror://cpan/authors/id/G/GR/GRANTM/XML-Simple-2.22.tar.gz";
157 hash = "sha256-uUUO8i6pZErl1q2ghtxDAPoQW+BQogMOvU79KMGY60k=";
158 };
159 propagatedBuildInputs = [ XMLNamespaceSupport XMLSAX XMLSAXExpat ];
160 meta = {
161 description = "An API for simple XML files";
162 license = with lib.licenses; [ artistic1 gpl1Plus ];
163 };
164 };
165```
166
167The output can be pasted into `pkgs/top-level/perl-packages.nix` or wherever else you need it.
168
169### Cross-compiling modules {#ssec-perl-cross-compilation}
170
171Nixpkgs has experimental support for cross-compiling Perl modules. In many cases, it will just work out of the box, even for modules with native extensions. Sometimes, however, the Makefile.PL for a module may (indirectly) import a native module. In that case, you will need to make a stub for that module that will satisfy the Makefile.PL and install it into `lib/perl5/site_perl/cross_perl/${perl.version}`. See the `postInstall` for `DBI` for an example.