pyrox.dev
1# To build, use:
2# nix-build nixos -I nixos-config=nixos/modules/installer/sd-card/sd-image-raspberrypi.nix -A config.system.build.sdImage
3{
4 config,
5 lib,
6 pkgs,
7 ...
8}:
9
10{
11 imports = [
12 ../../profiles/base.nix
13 ./sd-image.nix
14 ];
15
16 boot.loader.grub.enable = false;
17 boot.loader.generic-extlinux-compatible.enable = true;
18
19 boot.consoleLogLevel = lib.mkDefault 7;
20 boot.kernelPackages = pkgs.linuxKernel.packages.linux_rpi1;
21
22 sdImage = {
23 populateFirmwareCommands =
24 let
25 configTxt = pkgs.writeText "config.txt" ''
26 # u-boot refuses to start (gets stuck at rainbow polygon) without this,
27 # at least on Raspberry Pi 0.
28 enable_uart=1
29
30 # Prevent the firmware from smashing the framebuffer setup done by the mainline kernel
31 # when attempting to show low-voltage or overtemperature warnings.
32 avoid_warnings=1
33
34 [pi0]
35 kernel=u-boot-rpi0.bin
36
37 [pi1]
38 kernel=u-boot-rpi1.bin
39 '';
40 in
41 ''
42 (cd ${pkgs.raspberrypifw}/share/raspberrypi/boot && cp bootcode.bin fixup*.dat start*.elf *.dtb $NIX_BUILD_TOP/firmware/)
43 cp ${pkgs.ubootRaspberryPiZero}/u-boot.bin firmware/u-boot-rpi0.bin
44 cp ${pkgs.ubootRaspberryPi}/u-boot.bin firmware/u-boot-rpi1.bin
45 cp ${configTxt} firmware/config.txt
46 '';
47 populateRootCommands = ''
48 mkdir -p ./files/boot
49 ${config.boot.loader.generic-extlinux-compatible.populateCmd} -c ${config.system.build.toplevel} -d ./files/boot
50 '';
51 };
52}