pyrox.dev
1# Overriding {#chap-overrides}
2
3Sometimes one wants to override parts of `nixpkgs`, e.g. derivation attributes, the results of derivations.
4
5These functions are used to make changes to packages, returning only single packages. [Overlays](#chap-overlays), on the other hand, can be used to combine the overridden packages across the entire package set of Nixpkgs.
6
7## <pkg>.override {#sec-pkg-override}
8
9The function `override` is usually available for all the derivations in the nixpkgs expression (`pkgs`).
10
11It is used to override the arguments passed to a function.
12
13Example usages:
14
15```nix
16pkgs.foo.override {
17 arg1 = val1;
18 arg2 = val2; # ...
19}
20```
21
22It's also possible to access the previous arguments.
23
24```nix
25pkgs.foo.override (previous: {
26 arg1 = previous.arg1; # ...
27})
28```
29
30<!-- TODO: move below programlisting to a new section about extending and overlays and reference it -->
31
32```nix
33import pkgs.path {
34 overlays = [ (self: super: { foo = super.foo.override { barSupport = true; }; }) ];
35}
36```
37
38```nix
39{
40 mypkg = pkgs.callPackage ./mypkg.nix {
41 mydep = pkgs.mydep.override {
42 # ...
43 };
44 };
45}
46```
47
48In the first example, `pkgs.foo` is the result of a function call with some default arguments, usually a derivation. Using `pkgs.foo.override` will call the same function with the given new arguments.
49
50Many packages, like the `foo` example above, provide package options with default values in their arguments, to facilitate overriding.
51Because it's not usually feasible to test that packages build with all combinations of options, you might find that a package doesn't build if you override options to non-default values.
52
53Package maintainers are not expected to fix arbitrary combinations of options.
54If you find that something doesn't work, please submit a fix, ideally with a regression test.
55If you want to ensure that things keep working, consider [becoming a maintainer](https://github.com/NixOS/nixpkgs/tree/master/maintainers) for the package.
56
57## <pkg>.overrideAttrs {#sec-pkg-overrideAttrs}
58
59The function `overrideAttrs` allows overriding the attribute set passed to a `stdenv.mkDerivation` call, producing a new derivation based on the original one. This function is available on all derivations produced by the `stdenv.mkDerivation` function, which is most packages in the Nixpkgs expression `pkgs`.
60
61Example usages:
62
63```nix
64{
65 helloBar = pkgs.hello.overrideAttrs (
66 finalAttrs: previousAttrs: { pname = previousAttrs.pname + "-bar"; }
67 );
68}
69```
70
71In the above example, "-bar" is appended to the pname attribute, while all other attributes will be retained from the original `hello` package.
72
73The argument `previousAttrs` is conventionally used to refer to the attr set originally passed to `stdenv.mkDerivation`.
74
75The argument `finalAttrs` refers to the final attributes passed to `mkDerivation`, plus the `finalPackage` attribute which is equal to the result of `mkDerivation` or subsequent `overrideAttrs` calls.
76
77If only a one-argument function is written, the argument has the meaning of `previousAttrs`.
78
79Function arguments can be omitted entirely if there is no need to access `previousAttrs` or `finalAttrs`.
80
81```nix
82{ helloWithDebug = pkgs.hello.overrideAttrs { separateDebugInfo = true; }; }
83```
84
85In the above example, the `separateDebugInfo` attribute is overridden to be true, thus building debug info for `helloWithDebug`.
86
87::: {.note}
88Note that `separateDebugInfo` is processed only by the `stdenv.mkDerivation` function, not the generated, raw Nix derivation. Thus, using `overrideDerivation` will not work in this case, as it overrides only the attributes of the final derivation. It is for this reason that `overrideAttrs` should be preferred in (almost) all cases to `overrideDerivation`, i.e. to allow using `stdenv.mkDerivation` to process input arguments, as well as the fact that it is easier to use (you can use the same attribute names you see in your Nix code, instead of the ones generated (e.g. `buildInputs` vs `nativeBuildInputs`), and it involves less typing).
89:::
90
91## <pkg>.overrideDerivation {#sec-pkg-overrideDerivation}
92
93::: {.warning}
94You should prefer `overrideAttrs` in almost all cases, see its documentation for the reasons why. `overrideDerivation` is not deprecated and will continue to work, but is less nice to use and does not have as many abilities as `overrideAttrs`.
95:::
96
97::: {.warning}
98Do not use this function in Nixpkgs as it evaluates a derivation before modifying it, which breaks package abstraction. In addition, this evaluation-per-function application incurs a performance penalty, which can become a problem if many overrides are used. It is only intended for ad-hoc customisation, such as in `~/.config/nixpkgs/config.nix`.
99:::
100
101The function `overrideDerivation` creates a new derivation based on an existing one by overriding the original's attributes with the attribute set produced by the specified function. This function is available on all derivations defined using the `makeOverridable` function. Most standard derivation-producing functions, such as `stdenv.mkDerivation`, are defined using this function, which means most packages in the Nixpkgs expression, `pkgs`, have this function.
102
103Example usage:
104
105```nix
106{
107 mySed = pkgs.gnused.overrideDerivation (oldAttrs: {
108 name = "sed-4.2.2-pre";
109 src = fetchurl {
110 url = "ftp://alpha.gnu.org/gnu/sed/sed-4.2.2-pre.tar.bz2";
111 hash = "sha256-MxBJRcM2rYzQYwJ5XKxhXTQByvSg5jZc5cSHEZoB2IY=";
112 };
113 patches = [ ];
114 });
115}
116```
117
118In the above example, the `name`, `src`, and `patches` of the derivation will be overridden, while all other attributes will be retained from the original derivation.
119
120The argument `oldAttrs` is used to refer to the attribute set of the original derivation.
121
122::: {.note}
123A package's attributes are evaluated *before* being modified by the `overrideDerivation` function. For example, the `name` attribute reference in `url = "mirror://gnu/hello/${name}.tar.gz";` is filled-in *before* the `overrideDerivation` function modifies the attribute set. This means that overriding the `name` attribute, in this example, *will not* change the value of the `url` attribute. Instead, we need to override both the `name` *and* `url` attributes.
124:::
125
126## lib.makeOverridable {#sec-lib-makeOverridable}
127
128The function `lib.makeOverridable` is used to make the result of a function easily customizable. This utility only makes sense for functions that accept an argument set and return an attribute set.
129
130Example usage:
131
132```nix
133{
134 f =
135 { a, b }:
136 {
137 result = a + b;
138 };
139 c = lib.makeOverridable f {
140 a = 1;
141 b = 2;
142 };
143}
144```
145
146The variable `c` is the value of the `f` function applied with some default arguments. Hence the value of `c.result` is `3`, in this example.
147
148The variable `c` however also has some additional functions, like
149[c.override](#sec-pkg-override) which can be used to override the
150default arguments. In this example the value of
151`(c.override { a = 4; }).result` is 6.