pyrox.dev
1{ lib, ... }:
2{
3 name = "nvmetcfg";
4
5 meta = {
6 maintainers = with lib.maintainers; [ nickcao ];
7 };
8
9 nodes = {
10 server =
11 { pkgs, ... }:
12 {
13 boot.kernelModules = [ "nvmet" ];
14 environment.systemPackages = [ pkgs.nvmetcfg ];
15 networking.firewall.allowedTCPPorts = [ 4420 ];
16 virtualisation.emptyDiskImages = [ 512 ];
17 };
18 client =
19 { pkgs, ... }:
20 {
21 boot.kernelModules = [ "nvme-fabrics" ];
22 environment.systemPackages = [ pkgs.nvme-cli ];
23 };
24 };
25
26 testScript =
27 let
28 subsystem = "nqn.2014-08.org.nixos:server";
29 in
30 ''
31 import json
32
33 with subtest("Create subsystem and namespace"):
34 server.succeed("nvmet subsystem add ${subsystem}")
35 server.succeed("nvmet namespace add ${subsystem} 1 /dev/vdb")
36
37 with subtest("Bind subsystem to port"):
38 server.wait_for_unit("network-online.target")
39 server.succeed("nvmet port add 1 tcp [::]:4420")
40 server.succeed("nvmet port add-subsystem 1 ${subsystem}")
41
42 with subtest("Discover and connect to available subsystems"):
43 client.wait_for_unit("network-online.target")
44 assert "subnqn: ${subsystem}" in client.succeed("nvme discover --transport=tcp --traddr=server --trsvcid=4420")
45 client.succeed("nvme connect-all --transport=tcp --traddr=server --trsvcid=4420")
46
47 with subtest("Write to the connected subsystem"):
48 devices = json.loads(client.succeed("lsblk --nvme --paths --json"))["blockdevices"]
49 assert len(devices) == 1
50 client.succeed(f"dd if=/dev/zero of={devices[0]['name']} bs=1M count=64")
51 '';
52}