pyrox.dev
1{
2 lib,
3 stdenv,
4 langC,
5 langAda,
6 langObjC,
7 langObjCpp,
8 langFortran,
9 langGo,
10 reproducibleBuild,
11 profiledCompiler,
12 langJit,
13 staticCompiler,
14 enableShared,
15 enableLTO,
16 version,
17 fetchpatch,
18 majorVersion,
19 targetPlatform,
20 hostPlatform,
21 noSysDirs,
22 buildPlatform,
23 fetchurl,
24 withoutTargetLibc,
25 threadsCross,
26}:
27
28let
29 atLeast15 = lib.versionAtLeast version "15";
30 atLeast14 = lib.versionAtLeast version "14";
31 is15 = majorVersion == "15";
32 is14 = majorVersion == "14";
33 is13 = majorVersion == "13";
34
35 # We only apply these patches when building a native toolchain for
36 # aarch64-darwin, as it breaks building a foreign one:
37 # https://github.com/iains/gcc-12-branch/issues/18
38 canApplyIainsDarwinPatches =
39 stdenv.hostPlatform.isDarwin
40 && stdenv.hostPlatform.isAarch64
41 && (lib.systems.equals buildPlatform hostPlatform)
42 && (lib.systems.equals hostPlatform targetPlatform);
43
44 inherit (lib) optionals optional;
45in
46
47#
48# Patches below are organized into two general categories:
49# 1. Patches relevant on every platform
50# 2. Patches relevant on specific platforms
51#
52
53## 1. Patches relevant on every platform ####################################
54
55[ ]
56# Pass the path to a C++ compiler directly in the Makefile.in
57++ optional (!lib.systems.equals targetPlatform hostPlatform) ./libstdc++-target.patch
58++ optionals (noSysDirs) (
59 [
60 # Do not try looking for binaries and libraries in /lib and /usr/lib
61 ./gcc-12-no-sys-dirs.patch
62 ]
63 ++ (
64 {
65 "15" = [
66 # Do not try looking for binaries and libraries in /lib and /usr/lib
67 ./13/no-sys-dirs-riscv.patch
68 # Mangle the nix store hash in __FILE__ to prevent unneeded runtime references
69 #
70 # TODO: Remove these and the `useMacroPrefixMap` conditional
71 # in `cc-wrapper` once <https://gcc.gnu.org/PR111527>
72 # is fixed.
73 ./13/mangle-NIX_STORE-in-__FILE__.patch
74 ];
75 "14" = [
76 ./13/no-sys-dirs-riscv.patch
77 ./13/mangle-NIX_STORE-in-__FILE__.patch
78 ];
79 "13" = [
80 ./13/no-sys-dirs-riscv.patch
81 ./13/mangle-NIX_STORE-in-__FILE__.patch
82 ];
83 }
84 ."${majorVersion}" or [ ]
85 )
86)
87# Pass CFLAGS on to gnat
88++ optional langAda ./gnat-cflags-11.patch
89++ optional langFortran (
90 # Fix interaction of gfortran and libtool
91 # Fixes the output of -v
92 # See also https://github.com/nixOS/nixpkgs/commit/cc6f814a8f0e9b70ede5b24192558664fa1f98a2
93 ./gcc-12-gfortran-driving.patch)
94# Do not pass a default include dir on PowerPC+Musl
95# See https://github.com/NixOS/nixpkgs/pull/45340/commits/d6bb7d45162ac93e017cc9b665ae4836f6410710
96++ [ ./ppc-musl.patch ]
97# Moves the .cfi_starproc instruction to after the function label
98# Needed to build llvm-18 and later
99# See https://github.com/NixOS/nixpkgs/pull/354107/commits/2de1b4b14e17f42ba8b4bf43a29347c91511e008
100++ optional (!atLeast14) ./cfi_startproc-reorder-label-09-1.diff
101++ optional (atLeast14 && !canApplyIainsDarwinPatches) ./cfi_startproc-reorder-label-14-1.diff
102
103## 2. Patches relevant on specific platforms ####################################
104
105### Musl+Go+gcc12
106
107# backport fixes to build gccgo with musl libc
108++ optionals (stdenv.hostPlatform.isMusl && langGo) [
109 # libgo: handle stat st_atim32 field and SYS_SECCOMP
110 # syscall: gofmt
111 # Add blank lines after //sys comments where needed, and then run gofmt
112 # on the syscall package with the new formatter.
113 # See https://go-review.googlesource.com/c/gofrontend/+/412074
114 (fetchpatch {
115 excludes = [ "gcc/go/gofrontend/MERGE" ];
116 url = "https://github.com/gcc-mirror/gcc/commit/cf79b1117bd177d3d4c6ed24b6fa243c3628ac2d.diff";
117 hash = "sha256-mS5ZiYi5D8CpGXrWg3tXlbhp4o86ew1imCTwaHLfl+I=";
118 })
119 # libgo: permit loff_t and off_t to be macros
120 # See https://go-review.googlesource.com/c/gofrontend/+/412075
121 (fetchpatch {
122 excludes = [ "gcc/go/gofrontend/MERGE" ];
123 url = "https://github.com/gcc-mirror/gcc/commit/7f195a2270910a6ed08bd76e3a16b0a6503f9faf.diff";
124 hash = "sha256-Ze/cFM0dQofKH00PWPDoklXUlwWhwA1nyTuiDAZ6FKo=";
125 })
126 # libgo: handle stat st_atim32 field and SYS_SECCOMP
127 # See https://go-review.googlesource.com/c/gofrontend/+/415294
128 (fetchpatch {
129 excludes = [ "gcc/go/gofrontend/MERGE" ];
130 url = "https://github.com/gcc-mirror/gcc/commit/762fd5e5547e464e25b4bee435db6df4eda0de90.diff";
131 hash = "sha256-o28upwTcHAnHG2Iq0OewzwSBEhHs+XpBGdIfZdT81pk=";
132 })
133 # runtime: portable access to sigev_notify_thread_id
134 # See https://sourceware.org/bugzilla/show_bug.cgi?id=27417
135 # See https://go-review.googlesource.com/c/gofrontend/+/434755
136 (fetchpatch {
137 excludes = [ "gcc/go/gofrontend/MERGE" ];
138 url = "https://github.com/gcc-mirror/gcc/commit/e73d9fcafbd07bc3714fbaf8a82db71d50015c92.diff";
139 hash = "sha256-1SjYCVHLEUihdON2TOC3Z2ufM+jf2vH0LvYtZL+c1Fo=";
140 })
141 # syscall, runtime: always call XSI strerror_r
142 # See https://go-review.googlesource.com/c/gofrontend/+/454176
143 (fetchpatch {
144 excludes = [ "gcc/go/gofrontend/MERGE" ];
145 url = "https://github.com/gcc-mirror/gcc/commit/b6c6a3d64f2e4e9347733290aca3c75898c44b2e.diff";
146 hash = "sha256-RycJ3YCHd3MXtYFjxP0zY2Wuw7/C4bWoBAQtTKJZPOQ=";
147 })
148 # libgo: check for makecontext in -lucontext
149 # See https://go-review.googlesource.com/c/gofrontend/+/458396
150 (fetchpatch {
151 excludes = [ "gcc/go/gofrontend/MERGE" ];
152 url = "https://github.com/gcc-mirror/gcc/commit/2b1a604a9b28fbf4f382060bebd04adb83acc2f9.diff";
153 hash = "sha256-WiBQG0Xbk75rHk+AMDvsbrm+dc7lDH0EONJXSdEeMGE=";
154 })
155 # x86: Fix -fsplit-stack feature detection via TARGET_CAN_SPLIT_STACK
156 # Fixes compiling for non-glibc target
157 (fetchpatch {
158 url = "https://github.com/gcc-mirror/gcc/commit/c86b726c048eddc1be320c0bf64a897658bee13d.diff";
159 hash = "sha256-QSIlqDB6JRQhbj/c3ejlmbfWz9l9FurdSWxpwDebnlI=";
160 })
161]
162
163## Darwin
164
165# Fixes detection of Darwin on x86_64-darwin. Otherwise, GCC uses a deployment target of 10.5, which crashes ld64.
166++ optional (
167 is14 && stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isx86_64
168) ../patches/14/libgcc-darwin-detection.patch
169++ optional (
170 atLeast15 && stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isx86_64
171) ../patches/15/libgcc-darwin-detection.patch
172
173# Fix detection of bootstrap compiler Ada support (cctools as) on Nix Darwin
174++ optional (stdenv.hostPlatform.isDarwin && langAda) ./ada-cctools-as-detection-configure.patch
175
176# Remove CoreServices on Darwin, as it is only needed for macOS SDK 14+
177++ optional (
178 atLeast14 && stdenv.hostPlatform.isDarwin && langAda
179) ../patches/14/gcc-darwin-remove-coreservices.patch
180
181# Use absolute path in GNAT dylib install names on Darwin
182++ optionals (stdenv.hostPlatform.isDarwin && langAda) (
183 {
184 "15" = [ ../patches/14/gnat-darwin-dylib-install-name-14.patch ];
185 "14" = [ ../patches/14/gnat-darwin-dylib-install-name-14.patch ];
186 "13" = [ ./gnat-darwin-dylib-install-name-13.patch ];
187 }
188 .${majorVersion} or [ ]
189)
190
191# Here we apply patches by Iains (https://github.com/iains)
192# GitHub's "compare" API produces unstable diffs, so we resort to reusing
193# diffs from the Homebrew repo.
194++ optionals canApplyIainsDarwinPatches (
195 {
196 "15" = [
197 # Patches from https://github.com/iains/gcc-15-branch/compare/releases/gcc-15..gcc-15.1-darwin-rc1
198 (fetchpatch {
199 name = "gcc-15-darwin-aarch64-support.patch";
200 url = "https://raw.githubusercontent.com/Homebrew/formula-patches/a25079204c1cb3d78ba9dd7dd22b8aecce7ce264/gcc/gcc-15.1.0.diff";
201 sha256 = "sha256-MJxSGv6LEP1sIM8cDqbmfUV7byV0bYgADeIBY/Teyu8=";
202 })
203 ];
204 "14" = [
205 # Patches from https://github.com/iains/gcc-14-branch/compare/04696df09633baf97cdbbdd6e9929b9d472161d3..gcc-14.2-darwin-r2
206 (fetchpatch {
207 # There are no upstream release tags nor a static branch for 14.3.0 in https://github.com/iains/gcc-14-branch.
208 # aa4cd614456de65ee3417acb83c6cff0640144e9 is the merge base of https://github.com/iains/gcc-14-branch/tree/gcc-14-3-darwin-pre-0 and https://github.com/gcc-mirror/gcc/releases/tag/releases%2Fgcc-14.3.0
209 # 3e1d48d240f4aa5223c701b5c231c66f66ab1126 is the newest commit of https://github.com/iains/gcc-14-branch/tree/gcc-14-3-darwin-pre-0
210 name = "gcc-14-darwin-aarch64-support.patch";
211 url = "https://github.com/iains/gcc-14-branch/compare/aa4cd614456de65ee3417acb83c6cff0640144e9..3e1d48d240f4aa5223c701b5c231c66f66ab1126.diff";
212 hash = "sha256-BSTSYnkBJBEm++mGerVVyaCUC4dUyXq0N1tqbk25bO4=";
213 })
214 ];
215 # Patches from https://github.com/iains/gcc-13-branch/compare/b71f1de6e9cf7181a288c0f39f9b1ef6580cf5c8..gcc-13-3-darwin
216 "13" = [
217 (fetchpatch {
218 name = "gcc-13-darwin-aarch64-support.patch";
219 url = "https://raw.githubusercontent.com/Homebrew/formula-patches/698885df7f624d0ce15bceb79a4d9760a473b502/gcc/gcc-13.4.0.diff";
220 hash = "sha256-xqkBDFYZ6fdowtqR3kV7bR8a4Cu11RDokSzGn1k3a1w=";
221 })
222 ];
223 }
224 .${majorVersion} or [ ]
225)
226
227++ optional targetPlatform.isCygwin (fetchpatch {
228 name = "libstdc-fix-compilation-in-freestanding-win32.patch";
229 url = "https://inbox.sourceware.org/gcc-patches/20250922182808.2599390-2-corngood@gmail.com/raw";
230 hash = "sha256-+EYW9lG8CviVX7RyNHp+iX+8BRHUjt5b07k940khbbY=";
231})
232
233++ optionals targetPlatform.isCygwin [
234 (fetchpatch {
235 name = "cygwin-fix-compilation-with-inhibit_libc.patch";
236 url = "https://inbox.sourceware.org/gcc-patches/20250926170154.2222977-1-corngood@gmail.com/raw";
237 hash = "sha256-mgzMRvgPdhj+Q2VRsFhpE2WQzg0CvWsc5/FRAsSU1Es=";
238 })
239]