pyrox.dev
1import ./make-test-python.nix (
2 { pkgs, lib, ... }:
3 {
4 name = "budgie";
5
6 meta.maintainers = lib.teams.budgie.members;
7
8 nodes.machine =
9 { ... }:
10 {
11 imports = [
12 ./common/user-account.nix
13 ];
14
15 services.xserver.enable = true;
16
17 services.xserver.displayManager = {
18 lightdm.enable = true;
19 autoLogin = {
20 enable = true;
21 user = "alice";
22 };
23 };
24
25 # We don't ship gnome-text-editor in Budgie module, we add this line mainly
26 # to catch eval issues related to this option.
27 environment.budgie.excludePackages = [ pkgs.gnome-text-editor ];
28
29 services.xserver.desktopManager.budgie = {
30 enable = true;
31 extraPlugins = [
32 pkgs.budgie-analogue-clock-applet
33 ];
34 };
35 };
36
37 testScript =
38 { nodes, ... }:
39 let
40 user = nodes.machine.users.users.alice;
41 env = "DBUS_SESSION_BUS_ADDRESS=unix:path=/run/user/${toString user.uid}/bus DISPLAY=:0";
42 su = command: "su - ${user.name} -c '${env} ${command}'";
43 in
44 ''
45 with subtest("Wait for login"):
46 # wait_for_x() checks graphical-session.target, which is expected to be
47 # inactive on Budgie before Budgie manages user session with systemd.
48 # https://github.com/BuddiesOfBudgie/budgie-desktop/blob/39e9f0895c978f76/src/session/budgie-desktop.in#L16
49 #
50 # Previously this was unconditionally touched by xsessionWrapper but was
51 # changed in #233981 (we have Budgie:GNOME in XDG_CURRENT_DESKTOP).
52 # machine.wait_for_x()
53 machine.wait_until_succeeds('journalctl -t budgie-session-binary --grep "Entering running state"')
54 machine.wait_for_file("${user.home}/.Xauthority")
55 machine.succeed("xauth merge ${user.home}/.Xauthority")
56
57 with subtest("Check that logging in has given the user ownership of devices"):
58 machine.succeed("getfacl -p /dev/snd/timer | grep -q ${user.name}")
59
60 with subtest("Check if Budgie session components actually start"):
61 for i in ["budgie-daemon", "budgie-panel", "budgie-wm", "budgie-desktop-view", "gsd-media-keys"]:
62 machine.wait_until_succeeds(f"pgrep -f {i}")
63 # We don't check xwininfo for budgie-wm.
64 # See https://github.com/NixOS/nixpkgs/pull/216737#discussion_r1155312754
65 machine.wait_for_window("budgie-daemon")
66 machine.wait_for_window("budgie-panel")
67
68 with subtest("Check if various environment variables are set"):
69 cmd = "xargs --null --max-args=1 echo < /proc/$(pgrep -xf /run/current-system/sw/bin/budgie-wm)/environ"
70 machine.succeed(f"{cmd} | grep 'XDG_CURRENT_DESKTOP' | grep 'Budgie:GNOME'")
71 machine.succeed(f"{cmd} | grep 'BUDGIE_PLUGIN_DATADIR' | grep '${pkgs.budgie-desktop-with-plugins.pname}'")
72
73 with subtest("Open run dialog"):
74 machine.send_key("alt-f2")
75 machine.wait_for_window("budgie-run-dialog")
76 machine.sleep(2)
77 machine.screenshot("run_dialog")
78 machine.send_key("esc")
79
80 with subtest("Open Budgie Control Center"):
81 machine.succeed("${su "budgie-control-center >&2 &"}")
82 machine.wait_for_window("Budgie Control Center")
83
84 with subtest("Lock the screen"):
85 machine.succeed("${su "budgie-screensaver-command -l >&2 &"}")
86 machine.wait_until_succeeds("${su "budgie-screensaver-command -q"} | grep 'The screensaver is active'")
87 machine.sleep(2)
88 machine.send_chars("${user.password}", delay=0.5)
89 machine.screenshot("budgie_screensaver")
90 machine.send_chars("\n")
91 machine.wait_until_succeeds("${su "budgie-screensaver-command -q"} | grep 'The screensaver is inactive'")
92 machine.sleep(2)
93
94 with subtest("Open GNOME terminal"):
95 machine.succeed("${su "gnome-terminal"}")
96 machine.wait_for_window("${user.name}@machine: ~")
97
98 with subtest("Check if Budgie has ever coredumped"):
99 machine.fail("coredumpctl --json=short | grep budgie")
100 machine.sleep(10)
101 machine.screenshot("screen")
102 '';
103 }
104)