pyrox.dev
1{ pkgs, lib, ... }:
2let
3 port = 5000;
4in
5{
6 name = "osrm-backend";
7 meta.maintainers = [ lib.maintainers.erictapen ];
8
9 nodes.machine =
10 { config, pkgs, ... }:
11 {
12
13 services.osrm = {
14 enable = true;
15 inherit port;
16 dataFile =
17 let
18 filename = "monaco";
19 osrm-data = pkgs.stdenv.mkDerivation {
20 name = "osrm-data";
21
22 buildInputs = [ pkgs.osrm-backend ];
23
24 # This is a pbf file of monaco, downloaded at 2019-01-04 from
25 # http://download.geofabrik.de/europe/monaco-latest.osm.pbf
26 # as apparently no provider of OSM files guarantees immutability,
27 # this is hosted as a gist on GitHub.
28 src = pkgs.fetchgit {
29 url = "https://gist.github.com/erictapen/01e39f73a6c856eac53ba809a94cdb83";
30 rev = "9b1ff0f24deb40e5cf7df51f843dbe860637b8ce";
31 sha256 = "1scqhmrfnpwsy5i2a9jpggqnvfgj4hv9p4qyvc79321pzkbv59nx";
32 };
33
34 buildCommand = ''
35 cp $src/${filename}.osm.pbf .
36 ${pkgs.osrm-backend}/bin/osrm-extract -p ${pkgs.osrm-backend}/share/osrm/profiles/car.lua ${filename}.osm.pbf
37 ${pkgs.osrm-backend}/bin/osrm-partition ${filename}.osrm
38 ${pkgs.osrm-backend}/bin/osrm-customize ${filename}.osrm
39 mkdir -p $out
40 cp ${filename}* $out/
41 '';
42 };
43 in
44 "${osrm-data}/${filename}.osrm";
45 };
46
47 environment.systemPackages = [ pkgs.jq ];
48 };
49
50 testScript =
51 let
52 query = "http://localhost:${toString port}/route/v1/driving/7.41720,43.73304;7.42463,43.73886?steps=true";
53 in
54 ''
55 machine.wait_for_unit("osrm.service")
56 machine.wait_for_open_port(${toString port})
57 assert "Boulevard Rainier III" in machine.succeed(
58 "curl --fail --silent '${query}' | jq .waypoints[0].name"
59 )
60 assert "Avenue de la Costa" in machine.succeed(
61 "curl --fail --silent '${query}' | jq .waypoints[1].name"
62 )
63 '';
64}