pyrox.dev
1{
2 pkgs,
3 lib,
4 config,
5 ...
6}:
7with lib;
8let
9 cfg = config.services.mmsd;
10 dbusServiceFile = pkgs.writeTextDir "share/dbus-1/services/org.ofono.mms.service" ''
11 [D-BUS Service]
12 Name=org.ofono.mms
13 SystemdService=dbus-org.ofono.mms.service
14
15 # Exec= is still required despite SystemdService= being used:
16 # https://github.com/freedesktop/dbus/blob/ef55a3db0d8f17848f8a579092fb05900cc076f5/test/data/systemd-activation/com.example.SystemdActivatable1.service
17 Exec=${pkgs.coreutils}/bin/false mmsd
18 '';
19in
20{
21 options.services.mmsd = {
22 enable = mkEnableOption "Multimedia Messaging Service Daemon";
23 extraArgs = mkOption {
24 type = with types; listOf str;
25 description = "Extra arguments passed to `mmsd-tng`";
26 default = [ ];
27 example = [ "--debug" ];
28 };
29 };
30 config = mkIf cfg.enable {
31 services.dbus.packages = [ dbusServiceFile ];
32 systemd.user.services.mmsd = {
33 after = [ "ModemManager.service" ];
34 aliases = [ "dbus-org.ofono.mms.service" ];
35 serviceConfig = {
36 Type = "dbus";
37 ExecStart = "${pkgs.mmsd-tng}/bin/mmsdtng " + escapeShellArgs cfg.extraArgs;
38 BusName = "org.ofono.mms";
39 Restart = "on-failure";
40 };
41 };
42 };
43}