pyrox.dev
1{ lib, ... }:
2let
3 cfg = {
4 clusterId = "066ae264-2a5d-4729-8001-6ad265f50b03";
5 monA = {
6 name = "a";
7 ip = "192.168.1.1";
8 };
9 osd0 = {
10 name = "0";
11 ip = "192.168.1.2";
12 key = "AQBCEJNa3s8nHRAANvdsr93KqzBznuIWm2gOGg==";
13 uuid = "55ba2294-3e24-478f-bee0-9dca4c231dd9";
14 };
15 osd1 = {
16 name = "1";
17 ip = "192.168.1.3";
18 key = "AQBEEJNac00kExAAXEgy943BGyOpVH1LLlHafQ==";
19 uuid = "5e97a838-85b6-43b0-8950-cb56d554d1e5";
20 };
21 osd2 = {
22 name = "2";
23 ip = "192.168.1.4";
24 key = "AQAdyhZeIaUlARAAGRoidDAmS6Vkp546UFEf5w==";
25 uuid = "ea999274-13d0-4dd5-9af9-ad25a324f72f";
26 };
27 };
28 generateCephConfig =
29 { daemonConfig }:
30 {
31 enable = true;
32 global = {
33 fsid = cfg.clusterId;
34 monHost = cfg.monA.ip;
35 monInitialMembers = cfg.monA.name;
36 };
37 }
38 // daemonConfig;
39
40 generateHost =
41 { cephConfig, networkConfig }:
42 { pkgs, ... }:
43 {
44 virtualisation = {
45 emptyDiskImages = [ 20480 ];
46 vlans = [ 1 ];
47 };
48
49 networking = networkConfig;
50
51 environment.systemPackages = with pkgs; [
52 bash
53 sudo
54 ceph
55 xfsprogs
56 libressl.nc
57 ];
58
59 boot.kernelModules = [ "xfs" ];
60
61 services.ceph = cephConfig;
62 };
63
64 networkMonA = {
65 dhcpcd.enable = false;
66 interfaces.eth1.ipv4.addresses = lib.mkOverride 0 [
67 {
68 address = cfg.monA.ip;
69 prefixLength = 24;
70 }
71 ];
72 firewall = {
73 allowedTCPPorts = [
74 6789
75 3300
76 ];
77 allowedTCPPortRanges = [
78 {
79 from = 6800;
80 to = 7300;
81 }
82 ];
83 };
84 };
85 cephConfigMonA = generateCephConfig {
86 daemonConfig = {
87 mon = {
88 enable = true;
89 daemons = [ cfg.monA.name ];
90 };
91 mgr = {
92 enable = true;
93 daemons = [ cfg.monA.name ];
94 };
95 };
96 };
97
98 networkOsd = osd: {
99 dhcpcd.enable = false;
100 interfaces.eth1.ipv4.addresses = lib.mkOverride 0 [
101 {
102 address = osd.ip;
103 prefixLength = 24;
104 }
105 ];
106 firewall = {
107 allowedTCPPortRanges = [
108 {
109 from = 6800;
110 to = 7300;
111 }
112 ];
113 };
114 };
115
116 cephConfigOsd =
117 osd:
118 generateCephConfig {
119 daemonConfig = {
120 osd = {
121 enable = true;
122 daemons = [ osd.name ];
123 };
124 };
125 };
126
127 # Following deployment is based on the manual deployment described here:
128 # https://docs.ceph.com/docs/master/install/manual-deployment/
129 # For other ways to deploy a ceph cluster, look at the documentation at
130 # https://docs.ceph.com/docs/master/
131 testscript =
132 { ... }:
133 ''
134 start_all()
135
136 monA.wait_for_unit("network.target")
137 osd0.wait_for_unit("network.target")
138 osd1.wait_for_unit("network.target")
139 osd2.wait_for_unit("network.target")
140
141 # Bootstrap ceph-mon daemon
142 monA.succeed(
143 "sudo -u ceph ceph-authtool --create-keyring /tmp/ceph.mon.keyring --gen-key -n mon. --cap mon 'allow *'",
144 "sudo -u ceph ceph-authtool --create-keyring /etc/ceph/ceph.client.admin.keyring --gen-key -n client.admin --cap mon 'allow *' --cap osd 'allow *' --cap mds 'allow *' --cap mgr 'allow *'",
145 "sudo -u ceph ceph-authtool /tmp/ceph.mon.keyring --import-keyring /etc/ceph/ceph.client.admin.keyring",
146 "monmaptool --create --add ${cfg.monA.name} ${cfg.monA.ip} --fsid ${cfg.clusterId} /tmp/monmap",
147 "sudo -u ceph ceph-mon --mkfs -i ${cfg.monA.name} --monmap /tmp/monmap --keyring /tmp/ceph.mon.keyring",
148 "sudo -u ceph mkdir -p /var/lib/ceph/mgr/ceph-${cfg.monA.name}/",
149 "sudo -u ceph touch /var/lib/ceph/mon/ceph-${cfg.monA.name}/done",
150 "systemctl start ceph-mon-${cfg.monA.name}",
151 )
152 monA.wait_for_unit("ceph-mon-${cfg.monA.name}")
153 monA.succeed("ceph mon enable-msgr2")
154 monA.succeed("ceph config set mon auth_allow_insecure_global_id_reclaim false")
155
156 # Can't check ceph status until a mon is up
157 monA.succeed("ceph -s | grep 'mon: 1 daemons'")
158
159 # Start the ceph-mgr daemon, it has no deps and hardly any setup
160 monA.succeed(
161 "ceph auth get-or-create mgr.${cfg.monA.name} mon 'allow profile mgr' osd 'allow *' mds 'allow *' > /var/lib/ceph/mgr/ceph-${cfg.monA.name}/keyring",
162 "systemctl start ceph-mgr-${cfg.monA.name}",
163 )
164 monA.wait_for_unit("ceph-mgr-a")
165 monA.wait_until_succeeds("ceph -s | grep 'quorum ${cfg.monA.name}'")
166 monA.wait_until_succeeds("ceph -s | grep 'mgr: ${cfg.monA.name}(active,'")
167
168 # Send the admin keyring to the OSD machines
169 monA.succeed("cp /etc/ceph/ceph.client.admin.keyring /tmp/shared")
170 osd0.succeed("cp /tmp/shared/ceph.client.admin.keyring /etc/ceph")
171 osd1.succeed("cp /tmp/shared/ceph.client.admin.keyring /etc/ceph")
172 osd2.succeed("cp /tmp/shared/ceph.client.admin.keyring /etc/ceph")
173
174 # Bootstrap OSDs
175 osd0.succeed(
176 "mkfs.xfs /dev/vdb",
177 "mkdir -p /var/lib/ceph/osd/ceph-${cfg.osd0.name}",
178 "mount /dev/vdb /var/lib/ceph/osd/ceph-${cfg.osd0.name}",
179 "ceph-authtool --create-keyring /var/lib/ceph/osd/ceph-${cfg.osd0.name}/keyring --name osd.${cfg.osd0.name} --add-key ${cfg.osd0.key}",
180 'echo \'{"cephx_secret": "${cfg.osd0.key}"}\' | ceph osd new ${cfg.osd0.uuid} -i -',
181 )
182 osd1.succeed(
183 "mkfs.xfs /dev/vdb",
184 "mkdir -p /var/lib/ceph/osd/ceph-${cfg.osd1.name}",
185 "mount /dev/vdb /var/lib/ceph/osd/ceph-${cfg.osd1.name}",
186 "ceph-authtool --create-keyring /var/lib/ceph/osd/ceph-${cfg.osd1.name}/keyring --name osd.${cfg.osd1.name} --add-key ${cfg.osd1.key}",
187 'echo \'{"cephx_secret": "${cfg.osd1.key}"}\' | ceph osd new ${cfg.osd1.uuid} -i -',
188 )
189 osd2.succeed(
190 "mkfs.xfs /dev/vdb",
191 "mkdir -p /var/lib/ceph/osd/ceph-${cfg.osd2.name}",
192 "mount /dev/vdb /var/lib/ceph/osd/ceph-${cfg.osd2.name}",
193 "ceph-authtool --create-keyring /var/lib/ceph/osd/ceph-${cfg.osd2.name}/keyring --name osd.${cfg.osd2.name} --add-key ${cfg.osd2.key}",
194 'echo \'{"cephx_secret": "${cfg.osd2.key}"}\' | ceph osd new ${cfg.osd2.uuid} -i -',
195 )
196
197 # Initialize the OSDs with regular filestore
198 osd0.succeed(
199 "ceph-osd -i ${cfg.osd0.name} --mkfs --osd-uuid ${cfg.osd0.uuid}",
200 "chown -R ceph:ceph /var/lib/ceph/osd",
201 "systemctl start ceph-osd-${cfg.osd0.name}",
202 )
203 osd1.succeed(
204 "ceph-osd -i ${cfg.osd1.name} --mkfs --osd-uuid ${cfg.osd1.uuid}",
205 "chown -R ceph:ceph /var/lib/ceph/osd",
206 "systemctl start ceph-osd-${cfg.osd1.name}",
207 )
208 osd2.succeed(
209 "ceph-osd -i ${cfg.osd2.name} --mkfs --osd-uuid ${cfg.osd2.uuid}",
210 "chown -R ceph:ceph /var/lib/ceph/osd",
211 "systemctl start ceph-osd-${cfg.osd2.name}",
212 )
213 monA.wait_until_succeeds("ceph osd stat | grep -e '3 osds: 3 up[^,]*, 3 in'")
214 monA.wait_until_succeeds("ceph -s | grep 'mgr: ${cfg.monA.name}(active,'")
215 monA.wait_until_succeeds("ceph -s | grep 'HEALTH_OK'")
216
217 monA.succeed(
218 "ceph osd pool create multi-node-test 32 32",
219 "ceph osd pool ls | grep 'multi-node-test'",
220
221 # We need to enable an application on the pool, otherwise it will
222 # stay unhealthy in state POOL_APP_NOT_ENABLED.
223 # Creating a CephFS would do this automatically, but we haven't done that here.
224 # See: https://docs.ceph.com/en/reef/rados/operations/pools/#associating-a-pool-with-an-application
225 # We use the custom application name "nixos-test" for this.
226 "ceph osd pool application enable multi-node-test nixos-test",
227
228 "ceph osd pool rename multi-node-test multi-node-other-test",
229 "ceph osd pool ls | grep 'multi-node-other-test'",
230 )
231 monA.wait_until_succeeds("ceph -s | grep '2 pools, 33 pgs'")
232 monA.succeed("ceph osd pool set multi-node-other-test size 2")
233 monA.wait_until_succeeds("ceph -s | grep 'HEALTH_OK'")
234 monA.wait_until_succeeds("ceph -s | grep '33 active+clean'")
235 monA.fail(
236 "ceph osd pool ls | grep 'multi-node-test'",
237 "ceph osd pool delete multi-node-other-test multi-node-other-test --yes-i-really-really-mean-it",
238 )
239
240 # Shut down ceph on all machines in a very unpolite way
241 monA.crash()
242 osd0.crash()
243 osd1.crash()
244 osd2.crash()
245
246 # Start it up
247 osd0.start()
248 osd1.start()
249 osd2.start()
250 monA.start()
251
252 # Ensure the cluster comes back up again
253 monA.succeed("ceph -s | grep 'mon: 1 daemons'")
254 monA.wait_until_succeeds("ceph -s | grep 'quorum ${cfg.monA.name}'")
255 monA.wait_until_succeeds("ceph osd stat | grep -e '3 osds: 3 up[^,]*, 3 in'")
256 monA.wait_until_succeeds("ceph -s | grep 'mgr: ${cfg.monA.name}(active,'")
257 monA.wait_until_succeeds("ceph -s | grep 'HEALTH_OK'")
258 '';
259in
260{
261 name = "basic-multi-node-ceph-cluster";
262 meta = with lib.maintainers; {
263 maintainers = [ lejonet ];
264 };
265
266 nodes = {
267 monA = generateHost {
268 cephConfig = cephConfigMonA;
269 networkConfig = networkMonA;
270 };
271 osd0 = generateHost {
272 cephConfig = cephConfigOsd cfg.osd0;
273 networkConfig = networkOsd cfg.osd0;
274 };
275 osd1 = generateHost {
276 cephConfig = cephConfigOsd cfg.osd1;
277 networkConfig = networkOsd cfg.osd1;
278 };
279 osd2 = generateHost {
280 cephConfig = cephConfigOsd cfg.osd2;
281 networkConfig = networkOsd cfg.osd2;
282 };
283 };
284
285 testScript = testscript;
286}