pyrox.dev
1# To build, use:
2# nix-build nixos -I nixos-config=nixos/modules/installer/sd-card/sd-image-armv7l-multiplatform.nix -A config.system.build.sdImage
3{ config, lib, pkgs, ... }:
4
5{
6 imports = [
7 ../../profiles/base.nix
8 ./sd-image.nix
9 ];
10
11 boot.loader.grub.enable = false;
12 boot.loader.generic-extlinux-compatible.enable = true;
13
14 boot.consoleLogLevel = lib.mkDefault 7;
15 boot.kernelPackages = pkgs.linuxPackages_latest;
16 # The serial ports listed here are:
17 # - ttyS0: for Tegra (Jetson TK1)
18 # - ttymxc0: for i.MX6 (Wandboard)
19 # - ttyAMA0: for Allwinner (pcDuino3 Nano) and QEMU's -machine virt
20 # - ttyO0: for OMAP (BeagleBone Black)
21 # - ttySAC2: for Exynos (ODROID-XU3)
22 boot.kernelParams = ["console=ttyS0,115200n8" "console=ttymxc0,115200n8" "console=ttyAMA0,115200n8" "console=ttyO0,115200n8" "console=ttySAC2,115200n8" "console=tty0"];
23
24 sdImage = {
25 populateFirmwareCommands = let
26 configTxt = pkgs.writeText "config.txt" ''
27 # Prevent the firmware from smashing the framebuffer setup done by the mainline kernel
28 # when attempting to show low-voltage or overtemperature warnings.
29 avoid_warnings=1
30
31 [pi2]
32 kernel=u-boot-rpi2.bin
33
34 [pi3]
35 kernel=u-boot-rpi3.bin
36
37 # U-Boot used to need this to work, regardless of whether UART is actually used or not.
38 # TODO: check when/if this can be removed.
39 enable_uart=1
40 '';
41 in ''
42 (cd ${pkgs.raspberrypifw}/share/raspberrypi/boot && cp bootcode.bin fixup*.dat start*.elf $NIX_BUILD_TOP/firmware/)
43 cp ${pkgs.ubootRaspberryPi2}/u-boot.bin firmware/u-boot-rpi2.bin
44 cp ${pkgs.ubootRaspberryPi3_32bit}/u-boot.bin firmware/u-boot-rpi3.bin
45 cp ${configTxt} firmware/config.txt
46 '';
47 populateRootCommands = ''
48 mkdir -p ./files/boot
49 ${config.boot.loader.generic-extlinux-compatible.populateCmd} -c ${config.system.build.toplevel} -d ./files/boot
50 '';
51 };
52}