pyrox.dev
1{
2 config,
3 lib,
4 pkgs,
5 ...
6}:
7let
8 cfg = config.services.spamassassin;
9 spamassassin-local-cf = pkgs.writeText "local.cf" cfg.config;
10
11in
12
13{
14 options = {
15
16 services.spamassassin = {
17 enable = lib.mkEnableOption "the SpamAssassin daemon";
18
19 debug = lib.mkOption {
20 type = lib.types.bool;
21 default = false;
22 description = "Whether to run the SpamAssassin daemon in debug mode";
23 };
24
25 config = lib.mkOption {
26 type = lib.types.lines;
27 description = ''
28 The SpamAssassin local.cf config
29
30 If you are using this configuration:
31
32 add_header all Status _YESNO_, score=_SCORE_ required=_REQD_ tests=_TESTS_ autolearn=_AUTOLEARN_ version=_VERSION_
33
34 Then you can Use this sieve filter:
35
36 require ["fileinto", "reject", "envelope"];
37
38 if header :contains "X-Spam-Flag" "YES" {
39 fileinto "spam";
40 }
41
42 Or this procmail filter:
43
44 :0:
45 * ^X-Spam-Flag: YES
46 /var/vpopmail/domains/lastlog.de/js/.maildir/.spam/new
47
48 To filter your messages based on the additional mail headers added by spamassassin.
49 '';
50 example = ''
51 #rewrite_header Subject [***** SPAM _SCORE_ *****]
52 required_score 5.0
53 use_bayes 1
54 bayes_auto_learn 1
55 add_header all Status _YESNO_, score=_SCORE_ required=_REQD_ tests=_TESTS_ autolearn=_AUTOLEARN_ version=_VERSION_
56 '';
57 default = "";
58 };
59
60 initPreConf = lib.mkOption {
61 type = with lib.types; either str path;
62 description = "The SpamAssassin init.pre config.";
63 apply = val: if builtins.isPath val then val else pkgs.writeText "init.pre" val;
64 default = ''
65 #
66 # to update this list, run this command in the rules directory:
67 # grep 'loadplugin.*Mail::SpamAssassin::Plugin::.*' -o -h * | sort | uniq
68 #
69
70 #loadplugin Mail::SpamAssassin::Plugin::AccessDB
71 #loadplugin Mail::SpamAssassin::Plugin::AntiVirus
72 loadplugin Mail::SpamAssassin::Plugin::AskDNS
73 # loadplugin Mail::SpamAssassin::Plugin::ASN
74 loadplugin Mail::SpamAssassin::Plugin::AutoLearnThreshold
75 #loadplugin Mail::SpamAssassin::Plugin::AWL
76 loadplugin Mail::SpamAssassin::Plugin::Bayes
77 loadplugin Mail::SpamAssassin::Plugin::BodyEval
78 loadplugin Mail::SpamAssassin::Plugin::Check
79 #loadplugin Mail::SpamAssassin::Plugin::DCC
80 loadplugin Mail::SpamAssassin::Plugin::DKIM
81 loadplugin Mail::SpamAssassin::Plugin::DMARC
82 loadplugin Mail::SpamAssassin::Plugin::DNSEval
83 loadplugin Mail::SpamAssassin::Plugin::FreeMail
84 loadplugin Mail::SpamAssassin::Plugin::HeaderEval
85 loadplugin Mail::SpamAssassin::Plugin::HTMLEval
86 loadplugin Mail::SpamAssassin::Plugin::HTTPSMismatch
87 loadplugin Mail::SpamAssassin::Plugin::ImageInfo
88 loadplugin Mail::SpamAssassin::Plugin::MIMEEval
89 loadplugin Mail::SpamAssassin::Plugin::MIMEHeader
90 # loadplugin Mail::SpamAssassin::Plugin::PDFInfo
91 #loadplugin Mail::SpamAssassin::Plugin::PhishTag
92 loadplugin Mail::SpamAssassin::Plugin::Pyzor
93 loadplugin Mail::SpamAssassin::Plugin::Razor2
94 # loadplugin Mail::SpamAssassin::Plugin::RelayCountry
95 loadplugin Mail::SpamAssassin::Plugin::RelayEval
96 loadplugin Mail::SpamAssassin::Plugin::ReplaceTags
97 # loadplugin Mail::SpamAssassin::Plugin::Rule2XSBody
98 # loadplugin Mail::SpamAssassin::Plugin::Shortcircuit
99 loadplugin Mail::SpamAssassin::Plugin::SpamCop
100 loadplugin Mail::SpamAssassin::Plugin::SPF
101 #loadplugin Mail::SpamAssassin::Plugin::TextCat
102 # loadplugin Mail::SpamAssassin::Plugin::TxRep
103 loadplugin Mail::SpamAssassin::Plugin::URIDetail
104 loadplugin Mail::SpamAssassin::Plugin::URIDNSBL
105 loadplugin Mail::SpamAssassin::Plugin::URIEval
106 # loadplugin Mail::SpamAssassin::Plugin::URILocalBL
107 loadplugin Mail::SpamAssassin::Plugin::VBounce
108 loadplugin Mail::SpamAssassin::Plugin::WhiteListSubject
109 loadplugin Mail::SpamAssassin::Plugin::WLBLEval
110 '';
111 };
112 };
113 };
114
115 config = lib.mkIf cfg.enable {
116 environment.etc."mail/spamassassin/init.pre".source = cfg.initPreConf;
117 environment.etc."mail/spamassassin/local.cf".source = spamassassin-local-cf;
118
119 # Allow users to run 'spamc'.
120 environment.systemPackages = [ pkgs.spamassassin ];
121
122 users.users.spamd = {
123 description = "Spam Assassin Daemon";
124 uid = config.ids.uids.spamd;
125 group = "spamd";
126 };
127
128 users.groups.spamd = {
129 gid = config.ids.gids.spamd;
130 };
131
132 systemd.services.sa-update = {
133 # Needs to be able to contact the update server.
134 wants = [ "network-online.target" ];
135 after = [ "network-online.target" ];
136
137 serviceConfig = {
138 Type = "oneshot";
139 User = "spamd";
140 Group = "spamd";
141 StateDirectory = "spamassassin";
142 ExecStartPost = "+${config.systemd.package}/bin/systemctl -q --no-block try-reload-or-restart spamd.service";
143 };
144
145 script = ''
146 set +e
147 ${pkgs.spamassassin}/bin/sa-update --verbose --gpghomedir=/var/lib/spamassassin/sa-update-keys/
148 rc=$?
149 set -e
150
151 if [[ $rc -gt 1 ]]; then
152 # sa-update failed.
153 exit $rc
154 fi
155
156 if [[ $rc -eq 1 ]]; then
157 # No update was available, exit successfully.
158 exit 0
159 fi
160
161 # An update was available and installed. Compile the rules.
162 ${pkgs.spamassassin}/bin/sa-compile
163 '';
164 };
165
166 systemd.timers.sa-update = {
167 description = "sa-update-service";
168 partOf = [ "sa-update.service" ];
169 wantedBy = [ "timers.target" ];
170 timerConfig = {
171 OnCalendar = "1:*";
172 Persistent = true;
173 };
174 };
175
176 systemd.services.spamd = {
177 description = "SpamAssassin Server";
178
179 wantedBy = [ "multi-user.target" ];
180 wants = [ "sa-update.service" ];
181 after = [
182 "network.target"
183 "sa-update.service"
184 ];
185
186 serviceConfig = {
187 User = "spamd";
188 Group = "spamd";
189 ExecStart = "+${pkgs.spamassassin}/bin/spamd ${lib.optionalString cfg.debug "-D"} --username=spamd --groupname=spamd --virtual-config-dir=%S/spamassassin/user-%u --allow-tell --pidfile=/run/spamd.pid";
190 ExecReload = "+${pkgs.coreutils}/bin/kill -HUP $MAINPID";
191 StateDirectory = "spamassassin";
192 };
193 };
194 };
195}