pyrox.dev
1{ lib, php, ... }:
2{
3 name = "php-${php.version}-fpm-nginx-test";
4 meta.maintainers = lib.teams.php.members;
5
6 nodes.machine =
7 { config, pkgs, ... }:
8 {
9 environment.systemPackages = [ php ];
10
11 services.nginx = {
12 enable = true;
13
14 virtualHosts."phpfpm" =
15 let
16 testdir = pkgs.writeTextDir "web/index.php" "<?php phpinfo();";
17 in
18 {
19 root = "${testdir}/web";
20 locations."~ \\.php$".extraConfig = ''
21 fastcgi_pass unix:${config.services.phpfpm.pools.foobar.socket};
22 fastcgi_index index.php;
23 include ${config.services.nginx.package}/conf/fastcgi_params;
24 include ${pkgs.nginx}/conf/fastcgi.conf;
25 '';
26 locations."/" = {
27 tryFiles = "$uri $uri/ index.php";
28 index = "index.php index.html index.htm";
29 };
30 };
31 };
32
33 services.phpfpm.pools."foobar" = {
34 user = "nginx";
35 phpPackage = php;
36 settings = {
37 "listen.group" = "nginx";
38 "listen.mode" = "0600";
39 "listen.owner" = "nginx";
40 "pm" = "dynamic";
41 "pm.max_children" = 5;
42 "pm.max_requests" = 500;
43 "pm.max_spare_servers" = 3;
44 "pm.min_spare_servers" = 1;
45 "pm.start_servers" = 2;
46 };
47 };
48 };
49 testScript =
50 { ... }:
51 ''
52 machine.wait_for_unit("nginx.service")
53 machine.wait_for_unit("phpfpm-foobar.service")
54
55 # Check so we get an evaluated PHP back
56 response = machine.succeed("curl -fvvv -s http://127.0.0.1:80/")
57 assert "PHP Version ${php.version}" in response, "PHP version not detected"
58
59 # Check so we have database and some other extensions loaded
60 for ext in ["json", "opcache", "pdo_mysql", "pdo_pgsql", "pdo_sqlite", "apcu"]:
61 assert ext in response, f"Missing {ext} extension"
62 machine.succeed(f'test -n "$(php -m | grep -i {ext})"')
63 '';
64}