pyrox.dev
1{ pkgs, lib, ... }:
2{
3 name = "budgie";
4
5 meta.maintainers = lib.teams.budgie.members;
6
7 nodes.machine =
8 { ... }:
9 {
10 imports = [
11 ./common/user-account.nix
12 ];
13
14 services.xserver.enable = true;
15
16 services.xserver.displayManager = {
17 lightdm.enable = true;
18 autoLogin = {
19 enable = true;
20 user = "alice";
21 };
22 };
23
24 # We don't ship gnome-text-editor in Budgie module, we add this line mainly
25 # to catch eval issues related to this option.
26 environment.budgie.excludePackages = [ pkgs.gnome-text-editor ];
27
28 services.xserver.desktopManager.budgie = {
29 enable = true;
30 extraPlugins = [
31 pkgs.budgie-analogue-clock-applet
32 ];
33 };
34 };
35
36 testScript =
37 { nodes, ... }:
38 let
39 user = nodes.machine.users.users.alice;
40 env = "DBUS_SESSION_BUS_ADDRESS=unix:path=/run/user/${toString user.uid}/bus DISPLAY=:0";
41 su = command: "su - ${user.name} -c '${env} ${command}'";
42 in
43 ''
44 with subtest("Wait for login"):
45 # wait_for_x() checks graphical-session.target, which is expected to be
46 # inactive on Budgie before Budgie manages user session with systemd.
47 # https://github.com/BuddiesOfBudgie/budgie-desktop/blob/39e9f0895c978f76/src/session/budgie-desktop.in#L16
48 #
49 # Previously this was unconditionally touched by xsessionWrapper but was
50 # changed in #233981 (we have Budgie:GNOME in XDG_CURRENT_DESKTOP).
51 # machine.wait_for_x()
52 machine.wait_until_succeeds('journalctl -t budgie-session-binary --grep "Entering running state"')
53 machine.wait_for_file("${user.home}/.Xauthority")
54 machine.succeed("xauth merge ${user.home}/.Xauthority")
55
56 with subtest("Check that logging in has given the user ownership of devices"):
57 machine.succeed("getfacl -p /dev/snd/timer | grep -q ${user.name}")
58
59 with subtest("Check if Budgie session components actually start"):
60 for i in ["budgie-daemon", "budgie-panel", "budgie-wm", "budgie-desktop-view", "gsd-media-keys"]:
61 machine.wait_until_succeeds(f"pgrep -f {i}")
62 # We don't check xwininfo for budgie-wm.
63 # See https://github.com/NixOS/nixpkgs/pull/216737#discussion_r1155312754
64 machine.wait_for_window("budgie-daemon")
65 machine.wait_for_window("budgie-panel")
66
67 with subtest("Check if various environment variables are set"):
68 cmd = "xargs --null --max-args=1 echo < /proc/$(pgrep -xf /run/current-system/sw/bin/budgie-wm)/environ"
69 machine.succeed(f"{cmd} | grep 'XDG_CURRENT_DESKTOP' | grep 'Budgie:GNOME'")
70 machine.succeed(f"{cmd} | grep 'BUDGIE_PLUGIN_DATADIR' | grep '${pkgs.budgie-desktop-with-plugins.pname}'")
71 # From the nixos/budgie module
72 machine.succeed(f"{cmd} | grep 'SSH_AUTH_SOCK' | grep 'gcr'")
73
74 with subtest("Open run dialog"):
75 machine.send_key("alt-f2")
76 machine.wait_for_window("budgie-run-dialog")
77 machine.sleep(2)
78 machine.screenshot("run_dialog")
79 machine.send_key("esc")
80
81 with subtest("Open Budgie Control Center"):
82 machine.succeed("${su "budgie-control-center >&2 &"}")
83 machine.wait_for_window("Budgie Control Center")
84
85 with subtest("Lock the screen"):
86 machine.succeed("${su "budgie-screensaver-command -l >&2 &"}")
87 machine.wait_until_succeeds("${su "budgie-screensaver-command -q"} | grep 'The screensaver is active'")
88 machine.sleep(2)
89 machine.send_chars("${user.password}", delay=0.5)
90 machine.screenshot("budgie_screensaver")
91 machine.send_chars("\n")
92 machine.wait_until_succeeds("${su "budgie-screensaver-command -q"} | grep 'The screensaver is inactive'")
93 machine.sleep(2)
94
95 with subtest("Open GNOME terminal"):
96 machine.succeed("${su "gnome-terminal"}")
97 machine.wait_for_window("${user.name}@machine: ~")
98
99 with subtest("Check if Budgie has ever coredumped"):
100 machine.fail("coredumpctl --json=short | grep budgie")
101 machine.sleep(10)
102 machine.screenshot("screen")
103 '';
104}