pyrox.dev
1{ pkgs, ... }:
2{
3 # How to interactively test this module if the audio actually works
4
5 # - nix run .#pulseaudio-module-xrdp.tests.xrdp-with-audio-pulseaudio.driverInteractive
6 # - test_script() # launches the terminal and the tests itself
7 # - server.send_monitor_command("hostfwd_add tcp::3389-:3389") # forward the RDP port to the host
8 # - Connect with the RDP client you like (ex: Remmina)
9 # - Don't forget to enable audio support. In remmina: Advanced -> Audio output mode to Local (default is Off)
10 # - Open a browser or something that plays sound. Ex: chromium
11
12 name = "xrdp-with-audio-pulseaudio";
13 meta = with pkgs.lib.maintainers; {
14 maintainers = [ lucasew ];
15 };
16
17 nodes = {
18 server =
19 { pkgs, ... }:
20 {
21 imports = [ ./common/user-account.nix ];
22
23 environment.etc."xrdp/test.txt".text = "Shouldn't conflict";
24
25 services.xrdp.enable = true;
26 services.xrdp.audio.enable = true;
27 services.xrdp.defaultWindowManager = "${pkgs.xterm}/bin/xterm";
28
29 services.pulseaudio = {
30 enable = true;
31 };
32
33 systemd.user.services.pactl-list = {
34 script = ''
35 while [ ! -S /tmp/.xrdp/xrdp_chansrv_audio_in_socket_* ]; do
36 sleep 1
37 done
38 sleep 1
39 ${pkgs.pulseaudio}/bin/pactl list
40 echo Source:
41 ${pkgs.pulseaudio}/bin/pactl get-default-source | tee /tmp/pulseaudio-source
42 echo Sink:
43 ${pkgs.pulseaudio}/bin/pactl get-default-sink | tee /tmp/pulseaudio-sink
44
45 '';
46 wantedBy = [ "default.target" ];
47 };
48
49 networking.firewall.allowedTCPPorts = [ 3389 ];
50 };
51
52 client =
53 { pkgs, ... }:
54 {
55 imports = [
56 ./common/x11.nix
57 ./common/user-account.nix
58 ];
59 test-support.displayManager.auto.user = "alice";
60
61 environment.systemPackages = [ pkgs.freerdp ];
62
63 services.xrdp.enable = true;
64 services.xrdp.audio.enable = true;
65 services.xrdp.defaultWindowManager = "${pkgs.icewm}/bin/icewm";
66
67 services.pulseaudio = {
68 enable = true;
69 };
70 };
71 };
72
73 testScript =
74 { nodes, ... }:
75 let
76 user = nodes.client.config.users.users.alice;
77 in
78 ''
79 start_all()
80
81 client.wait_for_x()
82 client.wait_for_file("${user.home}/.Xauthority")
83 client.succeed("xauth merge ${user.home}/.Xauthority")
84
85 client.sleep(5)
86
87 client.execute("xterm >&2 &")
88 client.sleep(1)
89
90 client.send_chars("xfreerdp /cert-tofu /w:640 /h:480 /v:127.0.0.1 /u:${user.name} /p:${user.password} /sound\n")
91
92 client.sleep(10)
93
94 client.succeed("[ -S /tmp/.xrdp/xrdp_chansrv_audio_in_socket_* ]") # checks if it's a socket
95 client.sleep(5)
96 client.screenshot("localrdp")
97
98 client.execute("xterm >&2 &")
99 client.sleep(1)
100 client.send_chars("xfreerdp /cert-tofu /w:640 /h:480 /v:server /u:${user.name} /p:${user.password} /sound\n")
101 client.sleep(10)
102
103 server.succeed("[ -S /tmp/.xrdp/xrdp_chansrv_audio_in_socket_* ]") # checks if it's a socket
104 server.succeed('[ "$(cat /tmp/pulseaudio-source)" == "xrdp-source" ]')
105 server.succeed('[ "$(cat /tmp/pulseaudio-sink)" == "xrdp-sink" ]')
106 client.screenshot("remoterdp")
107 '';
108}