pyrox.dev
1{
2 config,
3 lib,
4 pkgs,
5 ...
6}:
7
8let
9 cfg = config.virtualisation.waydroid;
10 kCfg = config.lib.kernelConfig;
11 waydroidGbinderConf = pkgs.writeText "waydroid.conf" ''
12 [Protocol]
13 /dev/binder = aidl2
14 /dev/vndbinder = aidl2
15 /dev/hwbinder = hidl
16
17 [ServiceManager]
18 /dev/binder = aidl2
19 /dev/vndbinder = aidl2
20 /dev/hwbinder = hidl
21 '';
22
23in
24{
25
26 options.virtualisation.waydroid = {
27 enable = lib.mkEnableOption "Waydroid";
28 package = lib.mkPackageOption pkgs "waydroid" { };
29 };
30
31 config = lib.mkIf cfg.enable {
32 assertions = lib.singleton {
33 assertion = lib.versionAtLeast (lib.getVersion config.boot.kernelPackages.kernel) "4.18";
34 message = "Waydroid needs user namespace support to work properly";
35 };
36
37 system.requiredKernelConfig = [
38 (kCfg.isEnabled "ANDROID_BINDER_IPC")
39 (kCfg.isEnabled "ANDROID_BINDERFS")
40 (kCfg.isEnabled "MEMFD_CREATE")
41 ];
42
43 /*
44 NOTE: we always enable this flag even if CONFIG_PSI_DEFAULT_DISABLED is not on
45 as reading the kernel config is not always possible and on kernels where it's
46 already on it will be no-op
47 */
48 boot.kernelParams = [ "psi=1" ];
49
50 environment.etc."gbinder.d/waydroid.conf".source = waydroidGbinderConf;
51
52 environment.systemPackages = [ cfg.package ];
53
54 networking.firewall.trustedInterfaces = [ "waydroid0" ];
55
56 virtualisation.lxc.enable = true;
57
58 systemd.services.waydroid-container = {
59 description = "Waydroid Container";
60
61 wantedBy = [ "multi-user.target" ];
62
63 serviceConfig = {
64 Type = "dbus";
65 UMask = "0022";
66 ExecStart = "${cfg.package}/bin/waydroid -w container start";
67 BusName = "id.waydro.Container";
68 };
69 };
70
71 systemd.tmpfiles.rules = [
72 "d /var/lib/misc 0755 root root -" # for dnsmasq.leases
73 ];
74
75 services.dbus.packages = [ cfg.package ];
76 };
77
78}