pyrox.dev
1import ./make-test-python.nix (
2 { lib, pkgs, ... }:
3 {
4 name = "systemd-initrd-swraid";
5
6 nodes.machine =
7 { pkgs, ... }:
8 {
9 # Use systemd-boot
10 virtualisation = {
11 emptyDiskImages = [
12 512
13 512
14 ];
15 useBootLoader = true;
16 # Booting off the RAID requires an available init script
17 mountHostNixStore = true;
18 useEFIBoot = true;
19 };
20 boot.loader.systemd-boot.enable = true;
21 boot.loader.efi.canTouchEfiVariables = true;
22
23 environment.systemPackages = with pkgs; [
24 mdadm
25 e2fsprogs
26 ]; # for mdadm and mkfs.ext4
27 boot.swraid = {
28 enable = true;
29 mdadmConf = ''
30 ARRAY /dev/md0 devices=/dev/vdb,/dev/vdc
31 '';
32 };
33 environment.etc."mdadm.conf".text = ''
34 MAILADDR test@example.com
35 '';
36 boot.initrd = {
37 systemd = {
38 enable = true;
39 emergencyAccess = true;
40 };
41 kernelModules = [ "raid0" ];
42 };
43
44 specialisation.boot-swraid.configuration.virtualisation.rootDevice = "/dev/disk/by-label/testraid";
45 # This protects against a regression. We do not have to switch to it.
46 # It's sufficient to trigger its evaluation.
47 specialisation.build-old-initrd.configuration.boot.initrd.systemd.enable = lib.mkForce false;
48 };
49
50 testScript = ''
51 # Create RAID
52 machine.succeed("mdadm --create --force /dev/md0 -n 2 --level=raid1 /dev/vdb /dev/vdc --metadata=0.90")
53 machine.succeed("mkfs.ext4 -L testraid /dev/md0")
54 machine.succeed("mkdir -p /mnt && mount /dev/md0 /mnt && echo hello > /mnt/test && umount /mnt")
55
56 # Boot from the RAID
57 machine.succeed("bootctl set-default nixos-generation-1-specialisation-boot-swraid.conf")
58 machine.succeed("sync")
59 machine.crash()
60 machine.wait_for_unit("multi-user.target")
61
62 # Ensure we have successfully booted from the RAID
63 assert "(initrd)" in machine.succeed("systemd-analyze") # booted with systemd in stage 1
64 assert "/dev/md0 on / type ext4" in machine.succeed("mount")
65 assert "hello" in machine.succeed("cat /test")
66 assert "md0" in machine.succeed("cat /proc/mdstat")
67
68 expected_config = """MAILADDR test@example.com
69
70 ARRAY /dev/md0 devices=/dev/vdb,/dev/vdc
71 """
72 got_config = machine.execute("cat /etc/mdadm.conf")[1]
73 assert expected_config == got_config, repr((expected_config, got_config))
74 machine.wait_for_unit("mdmonitor.service")
75 '';
76 }
77)