pyrox.dev
1import ./make-test-python.nix (
2 { lib, pkgs, ... }:
3 {
4 name = "stub-ld";
5
6 nodes.machine =
7 { lib, ... }:
8 {
9 environment.stub-ld.enable = true;
10
11 specialisation.nostub = {
12 inheritParentConfig = true;
13
14 configuration =
15 { ... }:
16 {
17 environment.stub-ld.enable = lib.mkForce false;
18 };
19 };
20 };
21
22 testScript =
23 let
24 libDir = pkgs.stdenv.hostPlatform.libDir;
25 ldsoBasename = lib.last (lib.splitString "/" pkgs.stdenv.cc.bintools.dynamicLinker);
26
27 check32 = pkgs.stdenv.hostPlatform.isx86_64;
28 pkgs32 = pkgs.pkgsi686Linux;
29
30 libDir32 = pkgs32.stdenv.hostPlatform.libDir;
31 ldsoBasename32 = lib.last (lib.splitString "/" pkgs32.stdenv.cc.bintools.dynamicLinker);
32
33 test-exec =
34 builtins.mapAttrs
35 (
36 n: v:
37 pkgs.runCommand "test-exec-${n}" { src = pkgs.fetchurl v; } "mkdir -p $out;cd $out;tar -xzf $src"
38 )
39 {
40 x86_64-linux.url = "https://github.com/rustic-rs/rustic/releases/download/v0.6.1/rustic-v0.6.1-x86_64-unknown-linux-gnu.tar.gz";
41 x86_64-linux.hash = "sha256-3zySzx8MKFprMOi++yr2ZGASE0aRfXHQuG3SN+kWUCI=";
42 i686-linux.url = "https://github.com/rustic-rs/rustic/releases/download/v0.6.1/rustic-v0.6.1-i686-unknown-linux-gnu.tar.gz";
43 i686-linux.hash = "sha256-fWNiATFeg0B2pfB5zndlnzGn7Ztl8diVS1rFLEDnSLU=";
44 aarch64-linux.url = "https://github.com/rustic-rs/rustic/releases/download/v0.6.1/rustic-v0.6.1-aarch64-unknown-linux-gnu.tar.gz";
45 aarch64-linux.hash = "sha256-hnldbd2cctQIAhIKoEZLIWY8H3jiFBClkNy2UlyyvAs=";
46 };
47 exec-name = "rustic";
48
49 if32 = pythonStatement: if check32 then pythonStatement else "pass";
50 in
51 ''
52 machine.start()
53 machine.wait_for_unit("multi-user.target")
54
55 with subtest("Check for stub (enabled, initial)"):
56 machine.succeed('test -L /${libDir}/${ldsoBasename}')
57 ${if32 "machine.succeed('test -L /${libDir32}/${ldsoBasename32}')"}
58
59 with subtest("Try FHS executable"):
60 machine.copy_from_host('${test-exec.${pkgs.stdenv.hostPlatform.system}}','test-exec')
61 machine.succeed('if test-exec/${exec-name} 2>outfile; then false; else [ $? -eq 127 ];fi')
62 machine.succeed('grep -qi nixos outfile')
63 ${if32 "machine.copy_from_host('${
64 test-exec.${pkgs32.stdenv.hostPlatform.system}
65 }','test-exec32')"}
66 ${if32 "machine.succeed('if test-exec32/${exec-name} 2>outfile32; then false; else [ $? -eq 127 ];fi')"}
67 ${if32 "machine.succeed('grep -qi nixos outfile32')"}
68
69 with subtest("Disable stub"):
70 machine.succeed("/run/booted-system/specialisation/nostub/bin/switch-to-configuration test")
71
72 with subtest("Check for stub (disabled)"):
73 machine.fail('test -e /${libDir}/${ldsoBasename}')
74 ${if32 "machine.fail('test -e /${libDir32}/${ldsoBasename32}')"}
75
76 with subtest("Create file in stub location (to be overwritten)"):
77 machine.succeed('mkdir -p /${libDir};touch /${libDir}/${ldsoBasename}')
78 ${if32 "machine.succeed('mkdir -p /${libDir32};touch /${libDir32}/${ldsoBasename32}')"}
79
80 with subtest("Re-enable stub"):
81 machine.succeed("/run/booted-system/bin/switch-to-configuration test")
82
83 with subtest("Check for stub (enabled, final)"):
84 machine.succeed('test -L /${libDir}/${ldsoBasename}')
85 ${if32 "machine.succeed('test -L /${libDir32}/${ldsoBasename32}')"}
86 '';
87 }
88)