pyrox.dev
1{
2 lib,
3 stdenv,
4 fetchFromGitHub,
5 fetchpatch,
6 qmake,
7 qtbase,
8 qtmultimedia,
9}:
10
11stdenv.mkDerivation {
12 pname = "qmltermwidget";
13 version = "unstable-2022-01-09";
14
15 src = fetchFromGitHub {
16 owner = "Swordfish90";
17 repo = "qmltermwidget";
18 rev = "63228027e1f97c24abb907550b22ee91836929c5";
19 hash = "sha256-aVaiRpkYvuyomdkQYAgjIfi6a3wG2a6hNH1CfkA2WKQ=";
20 };
21
22 nativeBuildInputs = [
23 qmake
24 ];
25
26 buildInputs = [
27 qtbase
28 qtmultimedia
29 ];
30
31 patches = [
32 # Changes required to make it compatible with lomiri-terminal-app
33 # QML-exposed colorscheme, scrollbar & clipboard functionality
34 # Remove when https://github.com/Swordfish90/qmltermwidget/pull/39 merged
35 (fetchpatch {
36 name = "0001-qmltermwidget-lomiri-submissions.patch";
37 url = "https://github.com/Swordfish90/qmltermwidget/compare/63228027e1f97c24abb907550b22ee91836929c5..ffc6b2b2a20ca785f93300eca93c25c4b74ece17.patch";
38 hash = "sha256-1GjC2mdfP3NpePDWZaT8zvIq3vwWIZs+iQ9o01iQtD4=";
39 })
40
41 # A fix to the above series of patches, to fix a crash in lomiri-terminal-app
42 # Remove (and update the above fetchpatch) when https://github.com/gber/qmltermwidget/pull/1 merged
43 (fetchpatch {
44 name = "0002-qmltermwidget-Mark-ColorSchemeManager-singleton-as-C++-owned.patch";
45 url = "https://github.com/gber/qmltermwidget/commit/f3050bda066575eebdcff70fc1c3a393799e1d6d.patch";
46 hash = "sha256-O8fEpVLYMze6q4ps7RDGbNukRmZZBjLwqmvRqpp+H+Y=";
47 })
48
49 # Some files are copied twice to the output which makes the build fails
50 ./do-not-copy-artifacts-twice.patch
51 ];
52
53 postPatch = ''
54 substituteInPlace qmltermwidget.pro \
55 --replace '$$[QT_INSTALL_QML]' '$$PREFIX/${qtbase.qtQmlPrefix}/'
56 '';
57
58 dontWrapQtApps = true;
59
60 meta = {
61 description = "QML port of qtermwidget";
62 homepage = "https://github.com/Swordfish90/qmltermwidget";
63 license = lib.licenses.gpl2Plus;
64 platforms = with lib.platforms; linux ++ darwin;
65 maintainers = with lib.maintainers; [ OPNA2608 ];
66 };
67}